CMakeLists.txt

   1
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27 include(cotire)
  28
  29 project(pulseview)
  30
  31 #===============================================================================
  32 #= User Options
  33 #-------------------------------------------------------------------------------
  34
  35 option(DISABLE_WERROR "Build without -Werror" FALSE)
  36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  39
  40 if(WIN32)
  41         # On Windows/MinGW we need to statically link to libraries.
  42         # This option is user configurable, but enable it by default on win32.
  43         set(STATIC_PKGDEPS_LIBS TRUE)
  44
  45         # For boost-thread we need two additional settings on win32:
  46         set(Boost_USE_STATIC_LIBS on)
  47         add_definitions(-DBOOST_THREAD_USE_LIB)
  48
  49         # Windsws does not support UNIX signals
  50         set(ENABLE_SIGNALS FALSE)
  51 endif()
  52
  53 #===============================================================================
  54 #= Dependencies
  55 #-------------------------------------------------------------------------------
  56
  57 list(APPEND PKGDEPS
  58         libsigrok>=0.2.0
  59         libsigrokdecode>=0.2.0
  60 )
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  66 find_package(Qt4 REQUIRED)
  67
  68 # Find the platform's thread library (needed for boost-thread).
  69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  70 find_package(Threads)
  71
  72 if(WIN32)
  73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  74 # The library is named libboost_thread_win32* (not libboost_thread*).
  75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  76 else()
  77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  78 endif()
  79
  80 #===============================================================================
  81 #= Config Header
  82 #-------------------------------------------------------------------------------
  83
  84 set(PV_TITLE PulseView)
  85 set(PV_DESCRIPTION "A GUI for sigrok")
  86
  87 set(PV_VERSION_MAJOR 0)
  88 set(PV_VERSION_MINOR 1)
  89 set(PV_VERSION_MICRO 0)
  90 set(PV_VERSION_STRING
  91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  92 )
  93
  94 configure_file (
  95         ${PROJECT_SOURCE_DIR}/config.h.in
  96         ${PROJECT_BINARY_DIR}/config.h
  97 )
  98
  99 #===============================================================================
 100 #= Sources
 101 #-------------------------------------------------------------------------------
 102
 103 set(pulseview_SOURCES
 104         main.cpp
 105         pv/devicemanager.cpp
 106         pv/mainwindow.cpp
 107         pv/sigsession.cpp
 108         pv/data/analog.cpp
 109         pv/data/analogsnapshot.cpp
 110         pv/data/decoderstack.cpp
 111         pv/data/logic.cpp
 112         pv/data/logicsnapshot.cpp
 113         pv/data/signaldata.cpp
 114         pv/data/snapshot.cpp
 115         pv/data/decode/decoder.cpp
 116         pv/dialogs/about.cpp
 117         pv/dialogs/connect.cpp
 118         pv/popups/deviceoptions.cpp
 119         pv/popups/probes.cpp
 120         pv/prop/bool.cpp
 121         pv/prop/double.cpp
 122         pv/prop/enum.cpp
 123         pv/prop/int.cpp
 124         pv/prop/property.cpp
 125         pv/prop/string.cpp
 126         pv/prop/binding/binding.cpp
 127         pv/prop/binding/decoderoptions.cpp
 128         pv/prop/binding/deviceoptions.cpp
 129         pv/toolbars/samplingbar.cpp
 130         pv/view/analogsignal.cpp
 131         pv/view/cursor.cpp
 132         pv/view/cursorpair.cpp
 133         pv/view/decodetrace.cpp
 134         pv/view/header.cpp
 135         pv/view/marginwidget.cpp
 136         pv/view/logicsignal.cpp
 137         pv/view/ruler.cpp
 138         pv/view/selectableitem.cpp
 139         pv/view/signal.cpp
 140         pv/view/timemarker.cpp
 141         pv/view/trace.cpp
 142         pv/view/tracepalette.cpp
 143         pv/view/view.cpp
 144         pv/view/viewport.cpp
 145         pv/view/decode/annotation.cpp
 146         pv/widgets/colourbutton.cpp
 147         pv/widgets/colourpopup.cpp
 148         pv/widgets/decodermenu.cpp
 149         pv/widgets/popup.cpp
 150         pv/widgets/popuptoolbutton.cpp
 151         pv/widgets/wellarray.cpp
 152 )
 153
 154 # This list includes only QObject derrived class headers
 155 set(pulseview_HEADERS
 156         pv/mainwindow.h
 157         pv/sigsession.h
 158         pv/data/decoderstack.h
 159         pv/dialogs/about.h
 160         pv/dialogs/connect.h
 161         pv/popups/deviceoptions.h
 162         pv/popups/probes.h
 163         pv/prop/bool.h
 164         pv/prop/double.h
 165         pv/prop/enum.h
 166         pv/prop/int.h
 167         pv/prop/property.h
 168         pv/prop/string.h
 169         pv/toolbars/samplingbar.h
 170         pv/view/cursor.h
 171         pv/view/decodetrace.h
 172         pv/view/header.h
 173         pv/view/logicsignal.h
 174         pv/view/marginwidget.h
 175         pv/view/ruler.h
 176         pv/view/selectableitem.h
 177         pv/view/signal.h
 178         pv/view/timemarker.h
 179         pv/view/trace.h
 180         pv/view/view.h
 181         pv/view/viewport.h
 182         pv/widgets/colourbutton.h
 183         pv/widgets/colourpopup.h
 184         pv/widgets/decodermenu.h
 185         pv/widgets/popuptoolbutton.h
 186         pv/widgets/wellarray.h
 187 )
 188
 189 set(pulseview_FORMS
 190         pv/dialogs/about.ui
 191 )
 192
 193 set(pulseview_RESOURCES
 194         pulseview.qrc
 195 )
 196
 197 if(ENABLE_SIGNALS)
 198         list(APPEND pulseview_SOURCES signalhandler.cpp)
 199         list(APPEND pulseview_HEADERS signalhandler.h)
 200 endif()
 201
 202 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 203 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 204 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 205
 206 include(${QT_USE_FILE})
 207
 208 #===============================================================================
 209 #= Global Definitions
 210 #-------------------------------------------------------------------------------
 211
 212 add_definitions(${QT_DEFINITIONS})
 213 add_definitions(-Wall -Wextra)
 214
 215 if(NOT DISABLE_WERROR)
 216         add_definitions(-Werror)
 217 endif()
 218
 219 #===============================================================================
 220 #= Global Include Directories
 221 #-------------------------------------------------------------------------------
 222
 223 include_directories(
 224         ${CMAKE_CURRENT_BINARY_DIR}
 225         ${CMAKE_CURRENT_SOURCE_DIR}
 226         ${Boost_INCLUDE_DIRS}
 227 )
 228
 229 if(STATIC_PKGDEPS_LIBS)
 230         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 231 else()
 232         include_directories(${PKGDEPS_INCLUDE_DIRS})
 233 endif()
 234
 235 #===============================================================================
 236 #= Linker Configuration
 237 #-------------------------------------------------------------------------------
 238
 239 link_directories(${Boost_LIBRARY_DIRS})
 240
 241 set(PULSEVIEW_LINK_LIBS
 242         ${Boost_LIBRARIES}
 243         ${CMAKE_THREAD_LIBS_INIT}
 244         ${QT_LIBRARIES}
 245 )
 246
 247 if(STATIC_PKGDEPS_LIBS)
 248         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 249         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 250 else()
 251         link_directories(${PKGDEPS_LIBRARY_DIRS})
 252         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 253 endif()
 254
 255 add_executable(${PROJECT_NAME}
 256         ${pulseview_SOURCES}
 257         ${pulseview_HEADERS_MOC}
 258         ${pulseview_FORMS_HEADERS}
 259         ${pulseview_RESOURCES_RCC}
 260 )
 261
 262 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 263 cotire(${PROJECT_NAME})
 264
 265 if(WIN32)
 266 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 267 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 268 endif()
 269
 270 #===============================================================================
 271 #= Installation
 272 #-------------------------------------------------------------------------------
 273
 274 # Install the executable.
 275 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 276
 277 # Install the manpage.
 278 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 279
 280 #===============================================================================
 281 #= Packaging (handled by CPack)
 282 #-------------------------------------------------------------------------------
 283
 284 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 285 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 286 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 287 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 288 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 289 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 290 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 291         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 292 set(CPACK_SOURCE_GENERATOR "TGZ")
 293
 294 include(CPack)
 295
 296 #===============================================================================
 297 #= Tests
 298 #-------------------------------------------------------------------------------
 299
 300 if(ENABLE_TESTS)
 301         add_subdirectory(test)
 302         enable_testing()
 303         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 304 endif(ENABLE_TESTS)