CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57       FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrok>=0.2.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  68 endif()
  69
  70 find_package(PkgConfig)
  71 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  72
  73 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  74 find_package(Qt4 REQUIRED)
  75
  76 # Find the platform's thread library (needed for boost-thread).
  77 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  78 find_package(Threads)
  79
  80 if(WIN32)
  81         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  82         # The library is named libboost_thread_win32* (not libboost_thread*).
  83         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  84 else()
  85         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  86 endif()
  87
  88 #===============================================================================
  89 #= Config Header
  90 #-------------------------------------------------------------------------------
  91
  92 set(PV_TITLE PulseView)
  93 set(PV_DESCRIPTION "A GUI for sigrok")
  94
  95 set(PV_VERSION_MAJOR 0)
  96 set(PV_VERSION_MINOR 1)
  97 set(PV_VERSION_MICRO 0)
  98 set(PV_VERSION_STRING
  99         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 100 )
 101
 102 configure_file (
 103         ${PROJECT_SOURCE_DIR}/config.h.in
 104         ${PROJECT_BINARY_DIR}/config.h
 105 )
 106
 107 #===============================================================================
 108 #= Sources
 109 #-------------------------------------------------------------------------------
 110
 111 set(pulseview_SOURCES
 112         main.cpp
 113         pv/devicemanager.cpp
 114         pv/devinst.cpp
 115         pv/mainwindow.cpp
 116         pv/sigsession.cpp
 117         pv/storesession.cpp
 118         pv/data/analog.cpp
 119         pv/data/analogsnapshot.cpp
 120         pv/data/logic.cpp
 121         pv/data/logicsnapshot.cpp
 122         pv/data/signaldata.cpp
 123         pv/data/snapshot.cpp
 124         pv/dialogs/about.cpp
 125         pv/dialogs/connect.cpp
 126         pv/dialogs/storeprogress.cpp
 127         pv/popups/deviceoptions.cpp
 128         pv/popups/probes.cpp
 129         pv/prop/bool.cpp
 130         pv/prop/double.cpp
 131         pv/prop/enum.cpp
 132         pv/prop/int.cpp
 133         pv/prop/property.cpp
 134         pv/prop/string.cpp
 135         pv/prop/binding/binding.cpp
 136         pv/prop/binding/deviceoptions.cpp
 137         pv/toolbars/samplingbar.cpp
 138         pv/view/analogsignal.cpp
 139         pv/view/cursor.cpp
 140         pv/view/cursorpair.cpp
 141         pv/view/header.cpp
 142         pv/view/marginwidget.cpp
 143         pv/view/logicsignal.cpp
 144         pv/view/ruler.cpp
 145         pv/view/selectableitem.cpp
 146         pv/view/signal.cpp
 147         pv/view/timemarker.cpp
 148         pv/view/trace.cpp
 149         pv/view/tracepalette.cpp
 150         pv/view/view.cpp
 151         pv/view/viewport.cpp
 152         pv/widgets/colourbutton.cpp
 153         pv/widgets/colourpopup.cpp
 154         pv/widgets/popup.cpp
 155         pv/widgets/popuptoolbutton.cpp
 156         pv/widgets/sweeptimingwidget.cpp
 157         pv/widgets/wellarray.cpp
 158 )
 159
 160 # This list includes only QObject derived class headers.
 161 set(pulseview_HEADERS
 162         pv/devinst.h
 163         pv/mainwindow.h
 164         pv/sigsession.h
 165         pv/storesession.h
 166         pv/dialogs/about.h
 167         pv/dialogs/connect.h
 168         pv/dialogs/storeprogress.h
 169         pv/popups/probes.h
 170         pv/popups/deviceoptions.h
 171         pv/prop/bool.h
 172         pv/prop/double.h
 173         pv/prop/enum.h
 174         pv/prop/int.h
 175         pv/prop/property.h
 176         pv/prop/string.h
 177         pv/toolbars/samplingbar.h
 178         pv/view/cursor.h
 179         pv/view/header.h
 180         pv/view/logicsignal.h
 181         pv/view/marginwidget.h
 182         pv/view/ruler.h
 183         pv/view/selectableitem.h
 184         pv/view/signal.h
 185         pv/view/timemarker.h
 186         pv/view/trace.h
 187         pv/view/view.h
 188         pv/view/viewport.h
 189         pv/widgets/colourbutton.h
 190         pv/widgets/colourpopup.h
 191         pv/widgets/popup.h
 192         pv/widgets/popuptoolbutton.h
 193         pv/widgets/sweeptimingwidget.h
 194         pv/widgets/wellarray.h
 195 )
 196
 197 set(pulseview_FORMS
 198         pv/dialogs/about.ui
 199 )
 200
 201 set(pulseview_RESOURCES
 202         pulseview.qrc
 203 )
 204
 205 if(ENABLE_SIGNALS)
 206         list(APPEND pulseview_SOURCES signalhandler.cpp)
 207         list(APPEND pulseview_HEADERS signalhandler.h)
 208 endif()
 209
 210 if(ENABLE_DECODE)
 211         list(APPEND pulseview_SOURCES
 212                 pv/data/decoderstack.cpp
 213                 pv/data/decode/annotation.cpp
 214                 pv/data/decode/decoder.cpp
 215                 pv/data/decode/row.cpp
 216                 pv/data/decode/rowdata.cpp
 217                 pv/prop/binding/decoderoptions.cpp
 218                 pv/view/decodetrace.cpp
 219                 pv/widgets/decodergroupbox.cpp
 220                 pv/widgets/decodermenu.cpp
 221         )
 222
 223         list(APPEND pulseview_HEADERS
 224                 pv/data/decoderstack.h
 225                 pv/view/decodetrace.h
 226                 pv/widgets/decodergroupbox.h
 227                 pv/widgets/decodermenu.h
 228         )
 229 endif()
 230
 231 if(WIN32)
 232         # Use the sigrok icon for the pulseview.exe executable.
 233         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 234         enable_language(RC)
 235         list(APPEND pulseview_SOURCES pulseviewico.rc)
 236 endif()
 237
 238 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 239 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 240 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 241
 242 include(${QT_USE_FILE})
 243
 244 #===============================================================================
 245 #= Global Definitions
 246 #-------------------------------------------------------------------------------
 247
 248 add_definitions(${QT_DEFINITIONS})
 249 add_definitions(-D__STDC_LIMIT_MACROS)
 250 add_definitions(-Wall -Wextra)
 251
 252 if(ENABLE_DECODE)
 253         add_definitions(-DENABLE_DECODE)
 254 endif()
 255
 256 if(NOT DISABLE_WERROR)
 257         add_definitions(-Werror)
 258 endif()
 259
 260 #===============================================================================
 261 #= Global Include Directories
 262 #-------------------------------------------------------------------------------
 263
 264 include_directories(
 265         ${CMAKE_CURRENT_BINARY_DIR}
 266         ${CMAKE_CURRENT_SOURCE_DIR}
 267         ${Boost_INCLUDE_DIRS}
 268 )
 269
 270 if(STATIC_PKGDEPS_LIBS)
 271         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 272 else()
 273         include_directories(${PKGDEPS_INCLUDE_DIRS})
 274 endif()
 275
 276 #===============================================================================
 277 #= Linker Configuration
 278 #-------------------------------------------------------------------------------
 279
 280 link_directories(${Boost_LIBRARY_DIRS})
 281
 282 set(PULSEVIEW_LINK_LIBS
 283         ${Boost_LIBRARIES}
 284         ${CMAKE_THREAD_LIBS_INIT}
 285         ${QT_LIBRARIES}
 286 )
 287
 288 if(STATIC_PKGDEPS_LIBS)
 289         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 290         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 291 if(WIN32)
 292         # Workaround for a MinGW linking issue.
 293         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 294 endif()
 295 else()
 296         link_directories(${PKGDEPS_LIBRARY_DIRS})
 297         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 298 endif()
 299
 300 if(WIN32)
 301         # On Windows we need to statically link the libqsvg imageformat
 302         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 303         add_definitions(-DQT_STATICPLUGIN)
 304         link_directories("${QT_PLUGINS_DIR}/imageformats")
 305         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 306         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 307 endif()
 308
 309 add_executable(${PROJECT_NAME}
 310         ${pulseview_SOURCES}
 311         ${pulseview_HEADERS_MOC}
 312         ${pulseview_FORMS_HEADERS}
 313         ${pulseview_RESOURCES_RCC}
 314 )
 315
 316 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 317
 318 if(WIN32)
 319         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 320         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 321 endif()
 322
 323 if(ENABLE_COTIRE)
 324         include(cotire)
 325         cotire(${PROJECT_NAME})
 326 endif()
 327
 328 #===============================================================================
 329 #= Installation
 330 #-------------------------------------------------------------------------------
 331
 332 # Install the executable.
 333 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 334
 335 # Install the manpage.
 336 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 337
 338 #===============================================================================
 339 #= Packaging (handled by CPack)
 340 #-------------------------------------------------------------------------------
 341
 342 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 343 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 344 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 345 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 346 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 347 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 348 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 349         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 350 set(CPACK_SOURCE_GENERATOR "TGZ")
 351
 352 include(CPack)
 353
 354 #===============================================================================
 355 #= Tests
 356 #-------------------------------------------------------------------------------
 357
 358 if(ENABLE_TESTS)
 359         add_subdirectory(test)
 360         enable_testing()
 361         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 362 endif()