CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57       FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrok>=0.2.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  68 endif()
  69
  70 find_package(PkgConfig)
  71 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  72
  73 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  74 find_package(Qt4 REQUIRED)
  75
  76 # Find the platform's thread library (needed for boost-thread).
  77 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  78 find_package(Threads)
  79
  80 if(WIN32)
  81         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  82         # The library is named libboost_thread_win32* (not libboost_thread*).
  83         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  84 else()
  85         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  86 endif()
  87
  88 #===============================================================================
  89 #= System Introspection
  90 #-------------------------------------------------------------------------------
  91
  92 include(memaccess)
  93 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
  94
  95 #===============================================================================
  96 #= Config Header
  97 #-------------------------------------------------------------------------------
  98
  99 set(PV_TITLE PulseView)
 100 set(PV_DESCRIPTION "A GUI for sigrok")
 101
 102 set(PV_VERSION_MAJOR 0)
 103 set(PV_VERSION_MINOR 1)
 104 set(PV_VERSION_MICRO 0)
 105 set(PV_VERSION_STRING
 106         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 107 )
 108
 109 configure_file (
 110         ${PROJECT_SOURCE_DIR}/config.h.in
 111         ${PROJECT_BINARY_DIR}/config.h
 112 )
 113
 114 #===============================================================================
 115 #= Sources
 116 #-------------------------------------------------------------------------------
 117
 118 set(pulseview_SOURCES
 119         main.cpp
 120         pv/devicemanager.cpp
 121         pv/mainwindow.cpp
 122         pv/sigsession.cpp
 123         pv/storesession.cpp
 124         pv/data/analog.cpp
 125         pv/data/analogsnapshot.cpp
 126         pv/data/logic.cpp
 127         pv/data/logicsnapshot.cpp
 128         pv/data/signaldata.cpp
 129         pv/data/snapshot.cpp
 130         pv/device/device.cpp
 131         pv/device/file.cpp
 132         pv/device/devinst.cpp
 133         pv/device/inputfile.cpp
 134         pv/device/sessionfile.cpp
 135         pv/dialogs/about.cpp
 136         pv/dialogs/connect.cpp
 137         pv/dialogs/storeprogress.cpp
 138         pv/popups/deviceoptions.cpp
 139         pv/popups/probes.cpp
 140         pv/prop/bool.cpp
 141         pv/prop/double.cpp
 142         pv/prop/enum.cpp
 143         pv/prop/int.cpp
 144         pv/prop/property.cpp
 145         pv/prop/string.cpp
 146         pv/prop/binding/binding.cpp
 147         pv/prop/binding/deviceoptions.cpp
 148         pv/toolbars/samplingbar.cpp
 149         pv/view/analogsignal.cpp
 150         pv/view/cursor.cpp
 151         pv/view/cursorpair.cpp
 152         pv/view/header.cpp
 153         pv/view/marginwidget.cpp
 154         pv/view/logicsignal.cpp
 155         pv/view/ruler.cpp
 156         pv/view/selectableitem.cpp
 157         pv/view/signal.cpp
 158         pv/view/timemarker.cpp
 159         pv/view/trace.cpp
 160         pv/view/tracepalette.cpp
 161         pv/view/view.cpp
 162         pv/view/viewport.cpp
 163         pv/widgets/colourbutton.cpp
 164         pv/widgets/colourpopup.cpp
 165         pv/widgets/popup.cpp
 166         pv/widgets/popuptoolbutton.cpp
 167         pv/widgets/sweeptimingwidget.cpp
 168         pv/widgets/wellarray.cpp
 169 )
 170
 171 # This list includes only QObject derived class headers.
 172 set(pulseview_HEADERS
 173         pv/mainwindow.h
 174         pv/sigsession.h
 175         pv/storesession.h
 176         pv/device/devinst.h
 177         pv/dialogs/about.h
 178         pv/dialogs/connect.h
 179         pv/dialogs/storeprogress.h
 180         pv/popups/probes.h
 181         pv/popups/deviceoptions.h
 182         pv/prop/bool.h
 183         pv/prop/double.h
 184         pv/prop/enum.h
 185         pv/prop/int.h
 186         pv/prop/property.h
 187         pv/prop/string.h
 188         pv/toolbars/samplingbar.h
 189         pv/view/cursor.h
 190         pv/view/header.h
 191         pv/view/logicsignal.h
 192         pv/view/marginwidget.h
 193         pv/view/ruler.h
 194         pv/view/selectableitem.h
 195         pv/view/signal.h
 196         pv/view/timemarker.h
 197         pv/view/trace.h
 198         pv/view/view.h
 199         pv/view/viewport.h
 200         pv/widgets/colourbutton.h
 201         pv/widgets/colourpopup.h
 202         pv/widgets/popup.h
 203         pv/widgets/popuptoolbutton.h
 204         pv/widgets/sweeptimingwidget.h
 205         pv/widgets/wellarray.h
 206 )
 207
 208 set(pulseview_FORMS
 209         pv/dialogs/about.ui
 210 )
 211
 212 set(pulseview_RESOURCES
 213         pulseview.qrc
 214 )
 215
 216 if(ENABLE_SIGNALS)
 217         list(APPEND pulseview_SOURCES signalhandler.cpp)
 218         list(APPEND pulseview_HEADERS signalhandler.h)
 219 endif()
 220
 221 if(ENABLE_DECODE)
 222         list(APPEND pulseview_SOURCES
 223                 pv/data/decoderstack.cpp
 224                 pv/data/decode/annotation.cpp
 225                 pv/data/decode/decoder.cpp
 226                 pv/data/decode/row.cpp
 227                 pv/data/decode/rowdata.cpp
 228                 pv/prop/binding/decoderoptions.cpp
 229                 pv/view/decodetrace.cpp
 230                 pv/widgets/decodergroupbox.cpp
 231                 pv/widgets/decodermenu.cpp
 232         )
 233
 234         list(APPEND pulseview_HEADERS
 235                 pv/data/decoderstack.h
 236                 pv/view/decodetrace.h
 237                 pv/widgets/decodergroupbox.h
 238                 pv/widgets/decodermenu.h
 239         )
 240 endif()
 241
 242 if(WIN32)
 243         # Use the sigrok icon for the pulseview.exe executable.
 244         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 245         enable_language(RC)
 246         list(APPEND pulseview_SOURCES pulseviewico.rc)
 247 endif()
 248
 249 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 250 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 251 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 252
 253 include(${QT_USE_FILE})
 254
 255 #===============================================================================
 256 #= Global Definitions
 257 #-------------------------------------------------------------------------------
 258
 259 add_definitions(${QT_DEFINITIONS})
 260 add_definitions(-D__STDC_LIMIT_MACROS)
 261 add_definitions(-Wall -Wextra)
 262
 263 if(ENABLE_DECODE)
 264         add_definitions(-DENABLE_DECODE)
 265 endif()
 266
 267 if(NOT DISABLE_WERROR)
 268         add_definitions(-Werror)
 269 endif()
 270
 271 #===============================================================================
 272 #= Global Include Directories
 273 #-------------------------------------------------------------------------------
 274
 275 include_directories(
 276         ${CMAKE_CURRENT_BINARY_DIR}
 277         ${CMAKE_CURRENT_SOURCE_DIR}
 278         ${Boost_INCLUDE_DIRS}
 279 )
 280
 281 if(STATIC_PKGDEPS_LIBS)
 282         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 283 else()
 284         include_directories(${PKGDEPS_INCLUDE_DIRS})
 285 endif()
 286
 287 #===============================================================================
 288 #= Linker Configuration
 289 #-------------------------------------------------------------------------------
 290
 291 link_directories(${Boost_LIBRARY_DIRS})
 292
 293 set(PULSEVIEW_LINK_LIBS
 294         ${Boost_LIBRARIES}
 295         ${CMAKE_THREAD_LIBS_INIT}
 296         ${QT_LIBRARIES}
 297 )
 298
 299 if(STATIC_PKGDEPS_LIBS)
 300         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 301         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 302 if(WIN32)
 303         # Workaround for a MinGW linking issue.
 304         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 305 endif()
 306 else()
 307         link_directories(${PKGDEPS_LIBRARY_DIRS})
 308         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 309 endif()
 310
 311 if(WIN32)
 312         # On Windows we need to statically link the libqsvg imageformat
 313         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 314         add_definitions(-DQT_STATICPLUGIN)
 315         link_directories("${QT_PLUGINS_DIR}/imageformats")
 316         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 317         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 318 endif()
 319
 320 add_executable(${PROJECT_NAME}
 321         ${pulseview_SOURCES}
 322         ${pulseview_HEADERS_MOC}
 323         ${pulseview_FORMS_HEADERS}
 324         ${pulseview_RESOURCES_RCC}
 325 )
 326
 327 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 328
 329 if(WIN32)
 330         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 331         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 332 endif()
 333
 334 if(ENABLE_COTIRE)
 335         include(cotire)
 336         cotire(${PROJECT_NAME})
 337 endif()
 338
 339 #===============================================================================
 340 #= Installation
 341 #-------------------------------------------------------------------------------
 342
 343 # Install the executable.
 344 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 345
 346 # Install the manpage.
 347 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 348
 349 #===============================================================================
 350 #= Packaging (handled by CPack)
 351 #-------------------------------------------------------------------------------
 352
 353 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 354 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 355 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 356 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 357 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 358 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 359 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 360         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 361 set(CPACK_SOURCE_GENERATOR "TGZ")
 362
 363 include(CPack)
 364
 365 #===============================================================================
 366 #= Tests
 367 #-------------------------------------------------------------------------------
 368
 369 if(ENABLE_TESTS)
 370         add_subdirectory(test)
 371         enable_testing()
 372         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 373 endif()