CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27 include(cotire)
  28
  29 project(pulseview)
  30
  31 #===============================================================================
  32 #= User Options
  33 #-------------------------------------------------------------------------------
  34
  35 option(DISABLE_WERROR "Build without -Werror" FALSE)
  36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  39
  40 if(WIN32)
  41         # On Windows/MinGW we need to statically link to libraries.
  42         # This option is user configurable, but enable it by default on win32.
  43         set(STATIC_PKGDEPS_LIBS TRUE)
  44
  45         # For boost-thread we need two additional settings on win32:
  46         set(Boost_USE_STATIC_LIBS on)
  47         add_definitions(-DBOOST_THREAD_USE_LIB)
  48
  49         # Windsws does not support UNIX signals
  50         set(ENABLE_SIGNALS FALSE)
  51 endif()
  52
  53 #===============================================================================
  54 #= Dependencies
  55 #-------------------------------------------------------------------------------
  56
  57 list(APPEND PKGDEPS
  58         libsigrok>=0.2.0
  59         libsigrokdecode>=0.2.0
  60 )
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  66 find_package(Qt4 REQUIRED)
  67
  68 # Find the platform's thread library (needed for boost-thread).
  69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  70 find_package(Threads)
  71
  72 if(WIN32)
  73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  74 # The library is named libboost_thread_win32* (not libboost_thread*).
  75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  76 else()
  77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  78 endif()
  79
  80 #===============================================================================
  81 #= Config Header
  82 #-------------------------------------------------------------------------------
  83
  84 set(PV_TITLE PulseView)
  85 set(PV_DESCRIPTION "A GUI for sigrok")
  86
  87 set(PV_VERSION_MAJOR 0)
  88 set(PV_VERSION_MINOR 1)
  89 set(PV_VERSION_MICRO 0)
  90 set(PV_VERSION_STRING
  91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  92 )
  93
  94 configure_file (
  95         ${PROJECT_SOURCE_DIR}/config.h.in
  96         ${PROJECT_BINARY_DIR}/config.h
  97 )
  98
  99 #===============================================================================
 100 #= Sources
 101 #-------------------------------------------------------------------------------
 102
 103 set(pulseview_SOURCES
 104         main.cpp
 105         pv/devicemanager.cpp
 106         pv/mainwindow.cpp
 107         pv/sigsession.cpp
 108         pv/data/analog.cpp
 109         pv/data/analogsnapshot.cpp
 110         pv/data/logic.cpp
 111         pv/data/logicsnapshot.cpp
 112         pv/data/signaldata.cpp
 113         pv/data/snapshot.cpp
 114         pv/dialogs/about.cpp
 115         pv/dialogs/connect.cpp
 116         pv/dialogs/decoder.cpp
 117         pv/dialogs/deviceoptions.cpp
 118         pv/prop/bool.cpp
 119         pv/prop/double.cpp
 120         pv/prop/enum.cpp
 121         pv/prop/int.cpp
 122         pv/prop/property.cpp
 123         pv/prop/binding/binding.cpp
 124         pv/prop/binding/deviceoptions.cpp
 125         pv/toolbars/contextbar.cpp
 126         pv/toolbars/samplingbar.cpp
 127         pv/view/analogsignal.cpp
 128         pv/view/cursor.cpp
 129         pv/view/cursorpair.cpp
 130         pv/view/decodesignal.cpp
 131         pv/view/header.cpp
 132         pv/view/marginwidget.cpp
 133         pv/view/logicsignal.cpp
 134         pv/view/ruler.cpp
 135         pv/view/selectableitem.cpp
 136         pv/view/signal.cpp
 137         pv/view/timemarker.cpp
 138         pv/view/trace.cpp
 139         pv/view/view.cpp
 140         pv/view/viewport.cpp
 141 )
 142
 143 # This list includes only QObject derrived class headers
 144 set(pulseview_HEADERS
 145         pv/mainwindow.h
 146         pv/sigsession.h
 147         pv/dialogs/about.h
 148         pv/dialogs/connect.h
 149         pv/dialogs/deviceoptions.h
 150         pv/toolbars/contextbar.h
 151         pv/toolbars/samplingbar.h
 152         pv/view/cursor.h
 153         pv/view/header.h
 154         pv/view/logicsignal.h
 155         pv/view/marginwidget.h
 156         pv/view/ruler.h
 157         pv/view/selectableitem.h
 158         pv/view/signal.h
 159         pv/view/timemarker.h
 160         pv/view/trace.h
 161         pv/view/view.h
 162         pv/view/viewport.h
 163 )
 164
 165 set(pulseview_FORMS
 166         pv/dialogs/about.ui
 167 )
 168
 169 set(pulseview_RESOURCES
 170         pulseview.qrc
 171 )
 172
 173 if(ENABLE_SIGNALS)
 174         list(APPEND pulseview_SOURCES signalhandler.cpp)
 175         list(APPEND pulseview_HEADERS signalhandler.h)
 176 endif()
 177
 178 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 179 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 180 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 181
 182 include(${QT_USE_FILE})
 183
 184 #===============================================================================
 185 #= Global Definitions
 186 #-------------------------------------------------------------------------------
 187
 188 add_definitions(${QT_DEFINITIONS})
 189 add_definitions(-Wall -Wextra)
 190
 191 if(NOT DISABLE_WERROR)
 192         add_definitions(-Werror)
 193 endif()
 194
 195 #===============================================================================
 196 #= Global Include Directories
 197 #-------------------------------------------------------------------------------
 198
 199 include_directories(
 200         ${CMAKE_CURRENT_BINARY_DIR}
 201         ${CMAKE_CURRENT_SOURCE_DIR}
 202         ${Boost_INCLUDE_DIRS}
 203 )
 204
 205 if(STATIC_PKGDEPS_LIBS)
 206         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 207 else()
 208         include_directories(${PKGDEPS_INCLUDE_DIRS})
 209 endif()
 210
 211 #===============================================================================
 212 #= Linker Configuration
 213 #-------------------------------------------------------------------------------
 214
 215 link_directories(${Boost_LIBRARY_DIRS})
 216
 217 set(PULSEVIEW_LINK_LIBS
 218         ${Boost_LIBRARIES}
 219         ${CMAKE_THREAD_LIBS_INIT}
 220         ${QT_LIBRARIES}
 221 )
 222
 223 if(STATIC_PKGDEPS_LIBS)
 224         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 225         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 226 else()
 227         link_directories(${PKGDEPS_LIBRARY_DIRS})
 228         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 229 endif()
 230
 231 add_executable(${PROJECT_NAME}
 232         ${pulseview_SOURCES}
 233         ${pulseview_HEADERS_MOC}
 234         ${pulseview_FORMS_HEADERS}
 235         ${pulseview_RESOURCES_RCC}
 236 )
 237
 238 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 239 cotire(${PROJECT_NAME})
 240
 241 if(WIN32)
 242 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 243 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 244 endif()
 245
 246 #===============================================================================
 247 #= Installation
 248 #-------------------------------------------------------------------------------
 249
 250 # Install the executable.
 251 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 252
 253 # Install the manpage.
 254 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 255
 256 #===============================================================================
 257 #= Packaging (handled by CPack)
 258 #-------------------------------------------------------------------------------
 259
 260 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 261 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 262 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 263 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 264 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 265 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 266 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 267         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 268 set(CPACK_SOURCE_GENERATOR "TGZ")
 269
 270 include(CPack)
 271
 272 #===============================================================================
 273 #= Tests
 274 #-------------------------------------------------------------------------------
 275
 276 if(ENABLE_TESTS)
 277         add_subdirectory(test)
 278         enable_testing()
 279         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 280 endif(ENABLE_TESTS)