CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.4.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.4.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 include(GetGitRevisionDescription)
 126 git_describe(PV_NAME_VERSION_STRING)
 127
 128 if(NOT PV_NAME_VERSION_STRING)
 129         # Read the version from a file that is distributed with
 130         # the source package (see writepackageversion.cmake).
 131         file(STRINGS "${PROJECT_SOURCE_DIR}/VERSION" PV_NAME_VERSION_STRING LIMIT_COUNT 1)
 132 endif()
 133
 134 if(PV_NAME_VERSION_STRING MATCHES "^pulseview-([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]+)?$")
 135         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 136         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 137         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 138         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 139 else()
 140         message(FATAL_ERROR "-- Cannot get the ${PV_TITLE} version from anywhere")
 141 endif()
 142
 143 set(PV_VERSION_STRING
 144         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}${PV_VERSION_SUFFIX}
 145 )
 146 message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
 147
 148 configure_file (
 149         ${PROJECT_SOURCE_DIR}/config.h.in
 150         ${PROJECT_BINARY_DIR}/config.h
 151 )
 152
 153 #===============================================================================
 154 #= Sources
 155 #-------------------------------------------------------------------------------
 156
 157 set(pulseview_SOURCES
 158         main.cpp
 159         pv/application.cpp
 160         pv/devicemanager.cpp
 161         pv/mainwindow.cpp
 162         pv/session.cpp
 163         pv/storesession.cpp
 164         pv/util.cpp
 165         pv/binding/binding.cpp
 166         pv/binding/inputoutput.cpp
 167         pv/binding/device.cpp
 168         pv/data/analog.cpp
 169         pv/data/analogsegment.cpp
 170         pv/data/logic.cpp
 171         pv/data/logicsegment.cpp
 172         pv/data/signaldata.cpp
 173         pv/data/segment.cpp
 174         pv/devices/device.cpp
 175         pv/devices/file.cpp
 176         pv/devices/hardwaredevice.cpp
 177         pv/devices/inputfile.cpp
 178         pv/devices/sessionfile.cpp
 179         pv/dialogs/about.cpp
 180         pv/dialogs/connect.cpp
 181         pv/dialogs/inputoutputoptions.cpp
 182         pv/dialogs/storeprogress.cpp
 183         pv/popups/deviceoptions.cpp
 184         pv/popups/channels.cpp
 185         pv/prop/bool.cpp
 186         pv/prop/double.cpp
 187         pv/prop/enum.cpp
 188         pv/prop/int.cpp
 189         pv/prop/property.cpp
 190         pv/prop/string.cpp
 191         pv/toolbars/mainbar.cpp
 192         pv/view/analogsignal.cpp
 193         pv/view/cursor.cpp
 194         pv/view/cursorpair.cpp
 195         pv/view/flag.cpp
 196         pv/view/header.cpp
 197         pv/view/marginwidget.cpp
 198         pv/view/logicsignal.cpp
 199         pv/view/rowitem.cpp
 200         pv/view/rowitemowner.cpp
 201         pv/view/ruler.cpp
 202         pv/view/signal.cpp
 203         pv/view/timeitem.cpp
 204         pv/view/timemarker.cpp
 205         pv/view/trace.cpp
 206         pv/view/tracegroup.cpp
 207         pv/view/tracepalette.cpp
 208         pv/view/view.cpp
 209         pv/view/viewitem.cpp
 210         pv/view/viewitempaintparams.cpp
 211         pv/view/viewport.cpp
 212         pv/view/viewwidget.cpp
 213         pv/widgets/colourbutton.cpp
 214         pv/widgets/colourpopup.cpp
 215         pv/widgets/devicetoolbutton.cpp
 216         pv/widgets/exportmenu.cpp
 217         pv/widgets/hidingmenubar.cpp
 218         pv/widgets/importmenu.cpp
 219         pv/widgets/popup.cpp
 220         pv/widgets/popuptoolbutton.cpp
 221         pv/widgets/sweeptimingwidget.cpp
 222         pv/widgets/wellarray.cpp
 223 )
 224
 225 # This list includes only QObject derived class headers.
 226 set(pulseview_HEADERS
 227         pv/mainwindow.hpp
 228         pv/session.hpp
 229         pv/storesession.hpp
 230         pv/binding/device.hpp
 231         pv/dialogs/about.hpp
 232         pv/dialogs/connect.hpp
 233         pv/dialogs/inputoutputoptions.hpp
 234         pv/dialogs/storeprogress.hpp
 235         pv/popups/channels.hpp
 236         pv/popups/deviceoptions.hpp
 237         pv/prop/bool.hpp
 238         pv/prop/double.hpp
 239         pv/prop/enum.hpp
 240         pv/prop/int.hpp
 241         pv/prop/property.hpp
 242         pv/prop/string.hpp
 243         pv/toolbars/mainbar.hpp
 244         pv/view/cursor.hpp
 245         pv/view/flag.hpp
 246         pv/view/header.hpp
 247         pv/view/logicsignal.hpp
 248         pv/view/marginwidget.hpp
 249         pv/view/rowitem.hpp
 250         pv/view/ruler.hpp
 251         pv/view/signal.hpp
 252         pv/view/timeitem.hpp
 253         pv/view/timemarker.hpp
 254         pv/view/trace.hpp
 255         pv/view/tracegroup.hpp
 256         pv/view/view.hpp
 257         pv/view/viewitem.hpp
 258         pv/view/viewport.hpp
 259         pv/view/viewwidget.hpp
 260         pv/widgets/colourbutton.hpp
 261         pv/widgets/colourpopup.hpp
 262         pv/widgets/devicetoolbutton.hpp
 263         pv/widgets/exportmenu.hpp
 264         pv/widgets/hidingmenubar.hpp
 265         pv/widgets/importmenu.hpp
 266         pv/widgets/popup.hpp
 267         pv/widgets/popuptoolbutton.hpp
 268         pv/widgets/sweeptimingwidget.hpp
 269         pv/widgets/wellarray.hpp
 270 )
 271
 272 set(pulseview_FORMS
 273         pv/dialogs/about.ui
 274 )
 275
 276 set(pulseview_RESOURCES
 277         pulseview.qrc
 278 )
 279
 280 if(ENABLE_SIGNALS)
 281         list(APPEND pulseview_SOURCES signalhandler.cpp)
 282         list(APPEND pulseview_HEADERS signalhandler.hpp)
 283 endif()
 284
 285 if(ENABLE_DECODE)
 286         list(APPEND pulseview_SOURCES
 287                 pv/binding/decoder.cpp
 288                 pv/data/decoderstack.cpp
 289                 pv/data/decode/annotation.cpp
 290                 pv/data/decode/decoder.cpp
 291                 pv/data/decode/row.cpp
 292                 pv/data/decode/rowdata.cpp
 293                 pv/view/decodetrace.cpp
 294                 pv/widgets/decodergroupbox.cpp
 295                 pv/widgets/decodermenu.cpp
 296         )
 297
 298         list(APPEND pulseview_HEADERS
 299                 pv/data/decoderstack.hpp
 300                 pv/view/decodetrace.hpp
 301                 pv/widgets/decodergroupbox.hpp
 302                 pv/widgets/decodermenu.hpp
 303         )
 304 endif()
 305
 306 if(WIN32)
 307         # Use the sigrok icon for the pulseview.exe executable.
 308         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 309         enable_language(RC)
 310         list(APPEND pulseview_SOURCES pulseviewico.rc)
 311 endif()
 312
 313 if(ANDROID)
 314         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 315 endif()
 316
 317 if(Qt5Core_FOUND)
 318         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 319         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 320         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 321 else()
 322         # Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
 323         # https://bugreports.qt.io/browse/QTBUG-22829
 324         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
 325                 OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
 326         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 327         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 328         include(${QT_USE_FILE})
 329 endif()
 330
 331 #===============================================================================
 332 #= Global Definitions
 333 #-------------------------------------------------------------------------------
 334
 335 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 336 add_definitions(-D__STDC_LIMIT_MACROS)
 337 add_definitions(-Wall -Wextra)
 338 add_definitions(-std=c++11)
 339
 340 if(ENABLE_DECODE)
 341         add_definitions(-DENABLE_DECODE)
 342 endif()
 343
 344 if(NOT DISABLE_WERROR)
 345         add_definitions(-Werror)
 346 endif()
 347
 348 if(ENABLE_SIGNALS)
 349         add_definitions(-DENABLE_SIGNALS)
 350 endif()
 351
 352 #===============================================================================
 353 #= Global Include Directories
 354 #-------------------------------------------------------------------------------
 355
 356 include_directories(
 357         ${CMAKE_CURRENT_BINARY_DIR}
 358         ${CMAKE_CURRENT_SOURCE_DIR}
 359         ${Boost_INCLUDE_DIRS}
 360         ${QT_INCLUDE_DIRS}
 361 )
 362
 363 if(STATIC_PKGDEPS_LIBS)
 364         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 365 else()
 366         include_directories(${PKGDEPS_INCLUDE_DIRS})
 367 endif()
 368
 369 #===============================================================================
 370 #= Linker Configuration
 371 #-------------------------------------------------------------------------------
 372
 373 link_directories(${Boost_LIBRARY_DIRS})
 374
 375 set(PULSEVIEW_LINK_LIBS
 376         ${Boost_LIBRARIES}
 377         ${QT_LIBRARIES}
 378         ${CMAKE_THREAD_LIBS_INIT}
 379 )
 380
 381 if(STATIC_PKGDEPS_LIBS)
 382         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 383         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 384 if(WIN32)
 385         # Workaround for a MinGW linking issue.
 386         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 387 endif()
 388 else()
 389         link_directories(${PKGDEPS_LIBRARY_DIRS})
 390         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 391 endif()
 392
 393 if(WIN32)
 394         # On Windows we need to statically link the libqsvg imageformat
 395         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 396         add_definitions(-DQT_STATICPLUGIN)
 397         link_directories("${QT_PLUGINS_DIR}/imageformats")
 398         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 399         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 400 endif()
 401
 402 if(ANDROID)
 403         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 404 endif()
 405
 406 if(ANDROID)
 407 add_library(${PROJECT_NAME} SHARED
 408         ${pulseview_SOURCES}
 409         ${pulseview_HEADERS_MOC}
 410         ${pulseview_FORMS_HEADERS}
 411         ${pulseview_RESOURCES_RCC}
 412 )
 413 else()
 414 add_executable(${PROJECT_NAME}
 415         ${pulseview_SOURCES}
 416         ${pulseview_HEADERS_MOC}
 417         ${pulseview_FORMS_HEADERS}
 418         ${pulseview_RESOURCES_RCC}
 419 )
 420 endif()
 421
 422 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 423
 424 if(WIN32)
 425         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 426         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 427 endif()
 428
 429 #===============================================================================
 430 #= Installation
 431 #-------------------------------------------------------------------------------
 432
 433 # Install the executable.
 434 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 435
 436 # Install the manpage.
 437 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 438
 439 #===============================================================================
 440 #= Packaging (handled by CPack)
 441 #-------------------------------------------------------------------------------
 442
 443 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 444 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 445 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 446 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 447 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 448 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 449 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 450 set(CPACK_SOURCE_GENERATOR "TGZ")
 451 set(CPACK_INSTALL_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/CMake/writepackageversion.cmake)
 452
 453 include(CPack)
 454
 455 #===============================================================================
 456 #= Tests
 457 #-------------------------------------------------------------------------------
 458
 459 if(ENABLE_TESTS)
 460         add_subdirectory(test)
 461         enable_testing()
 462         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 463 endif()