CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ## Copyright (C) 2020 Soeren Apel <soeren@apelpie.net>
   7 ##
   8 ## This program is free software: you can redistribute it and/or modify
   9 ## it under the terms of the GNU General Public License as published by
  10 ## the Free Software Foundation, either version 2 of the License, or
  11 ## (at your option) any later version.
  12 ##
  13 ## This program is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License
  19 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 ##
  21
  22 cmake_minimum_required(VERSION 2.8.12)
  23
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 # Let AUTOMOC and AUTOUIC process GENERATED files.
  29 if(POLICY CMP0071)
  30         cmake_policy(SET CMP0071 NEW)
  31 endif()
  32
  33 # Only interpret if() arguments as variables or keywords when unquoted.
  34 if(POLICY CMP0054)
  35         cmake_policy(SET CMP0054 NEW)
  36 endif()
  37
  38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  39
  40 #===============================================================================
  41 #= User Options
  42 #-------------------------------------------------------------------------------
  43
  44 option(DISABLE_WERROR "Build without -Werror" TRUE)
  45 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  46 option(ENABLE_STACKTRACE "Enable stack trace when crashing" FALSE)
  47 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  48 option(ENABLE_FLOW "Build with libsigrokflow" FALSE)
  49 option(ENABLE_TESTS "Enable unit tests" FALSE)
  50 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  51
  52 if(WIN32)
  53         # On Windows/MinGW we need to statically link to libraries.
  54         # This option is user configurable, but enable it by default on win32.
  55         set(STATIC_PKGDEPS_LIBS TRUE)
  56
  57         # Windows does not support UNIX signals.
  58         set(ENABLE_SIGNALS FALSE)
  59 endif()
  60
  61 if(NOT CMAKE_BUILD_TYPE)
  62         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  63         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  64         FORCE)
  65 endif()
  66
  67 #===============================================================================
  68 #= Documentation
  69 #-------------------------------------------------------------------------------
  70
  71 add_subdirectory(manual)
  72
  73 #===============================================================================
  74 #= Dependencies
  75 #-------------------------------------------------------------------------------
  76
  77 list(APPEND PKGDEPS glib-2.0>=2.28.0)
  78 list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
  79
  80 if(ENABLE_FLOW)
  81         list(APPEND PKGDEPS gstreamermm-1.0>=1.8.0)
  82         list(APPEND PKGDEPS libsigrokflow>=0.1.0)
  83 endif()
  84
  85 set(LIBSR_CXX_BINDING "libsigrokcxx>=0.5.2")
  86 list(APPEND PKGDEPS "${LIBSR_CXX_BINDING}")
  87
  88 if(ENABLE_DECODE)
  89         list(APPEND PKGDEPS libsigrokdecode>=0.5.2)
  90 endif()
  91
  92 if(ANDROID)
  93         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  94 endif()
  95
  96 find_package(PkgConfig)
  97 pkg_check_modules(LIBSRCXX ${LIBSR_CXX_BINDING})
  98 if(NOT LIBSRCXX_FOUND OR NOT LIBSRCXX_VERSION)
  99         message(FATAL_ERROR "libsigrok C++ bindings missing, check libsigrok's 'configure' output (missing dependencies?)")
 100 endif()
 101 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
 102
 103 set(CMAKE_AUTOMOC TRUE)
 104
 105 find_package(Qt5 5.3 COMPONENTS Core Gui LinguistTools Widgets Svg REQUIRED)
 106
 107 message(STATUS "Qt version: ${Qt5_VERSION}")
 108
 109 if(WIN32)
 110         # MXE workaround: Use pkg-config to find Qt5 libs.
 111         # https://github.com/mxe/mxe/issues/1642
 112         # Not required (and doesn't work) on MSYS2.
 113         if(NOT DEFINED ENV{MSYSTEM})
 114                 pkg_check_modules(QT5ALL REQUIRED Qt5Widgets>=5.3 Qt5Gui>=5.3 Qt5Svg>=5.3)
 115         endif()
 116 endif()
 117
 118 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
 119
 120 set(BOOSTCOMPS filesystem serialization system)
 121 if(ENABLE_TESTS)
 122         list(APPEND BOOSTCOMPS unit_test_framework)
 123 endif()
 124
 125 if(ENABLE_STACKTRACE)
 126         include(FindBacktrace)
 127         if (Backtrace_FOUND)
 128                 set(_Boost_STACKTRACE_BACKTRACE_HEADERS "boost/stacktrace.hpp")
 129                 list(APPEND BOOSTCOMPS stacktrace_backtrace)
 130         else()
 131                 set(_Boost_STACKTRACE_BASIC_HEADERS     "boost/stacktrace.hpp")
 132                 list(APPEND BOOSTCOMPS stacktrace_basic)
 133         endif()
 134         find_package(Boost 1.65.1 COMPONENTS ${BOOSTCOMPS} REQUIRED)
 135 else()
 136         find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
 137 endif()
 138
 139 # Find the platform's thread library (needed for C++11 threads).
 140 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 141 find_package(Threads REQUIRED)
 142
 143 # Check for explicit link against libatomic
 144 #
 145 # Depending on the toolchain, linking a program using atomic functions may need
 146 # "-latomic" explicitly passed to the linker
 147 #
 148 # This check first tests if atomics are available in the C-library, if not and
 149 # libatomic exists, then it runs the same test with -latomic added to the
 150 # linker flags.
 151
 152 # Helper for checking for atomics
 153 function(check_working_cxx_atomics varname additional_lib)
 154   include(CheckCXXSourceCompiles)
 155   include(CMakePushCheckState)
 156   cmake_push_check_state()
 157   set(CMAKE_REQUIRED_FLAGS "-std=c++11")
 158   set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
 159   set(CMAKE_REQUIRED_QUIET 1)
 160   CHECK_CXX_SOURCE_COMPILES("
 161 #include <atomic>
 162 std::atomic<int> x;
 163 int main() {
 164   return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
 165 }
 166 " ${varname})
 167   cmake_pop_check_state()
 168 endfunction(check_working_cxx_atomics)
 169
 170 # First check if atomics work without the library.
 171 # If not, check if the library exists, and atomics work with it.
 172 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
 173 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
 174   message(STATUS "Atomics provided by the C-library - yes")
 175 else()
 176   message(STATUS "Atomics provided by the C-library - no")
 177   find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
 178   if(LIBATOMIC_LIBRARY)
 179     check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
 180     if (HAVE_CXX_ATOMICS_WITH_LIB)
 181       message(STATUS "Atomics provided by libatomic - yes")
 182     else()
 183       message(STATUS "Atomics provided by libatomic - no")
 184       message(FATAL_ERROR "Compiler must support std::atomic!")
 185     endif()
 186   else()
 187     message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
 188   endif()
 189 endif()
 190
 191 #===============================================================================
 192 #= System Introspection
 193 #-------------------------------------------------------------------------------
 194
 195 include(memaccess)
 196 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 197
 198 #===============================================================================
 199 #= Config Header
 200 #-------------------------------------------------------------------------------
 201
 202 set(PV_TITLE PulseView)
 203 set(PV_VERSION_STRING "0.5.0")
 204
 205 set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
 206
 207 include(GetGitRevisionDescription)
 208
 209 # Append the revision hash unless we are exactly on a tagged release.
 210 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
 211 if(NOT PV_TAG_VERSION_STRING)
 212         get_git_head_revision(PV_REVSPEC PV_HASH)
 213         if(PV_HASH)
 214                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
 215                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
 216         endif()
 217
 218         # Non-tagged releases use the unstable manual
 219         set(PV_MANUAL_VERSION "unstable")
 220 else()
 221         # Tagged releases use a fixed manual version
 222         set(PV_MANUAL_VERSION ${PV_VERSION_STRING})
 223 endif()
 224
 225 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
 226         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 227         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 228         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 229         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 230 endif()
 231
 232 message(STATUS "${PV_TITLE} version: ${PV_VERSION_STRING}")
 233
 234 configure_file (
 235         ${PROJECT_SOURCE_DIR}/config.h.in
 236         ${PROJECT_BINARY_DIR}/config.h
 237 )
 238
 239 #===============================================================================
 240 #= Sources
 241 #-------------------------------------------------------------------------------
 242
 243 set(pulseview_SOURCES
 244         main.cpp
 245         pv/application.cpp
 246         pv/devicemanager.cpp
 247         pv/globalsettings.cpp
 248         pv/logging.cpp
 249         pv/mainwindow.cpp
 250         pv/session.cpp
 251         pv/storesession.cpp
 252         pv/util.cpp
 253         pv/binding/binding.cpp
 254         pv/binding/inputoutput.cpp
 255         pv/binding/device.cpp
 256         pv/data/analog.cpp
 257         pv/data/analogsegment.cpp
 258         pv/data/logic.cpp
 259         pv/data/logicsegment.cpp
 260         pv/data/signalbase.cpp
 261         pv/data/signaldata.cpp
 262         pv/data/segment.cpp
 263         pv/devices/device.cpp
 264         pv/devices/file.cpp
 265         pv/devices/hardwaredevice.cpp
 266         pv/devices/inputfile.cpp
 267         pv/devices/sessionfile.cpp
 268         pv/dialogs/connect.cpp
 269         pv/dialogs/inputoutputoptions.cpp
 270         pv/dialogs/settings.cpp
 271         pv/dialogs/storeprogress.cpp
 272         pv/popups/deviceoptions.cpp
 273         pv/popups/channels.cpp
 274         pv/prop/bool.cpp
 275         pv/prop/double.cpp
 276         pv/prop/enum.cpp
 277         pv/prop/int.cpp
 278         pv/prop/property.cpp
 279         pv/prop/string.cpp
 280         pv/subwindows/subwindowbase.cpp
 281         pv/toolbars/mainbar.cpp
 282         pv/views/trace/analogsignal.cpp
 283         pv/views/trace/cursor.cpp
 284         pv/views/trace/cursorpair.cpp
 285         pv/views/trace/flag.cpp
 286         pv/views/trace/header.cpp
 287         pv/views/trace/marginwidget.cpp
 288         pv/views/trace/logicsignal.cpp
 289         pv/views/trace/ruler.cpp
 290         pv/views/trace/signal.cpp
 291         pv/views/trace/timeitem.cpp
 292         pv/views/trace/timemarker.cpp
 293         pv/views/trace/trace.cpp
 294         pv/views/trace/tracegroup.cpp
 295         pv/views/trace/tracepalette.cpp
 296         pv/views/trace/tracetreeitem.cpp
 297         pv/views/trace/tracetreeitemowner.cpp
 298         pv/views/trace/triggermarker.cpp
 299         pv/views/trace/view.cpp
 300         pv/views/trace/viewitem.cpp
 301         pv/views/trace/viewitemowner.cpp
 302         pv/views/trace/viewitempaintparams.cpp
 303         pv/views/trace/viewport.cpp
 304         pv/views/trace/viewwidget.cpp
 305         pv/views/viewbase.cpp
 306         pv/views/trace/standardbar.cpp
 307         pv/widgets/colorbutton.cpp
 308         pv/widgets/colorpopup.cpp
 309         pv/widgets/devicetoolbutton.cpp
 310         pv/widgets/exportmenu.cpp
 311         pv/widgets/flowlayout.cpp
 312         pv/widgets/importmenu.cpp
 313         pv/widgets/popup.cpp
 314         pv/widgets/popuptoolbutton.cpp
 315         pv/widgets/sweeptimingwidget.cpp
 316         pv/widgets/timestampspinbox.cpp
 317         pv/widgets/wellarray.cpp
 318 )
 319
 320 # This list includes only QObject derived class headers.
 321 set(pulseview_HEADERS
 322         pv/logging.hpp
 323         pv/globalsettings.hpp
 324         pv/mainwindow.hpp
 325         pv/session.hpp
 326         pv/storesession.hpp
 327         pv/binding/device.hpp
 328         pv/data/analog.hpp
 329         pv/data/analogsegment.hpp
 330         pv/data/logic.hpp
 331         pv/data/logicsegment.hpp
 332         pv/data/signalbase.hpp
 333         pv/dialogs/connect.hpp
 334         pv/dialogs/inputoutputoptions.hpp
 335         pv/dialogs/settings.hpp
 336         pv/dialogs/storeprogress.hpp
 337         pv/popups/channels.hpp
 338         pv/popups/deviceoptions.hpp
 339         pv/prop/bool.hpp
 340         pv/prop/double.hpp
 341         pv/prop/enum.hpp
 342         pv/prop/int.hpp
 343         pv/prop/property.hpp
 344         pv/prop/string.hpp
 345         pv/subwindows/subwindowbase.hpp
 346         pv/toolbars/mainbar.hpp
 347         pv/views/trace/analogsignal.hpp
 348         pv/views/trace/cursor.hpp
 349         pv/views/trace/flag.hpp
 350         pv/views/trace/header.hpp
 351         pv/views/trace/logicsignal.hpp
 352         pv/views/trace/marginwidget.hpp
 353         pv/views/trace/ruler.hpp
 354         pv/views/trace/signal.hpp
 355         pv/views/trace/timeitem.hpp
 356         pv/views/trace/timemarker.hpp
 357         pv/views/trace/trace.hpp
 358         pv/views/trace/tracegroup.hpp
 359         pv/views/trace/tracetreeitem.hpp
 360         pv/views/trace/triggermarker.hpp
 361         pv/views/trace/view.hpp
 362         pv/views/trace/viewitem.hpp
 363         pv/views/trace/viewport.hpp
 364         pv/views/trace/viewwidget.hpp
 365         pv/views/viewbase.hpp
 366         pv/views/trace/standardbar.hpp
 367         pv/widgets/colorbutton.hpp
 368         pv/widgets/colorpopup.hpp
 369         pv/widgets/devicetoolbutton.hpp
 370         pv/widgets/exportmenu.hpp
 371         pv/widgets/flowlayout.hpp
 372         pv/widgets/importmenu.hpp
 373         pv/widgets/popup.hpp
 374         pv/widgets/popuptoolbutton.hpp
 375         pv/widgets/sweeptimingwidget.hpp
 376         pv/widgets/timestampspinbox.hpp
 377         pv/widgets/wellarray.hpp
 378 )
 379
 380 set(pulseview_RESOURCES
 381         pulseview.qrc
 382 )
 383
 384 if(ENABLE_SIGNALS)
 385         list(APPEND pulseview_SOURCES signalhandler.cpp)
 386         list(APPEND pulseview_HEADERS signalhandler.hpp)
 387 endif()
 388
 389 if(ENABLE_DECODE)
 390         list(APPEND pulseview_SOURCES
 391                 pv/binding/decoder.cpp
 392                 pv/data/decodesignal.cpp
 393                 pv/data/decode/annotation.cpp
 394                 pv/data/decode/decoder.cpp
 395                 pv/data/decode/row.cpp
 396                 pv/data/decode/rowdata.cpp
 397                 pv/subwindows/decoder_selector/item.cpp
 398                 pv/subwindows/decoder_selector/model.cpp
 399                 pv/subwindows/decoder_selector/subwindow.cpp
 400                 pv/views/decoder_binary/view.cpp
 401                 pv/views/decoder_binary/QHexView.cpp
 402                 pv/views/trace/decodetrace.cpp
 403                 pv/widgets/decodergroupbox.cpp
 404                 pv/widgets/decodermenu.cpp
 405         )
 406
 407         list(APPEND pulseview_HEADERS
 408                 pv/data/decodesignal.hpp
 409                 pv/subwindows/decoder_selector/subwindow.hpp
 410                 pv/views/decoder_binary/view.hpp
 411                 pv/views/decoder_binary/QHexView.hpp
 412                 pv/views/trace/decodetrace.hpp
 413                 pv/widgets/decodergroupbox.hpp
 414                 pv/widgets/decodermenu.hpp
 415         )
 416 endif()
 417
 418 if(WIN32)
 419         # Use the sigrok icon for the pulseview.exe executable.
 420         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 421         enable_language(RC)
 422         list(APPEND pulseview_SOURCES pulseviewico.rc)
 423 endif()
 424
 425 if(ANDROID)
 426         list(APPEND pulseview_SOURCES
 427                 android/assetreader.cpp
 428                 android/loghandler.cpp
 429         )
 430 endif()
 431
 432 qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 433
 434 #===============================================================================
 435 #= Translations
 436 #-------------------------------------------------------------------------------
 437
 438 file(GLOB TS_FILES ${CMAKE_SOURCE_DIR}/l10n/*.ts)
 439 set_property(SOURCE ${TS_FILES} PROPERTY OUTPUT_LOCATION ${CMAKE_BINARY_DIR}/l10n)
 440 if (NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
 441         configure_file("translations.qrc" "translations.qrc" COPYONLY)
 442 endif ()
 443
 444 qt5_add_translation(QM_FILES ${TS_FILES})
 445 qt5_create_translation(QM_FILES ${pulseview_SOURCES} ${TS_FILES})
 446
 447 qt5_add_resources(pulseview_RESOURCES_RCC ${CMAKE_BINARY_DIR}/translations.qrc)
 448
 449 #===============================================================================
 450 #= Global Definitions
 451 #-------------------------------------------------------------------------------
 452
 453 add_definitions(-DQT_NO_KEYWORDS)
 454 add_definitions(-D__STDC_LIMIT_MACROS)
 455 add_definitions(-Wall -Wextra)
 456 add_definitions(-std=c++11)
 457 add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
 458
 459 if(ENABLE_FLOW)
 460         add_definitions(-DENABLE_FLOW)
 461 endif()
 462
 463 if(ENABLE_DECODE)
 464         add_definitions(-DENABLE_DECODE)
 465 endif()
 466
 467 if(NOT DISABLE_WERROR)
 468         add_definitions(-Werror)
 469 endif()
 470
 471 if(ENABLE_SIGNALS)
 472         add_definitions(-DENABLE_SIGNALS)
 473 endif()
 474
 475 if(ENABLE_STACKTRACE)
 476         add_definitions(-DENABLE_STACKTRACE -no-pie -fno-pie)
 477         if (Backtrace_FOUND)
 478                 add_definitions(-DBOOST_STACKTRACE_USE_BACKTRACE)
 479         endif()
 480 endif()
 481
 482 #===============================================================================
 483 #= Global Include Directories
 484 #-------------------------------------------------------------------------------
 485
 486 include_directories(
 487         ${CMAKE_CURRENT_BINARY_DIR}
 488         ${CMAKE_CURRENT_SOURCE_DIR}
 489         ${Boost_INCLUDE_DIRS}
 490 )
 491
 492 if(STATIC_PKGDEPS_LIBS)
 493         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 494 else()
 495         include_directories(${PKGDEPS_INCLUDE_DIRS})
 496 endif()
 497
 498 #===============================================================================
 499 #= Linker Configuration
 500 #-------------------------------------------------------------------------------
 501
 502 link_directories(${Boost_LIBRARY_DIRS})
 503
 504 set(PULSEVIEW_LINK_LIBS
 505         ${Boost_LIBRARIES}
 506         ${QT_LIBRARIES}
 507         ${CMAKE_THREAD_LIBS_INIT}
 508         ${LIBATOMIC_LIBRARY}
 509 )
 510
 511 if(STATIC_PKGDEPS_LIBS)
 512         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 513         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
 514 else()
 515         link_directories(${PKGDEPS_LIBRARY_DIRS})
 516         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 517 endif()
 518
 519 if(WIN32)
 520         # On Windows we need to statically link the libqsvg imageformat
 521         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 522         # We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
 523         # Qt < 5.8.0), and all Qt libs and their dependencies.
 524         add_definitions(-DQT_STATICPLUGIN)
 525         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
 526         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
 527         if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
 528                 list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
 529         endif()
 530         list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
 531 endif()
 532
 533 if(ENABLE_STACKTRACE)
 534         list(APPEND PULSEVIEW_LINK_LIBS ${CMAKE_DL_LIBS} ${Backtrace_LIBRARIES})
 535         link_libraries("-no-pie -fno-pie")
 536 endif()
 537
 538 if(ANDROID)
 539         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 540 endif()
 541
 542 set(INPUT_FILES_LIST ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC} ${QM_FILES})
 543 if(ANDROID)
 544         add_library(${PROJECT_NAME} SHARED ${INPUT_FILES_LIST})
 545 else()
 546         add_executable(${PROJECT_NAME} ${INPUT_FILES_LIST})
 547 endif()
 548
 549 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 550
 551 if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
 552         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 553         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 554 endif()
 555
 556 #===============================================================================
 557 #= Installation
 558 #-------------------------------------------------------------------------------
 559
 560 # Install the executable.
 561 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 562
 563 # Install the manpage.
 564 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 565
 566 # Install the desktop file.
 567 install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 568
 569 # Install the AppData/AppStream file.
 570 install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)
 571
 572 # Install the PulseView icons.
 573 install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
 574 install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)
 575
 576 # Generate Windows installer script.
 577 configure_file(contrib/pulseview_cross.nsi.in ${CMAKE_CURRENT_BINARY_DIR}/contrib/pulseview_cross.nsi @ONLY)
 578
 579 #===============================================================================
 580 #= Packaging (handled by CPack)
 581 #-------------------------------------------------------------------------------
 582
 583 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 584 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 585 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 586 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 587 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 588 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 589 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 590 set(CPACK_SOURCE_GENERATOR "TGZ")
 591
 592 include(CPack)
 593
 594 #===============================================================================
 595 #= Tests
 596 #-------------------------------------------------------------------------------
 597
 598 if(ENABLE_TESTS)
 599         add_subdirectory(test)
 600         enable_testing()
 601         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 602 endif()