CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57       FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrok>=0.2.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  68 endif()
  69
  70 find_package(PkgConfig)
  71 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  72
  73 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  74 find_package(Qt4 REQUIRED)
  75
  76 # Find the platform's thread library (needed for boost-thread).
  77 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  78 find_package(Threads)
  79
  80 if(WIN32)
  81         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  82         # The library is named libboost_thread_win32* (not libboost_thread*).
  83         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  84 else()
  85         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  86 endif()
  87
  88 #===============================================================================
  89 #= Config Header
  90 #-------------------------------------------------------------------------------
  91
  92 set(PV_TITLE PulseView)
  93 set(PV_DESCRIPTION "A GUI for sigrok")
  94
  95 set(PV_VERSION_MAJOR 0)
  96 set(PV_VERSION_MINOR 1)
  97 set(PV_VERSION_MICRO 0)
  98 set(PV_VERSION_STRING
  99         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 100 )
 101
 102 configure_file (
 103         ${PROJECT_SOURCE_DIR}/config.h.in
 104         ${PROJECT_BINARY_DIR}/config.h
 105 )
 106
 107 #===============================================================================
 108 #= Sources
 109 #-------------------------------------------------------------------------------
 110
 111 set(pulseview_SOURCES
 112         main.cpp
 113         pv/devicemanager.cpp
 114         pv/mainwindow.cpp
 115         pv/sigsession.cpp
 116         pv/storesession.cpp
 117         pv/data/analog.cpp
 118         pv/data/analogsnapshot.cpp
 119         pv/data/logic.cpp
 120         pv/data/logicsnapshot.cpp
 121         pv/data/signaldata.cpp
 122         pv/data/snapshot.cpp
 123         pv/dialogs/about.cpp
 124         pv/dialogs/connect.cpp
 125         pv/dialogs/storeprogress.cpp
 126         pv/popups/deviceoptions.cpp
 127         pv/popups/probes.cpp
 128         pv/prop/bool.cpp
 129         pv/prop/double.cpp
 130         pv/prop/enum.cpp
 131         pv/prop/int.cpp
 132         pv/prop/property.cpp
 133         pv/prop/string.cpp
 134         pv/prop/binding/binding.cpp
 135         pv/prop/binding/deviceoptions.cpp
 136         pv/toolbars/samplingbar.cpp
 137         pv/view/analogsignal.cpp
 138         pv/view/cursor.cpp
 139         pv/view/cursorpair.cpp
 140         pv/view/header.cpp
 141         pv/view/marginwidget.cpp
 142         pv/view/logicsignal.cpp
 143         pv/view/ruler.cpp
 144         pv/view/selectableitem.cpp
 145         pv/view/signal.cpp
 146         pv/view/timemarker.cpp
 147         pv/view/trace.cpp
 148         pv/view/tracepalette.cpp
 149         pv/view/view.cpp
 150         pv/view/viewport.cpp
 151         pv/widgets/colourbutton.cpp
 152         pv/widgets/colourpopup.cpp
 153         pv/widgets/popup.cpp
 154         pv/widgets/popuptoolbutton.cpp
 155         pv/widgets/sweeptimingwidget.cpp
 156         pv/widgets/wellarray.cpp
 157 )
 158
 159 # This list includes only QObject derived class headers.
 160 set(pulseview_HEADERS
 161         pv/mainwindow.h
 162         pv/sigsession.h
 163         pv/storesession.h
 164         pv/dialogs/about.h
 165         pv/dialogs/connect.h
 166         pv/dialogs/storeprogress.h
 167         pv/popups/probes.h
 168         pv/popups/deviceoptions.h
 169         pv/prop/bool.h
 170         pv/prop/double.h
 171         pv/prop/enum.h
 172         pv/prop/int.h
 173         pv/prop/property.h
 174         pv/prop/string.h
 175         pv/toolbars/samplingbar.h
 176         pv/view/cursor.h
 177         pv/view/header.h
 178         pv/view/logicsignal.h
 179         pv/view/marginwidget.h
 180         pv/view/ruler.h
 181         pv/view/selectableitem.h
 182         pv/view/signal.h
 183         pv/view/timemarker.h
 184         pv/view/trace.h
 185         pv/view/view.h
 186         pv/view/viewport.h
 187         pv/widgets/colourbutton.h
 188         pv/widgets/colourpopup.h
 189         pv/widgets/popup.h
 190         pv/widgets/popuptoolbutton.h
 191         pv/widgets/sweeptimingwidget.h
 192         pv/widgets/wellarray.h
 193 )
 194
 195 set(pulseview_FORMS
 196         pv/dialogs/about.ui
 197 )
 198
 199 set(pulseview_RESOURCES
 200         pulseview.qrc
 201 )
 202
 203 if(ENABLE_SIGNALS)
 204         list(APPEND pulseview_SOURCES signalhandler.cpp)
 205         list(APPEND pulseview_HEADERS signalhandler.h)
 206 endif()
 207
 208 if(ENABLE_DECODE)
 209         list(APPEND pulseview_SOURCES
 210                 pv/data/decoderstack.cpp
 211                 pv/data/decode/annotation.cpp
 212                 pv/data/decode/decoder.cpp
 213                 pv/data/decode/row.cpp
 214                 pv/data/decode/rowdata.cpp
 215                 pv/prop/binding/decoderoptions.cpp
 216                 pv/view/decodetrace.cpp
 217                 pv/widgets/decodergroupbox.cpp
 218                 pv/widgets/decodermenu.cpp
 219         )
 220
 221         list(APPEND pulseview_HEADERS
 222                 pv/data/decoderstack.h
 223                 pv/view/decodetrace.h
 224                 pv/widgets/decodergroupbox.h
 225                 pv/widgets/decodermenu.h
 226         )
 227 endif()
 228
 229 if(WIN32)
 230         # Use the sigrok icon for the pulseview.exe executable.
 231         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 232         enable_language(RC)
 233         list(APPEND pulseview_SOURCES pulseviewico.rc)
 234 endif()
 235
 236 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 237 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 238 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 239
 240 include(${QT_USE_FILE})
 241
 242 #===============================================================================
 243 #= Global Definitions
 244 #-------------------------------------------------------------------------------
 245
 246 add_definitions(${QT_DEFINITIONS})
 247 add_definitions(-D__STDC_LIMIT_MACROS)
 248 add_definitions(-Wall -Wextra)
 249
 250 if(ENABLE_DECODE)
 251         add_definitions(-DENABLE_DECODE)
 252 endif()
 253
 254 if(NOT DISABLE_WERROR)
 255         add_definitions(-Werror)
 256 endif()
 257
 258 #===============================================================================
 259 #= Global Include Directories
 260 #-------------------------------------------------------------------------------
 261
 262 include_directories(
 263         ${CMAKE_CURRENT_BINARY_DIR}
 264         ${CMAKE_CURRENT_SOURCE_DIR}
 265         ${Boost_INCLUDE_DIRS}
 266 )
 267
 268 if(STATIC_PKGDEPS_LIBS)
 269         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 270 else()
 271         include_directories(${PKGDEPS_INCLUDE_DIRS})
 272 endif()
 273
 274 #===============================================================================
 275 #= Linker Configuration
 276 #-------------------------------------------------------------------------------
 277
 278 link_directories(${Boost_LIBRARY_DIRS})
 279
 280 set(PULSEVIEW_LINK_LIBS
 281         ${Boost_LIBRARIES}
 282         ${CMAKE_THREAD_LIBS_INIT}
 283         ${QT_LIBRARIES}
 284 )
 285
 286 if(STATIC_PKGDEPS_LIBS)
 287         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 288         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 289 if(WIN32)
 290         # Workaround for a MinGW linking issue.
 291         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 292 endif()
 293 else()
 294         link_directories(${PKGDEPS_LIBRARY_DIRS})
 295         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 296 endif()
 297
 298 if(WIN32)
 299         # On Windows we need to statically link the libqsvg imageformat
 300         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 301         add_definitions(-DQT_STATICPLUGIN)
 302         link_directories("${QT_PLUGINS_DIR}/imageformats")
 303         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 304         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 305 endif()
 306
 307 add_executable(${PROJECT_NAME}
 308         ${pulseview_SOURCES}
 309         ${pulseview_HEADERS_MOC}
 310         ${pulseview_FORMS_HEADERS}
 311         ${pulseview_RESOURCES_RCC}
 312 )
 313
 314 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 315
 316 if(WIN32)
 317         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 318         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 319 endif()
 320
 321 if(ENABLE_COTIRE)
 322         include(cotire)
 323         cotire(${PROJECT_NAME})
 324 endif()
 325
 326 #===============================================================================
 327 #= Installation
 328 #-------------------------------------------------------------------------------
 329
 330 # Install the executable.
 331 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 332
 333 # Install the manpage.
 334 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 335
 336 #===============================================================================
 337 #= Packaging (handled by CPack)
 338 #-------------------------------------------------------------------------------
 339
 340 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 341 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 342 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 343 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 344 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 345 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 346 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 347         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 348 set(CPACK_SOURCE_GENERATOR "TGZ")
 349
 350 include(CPack)
 351
 352 #===============================================================================
 353 #= Tests
 354 #-------------------------------------------------------------------------------
 355
 356 if(ENABLE_TESTS)
 357         add_subdirectory(test)
 358         enable_testing()
 359         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 360 endif()