CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57       FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrok>=0.2.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  68 endif()
  69
  70 find_package(PkgConfig)
  71 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  72
  73 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  74 find_package(Qt4 REQUIRED)
  75
  76 # Find the platform's thread library (needed for boost-thread).
  77 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  78 find_package(Threads)
  79
  80 if(WIN32)
  81         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  82         # The library is named libboost_thread_win32* (not libboost_thread*).
  83         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  84 else()
  85         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  86 endif()
  87
  88 #===============================================================================
  89 #= System Introspection
  90 #-------------------------------------------------------------------------------
  91
  92 include(memaccess)
  93 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
  94
  95 #===============================================================================
  96 #= Config Header
  97 #-------------------------------------------------------------------------------
  98
  99 set(PV_TITLE PulseView)
 100 set(PV_DESCRIPTION "A GUI for sigrok")
 101
 102 set(PV_VERSION_MAJOR 0)
 103 set(PV_VERSION_MINOR 1)
 104 set(PV_VERSION_MICRO 0)
 105 set(PV_VERSION_STRING
 106         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 107 )
 108
 109 configure_file (
 110         ${PROJECT_SOURCE_DIR}/config.h.in
 111         ${PROJECT_BINARY_DIR}/config.h
 112 )
 113
 114 #===============================================================================
 115 #= Sources
 116 #-------------------------------------------------------------------------------
 117
 118 set(pulseview_SOURCES
 119         main.cpp
 120         pv/devicemanager.cpp
 121         pv/devinst.cpp
 122         pv/mainwindow.cpp
 123         pv/sigsession.cpp
 124         pv/storesession.cpp
 125         pv/data/analog.cpp
 126         pv/data/analogsnapshot.cpp
 127         pv/data/logic.cpp
 128         pv/data/logicsnapshot.cpp
 129         pv/data/signaldata.cpp
 130         pv/data/snapshot.cpp
 131         pv/dialogs/about.cpp
 132         pv/dialogs/connect.cpp
 133         pv/dialogs/storeprogress.cpp
 134         pv/popups/deviceoptions.cpp
 135         pv/popups/probes.cpp
 136         pv/prop/bool.cpp
 137         pv/prop/double.cpp
 138         pv/prop/enum.cpp
 139         pv/prop/int.cpp
 140         pv/prop/property.cpp
 141         pv/prop/string.cpp
 142         pv/prop/binding/binding.cpp
 143         pv/prop/binding/deviceoptions.cpp
 144         pv/toolbars/samplingbar.cpp
 145         pv/view/analogsignal.cpp
 146         pv/view/cursor.cpp
 147         pv/view/cursorpair.cpp
 148         pv/view/header.cpp
 149         pv/view/marginwidget.cpp
 150         pv/view/logicsignal.cpp
 151         pv/view/ruler.cpp
 152         pv/view/selectableitem.cpp
 153         pv/view/signal.cpp
 154         pv/view/timemarker.cpp
 155         pv/view/trace.cpp
 156         pv/view/tracepalette.cpp
 157         pv/view/view.cpp
 158         pv/view/viewport.cpp
 159         pv/widgets/colourbutton.cpp
 160         pv/widgets/colourpopup.cpp
 161         pv/widgets/popup.cpp
 162         pv/widgets/popuptoolbutton.cpp
 163         pv/widgets/sweeptimingwidget.cpp
 164         pv/widgets/wellarray.cpp
 165 )
 166
 167 # This list includes only QObject derived class headers.
 168 set(pulseview_HEADERS
 169         pv/devinst.h
 170         pv/mainwindow.h
 171         pv/sigsession.h
 172         pv/storesession.h
 173         pv/dialogs/about.h
 174         pv/dialogs/connect.h
 175         pv/dialogs/storeprogress.h
 176         pv/popups/probes.h
 177         pv/popups/deviceoptions.h
 178         pv/prop/bool.h
 179         pv/prop/double.h
 180         pv/prop/enum.h
 181         pv/prop/int.h
 182         pv/prop/property.h
 183         pv/prop/string.h
 184         pv/toolbars/samplingbar.h
 185         pv/view/cursor.h
 186         pv/view/header.h
 187         pv/view/logicsignal.h
 188         pv/view/marginwidget.h
 189         pv/view/ruler.h
 190         pv/view/selectableitem.h
 191         pv/view/signal.h
 192         pv/view/timemarker.h
 193         pv/view/trace.h
 194         pv/view/view.h
 195         pv/view/viewport.h
 196         pv/widgets/colourbutton.h
 197         pv/widgets/colourpopup.h
 198         pv/widgets/popup.h
 199         pv/widgets/popuptoolbutton.h
 200         pv/widgets/sweeptimingwidget.h
 201         pv/widgets/wellarray.h
 202 )
 203
 204 set(pulseview_FORMS
 205         pv/dialogs/about.ui
 206 )
 207
 208 set(pulseview_RESOURCES
 209         pulseview.qrc
 210 )
 211
 212 if(ENABLE_SIGNALS)
 213         list(APPEND pulseview_SOURCES signalhandler.cpp)
 214         list(APPEND pulseview_HEADERS signalhandler.h)
 215 endif()
 216
 217 if(ENABLE_DECODE)
 218         list(APPEND pulseview_SOURCES
 219                 pv/data/decoderstack.cpp
 220                 pv/data/decode/annotation.cpp
 221                 pv/data/decode/decoder.cpp
 222                 pv/data/decode/row.cpp
 223                 pv/data/decode/rowdata.cpp
 224                 pv/prop/binding/decoderoptions.cpp
 225                 pv/view/decodetrace.cpp
 226                 pv/widgets/decodergroupbox.cpp
 227                 pv/widgets/decodermenu.cpp
 228         )
 229
 230         list(APPEND pulseview_HEADERS
 231                 pv/data/decoderstack.h
 232                 pv/view/decodetrace.h
 233                 pv/widgets/decodergroupbox.h
 234                 pv/widgets/decodermenu.h
 235         )
 236 endif()
 237
 238 if(WIN32)
 239         # Use the sigrok icon for the pulseview.exe executable.
 240         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 241         enable_language(RC)
 242         list(APPEND pulseview_SOURCES pulseviewico.rc)
 243 endif()
 244
 245 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 246 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 247 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 248
 249 include(${QT_USE_FILE})
 250
 251 #===============================================================================
 252 #= Global Definitions
 253 #-------------------------------------------------------------------------------
 254
 255 add_definitions(${QT_DEFINITIONS})
 256 add_definitions(-D__STDC_LIMIT_MACROS)
 257 add_definitions(-Wall -Wextra)
 258
 259 if(ENABLE_DECODE)
 260         add_definitions(-DENABLE_DECODE)
 261 endif()
 262
 263 if(NOT DISABLE_WERROR)
 264         add_definitions(-Werror)
 265 endif()
 266
 267 #===============================================================================
 268 #= Global Include Directories
 269 #-------------------------------------------------------------------------------
 270
 271 include_directories(
 272         ${CMAKE_CURRENT_BINARY_DIR}
 273         ${CMAKE_CURRENT_SOURCE_DIR}
 274         ${Boost_INCLUDE_DIRS}
 275 )
 276
 277 if(STATIC_PKGDEPS_LIBS)
 278         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 279 else()
 280         include_directories(${PKGDEPS_INCLUDE_DIRS})
 281 endif()
 282
 283 #===============================================================================
 284 #= Linker Configuration
 285 #-------------------------------------------------------------------------------
 286
 287 link_directories(${Boost_LIBRARY_DIRS})
 288
 289 set(PULSEVIEW_LINK_LIBS
 290         ${Boost_LIBRARIES}
 291         ${CMAKE_THREAD_LIBS_INIT}
 292         ${QT_LIBRARIES}
 293 )
 294
 295 if(STATIC_PKGDEPS_LIBS)
 296         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 297         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 298 if(WIN32)
 299         # Workaround for a MinGW linking issue.
 300         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 301 endif()
 302 else()
 303         link_directories(${PKGDEPS_LIBRARY_DIRS})
 304         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 305 endif()
 306
 307 if(WIN32)
 308         # On Windows we need to statically link the libqsvg imageformat
 309         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 310         add_definitions(-DQT_STATICPLUGIN)
 311         link_directories("${QT_PLUGINS_DIR}/imageformats")
 312         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 313         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 314 endif()
 315
 316 add_executable(${PROJECT_NAME}
 317         ${pulseview_SOURCES}
 318         ${pulseview_HEADERS_MOC}
 319         ${pulseview_FORMS_HEADERS}
 320         ${pulseview_RESOURCES_RCC}
 321 )
 322
 323 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 324
 325 if(WIN32)
 326         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 327         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 328 endif()
 329
 330 if(ENABLE_COTIRE)
 331         include(cotire)
 332         cotire(${PROJECT_NAME})
 333 endif()
 334
 335 #===============================================================================
 336 #= Installation
 337 #-------------------------------------------------------------------------------
 338
 339 # Install the executable.
 340 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 341
 342 # Install the manpage.
 343 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 344
 345 #===============================================================================
 346 #= Packaging (handled by CPack)
 347 #-------------------------------------------------------------------------------
 348
 349 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 350 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 351 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 352 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 353 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 354 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 355 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 356         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 357 set(CPACK_SOURCE_GENERATOR "TGZ")
 358
 359 include(CPack)
 360
 361 #===============================================================================
 362 #= Tests
 363 #-------------------------------------------------------------------------------
 364
 365 if(ENABLE_TESTS)
 366         add_subdirectory(test)
 367         enable_testing()
 368         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 369 endif()