CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23 include(GNUInstallDirs)
  24
  25 project(pulseview)
  26
  27 #===============================================================================
  28 #= User Options
  29 #-------------------------------------------------------------------------------
  30
  31 option(DISABLE_WERROR "Build without -Werror" FALSE)
  32 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  33 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  34 option(ENABLE_TESTS "Enable unit tests" FALSE)
  35 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  36
  37 if(WIN32)
  38         # On Windows/MinGW we need to statically link to libraries.
  39         # This option is user configurable, but enable it by default on win32.
  40         set(STATIC_PKGDEPS_LIBS TRUE)
  41
  42         # For boost-thread we need two additional settings on win32:
  43         set(Boost_USE_STATIC_LIBS on)
  44         add_definitions(-DBOOST_THREAD_USE_LIB)
  45
  46         # Windsws does not support UNIX signals
  47         set(ENABLE_SIGNALS FALSE)
  48 endif()
  49
  50 #===============================================================================
  51 #= Dependencies
  52 #-------------------------------------------------------------------------------
  53
  54 list(APPEND PKGDEPS
  55         libsigrok>=0.2.0
  56 )
  57
  58 if(ENABLE_SIGROKDECODE)
  59         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  60 endif()
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 find_package(Qt4 REQUIRED)
  66
  67 # Find the platform's thread library (needed for boost-thread).
  68 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  69 find_package(Threads)
  70
  71 if(WIN32)
  72 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  73 # The library is named libboost_thread_win32* (not libboost_thread*).
  74 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  75 else()
  76 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  77 endif()
  78
  79 #===============================================================================
  80 #= Config Header
  81 #-------------------------------------------------------------------------------
  82
  83 set(PV_TITLE PulseView)
  84 set(PV_DESCRIPTION "A GUI for sigrok")
  85
  86 set(PV_VERSION_MAJOR 0)
  87 set(PV_VERSION_MINOR 1)
  88 set(PV_VERSION_MICRO 0)
  89 set(PV_VERSION_STRING
  90         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  91 )
  92
  93 configure_file (
  94         ${PROJECT_SOURCE_DIR}/config.h.in
  95         ${PROJECT_BINARY_DIR}/config.h
  96 )
  97
  98 #===============================================================================
  99 #= Sources
 100 #-------------------------------------------------------------------------------
 101
 102 set(pulseview_SOURCES
 103         main.cpp
 104         pv/devicemanager.cpp
 105         pv/mainwindow.cpp
 106         pv/sigsession.cpp
 107         pv/data/analog.cpp
 108         pv/data/analogsnapshot.cpp
 109         pv/data/logic.cpp
 110         pv/data/logicsnapshot.cpp
 111         pv/data/signaldata.cpp
 112         pv/data/snapshot.cpp
 113         pv/dialogs/about.cpp
 114         pv/dialogs/connect.cpp
 115         pv/dialogs/deviceoptions.cpp
 116         pv/prop/bool.cpp
 117         pv/prop/double.cpp
 118         pv/prop/enum.cpp
 119         pv/prop/int.cpp
 120         pv/prop/property.cpp
 121         pv/prop/binding/binding.cpp
 122         pv/prop/binding/deviceoptions.cpp
 123         pv/toolbars/contextbar.cpp
 124         pv/toolbars/samplingbar.cpp
 125         pv/view/analogsignal.cpp
 126         pv/view/cursor.cpp
 127         pv/view/cursorpair.cpp
 128         pv/view/header.cpp
 129         pv/view/marginwidget.cpp
 130         pv/view/logicsignal.cpp
 131         pv/view/ruler.cpp
 132         pv/view/selectableitem.cpp
 133         pv/view/signal.cpp
 134         pv/view/timemarker.cpp
 135         pv/view/view.cpp
 136         pv/view/viewport.cpp
 137 )
 138
 139 set(pulseview_HEADERS
 140         pv/mainwindow.h
 141         pv/sigsession.h
 142         pv/dialogs/about.h
 143         pv/dialogs/connect.h
 144         pv/dialogs/deviceoptions.h
 145         pv/toolbars/contextbar.h
 146         pv/toolbars/samplingbar.h
 147         pv/view/cursor.h
 148         pv/view/header.h
 149         pv/view/marginwidget.h
 150         pv/view/ruler.h
 151         pv/view/selectableitem.h
 152         pv/view/signal.h
 153         pv/view/timemarker.h
 154         pv/view/view.h
 155         pv/view/viewport.h
 156 )
 157
 158 set(pulseview_FORMS
 159         pv/dialogs/about.ui
 160 )
 161
 162 set(pulseview_RESOURCES
 163         pulseview.qrc
 164 )
 165
 166 if(ENABLE_SIGNALS)
 167         list(APPEND pulseview_SOURCES signalhandler.cpp)
 168         list(APPEND pulseview_HEADERS signalhandler.h)
 169 endif()
 170
 171 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 172 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 173 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 174
 175 include(${QT_USE_FILE})
 176
 177 #===============================================================================
 178 #= Global Definitions
 179 #-------------------------------------------------------------------------------
 180
 181 add_definitions(${QT_DEFINITIONS})
 182 add_definitions(-Wall -Wextra)
 183
 184 if(ENABLE_SIGROKDECODE)
 185         add_definitions(-DENABLE_SIGROKDECODE)
 186 endif()
 187
 188 if(NOT DISABLE_WERROR)
 189         add_definitions(-Werror)
 190 endif()
 191
 192 #===============================================================================
 193 #= Global Include Directories
 194 #-------------------------------------------------------------------------------
 195
 196 include_directories(
 197         ${CMAKE_CURRENT_BINARY_DIR}
 198         ${CMAKE_CURRENT_SOURCE_DIR}
 199         ${Boost_INCLUDE_DIRS}
 200 )
 201
 202 if(STATIC_PKGDEPS_LIBS)
 203         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 204 else()
 205         include_directories(${PKGDEPS_INCLUDE_DIRS})
 206 endif()
 207
 208 #===============================================================================
 209 #= Linker Configuration
 210 #-------------------------------------------------------------------------------
 211
 212 link_directories(${Boost_LIBRARY_DIRS})
 213
 214 set(PULSEVIEW_LINK_LIBS
 215         ${Boost_LIBRARIES}
 216         ${CMAKE_THREAD_LIBS_INIT}
 217         ${QT_LIBRARIES}
 218 )
 219
 220 if(STATIC_PKGDEPS_LIBS)
 221         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 222         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 223 else()
 224         link_directories(${PKGDEPS_LIBRARY_DIRS})
 225         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 226 endif()
 227
 228 add_executable(${PROJECT_NAME}
 229         ${pulseview_SOURCES}
 230         ${pulseview_HEADERS_MOC}
 231         ${pulseview_FORMS_HEADERS}
 232         ${pulseview_RESOURCES_RCC}
 233 )
 234
 235 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 236
 237 if(WIN32)
 238 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 239 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 240 endif()
 241
 242 #===============================================================================
 243 #= Installation
 244 #-------------------------------------------------------------------------------
 245
 246 # Install the executable.
 247 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 248
 249 # Install the manpage.
 250 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 251
 252 #===============================================================================
 253 #= Packaging (handled by CPack)
 254 #-------------------------------------------------------------------------------
 255
 256 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 257 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 258 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 259 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 260 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 261 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 262 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 263         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 264 set(CPACK_SOURCE_GENERATOR "TGZ")
 265
 266 include(CPack)
 267
 268 #===============================================================================
 269 #= Tests
 270 #-------------------------------------------------------------------------------
 271
 272 if(ENABLE_TESTS)
 273         add_subdirectory(test)
 274         enable_testing()
 275         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 276 endif(ENABLE_TESTS)