CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  32 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  33 option(ENABLE_TESTS "Enable unit tests" FALSE)
  34 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  35
  36 if(WIN32)
  37         # On Windows/MinGW we need to statically link to libraries.
  38         # This option is user configurable, but enable it by default on win32.
  39         set(STATIC_PKGDEPS_LIBS TRUE)
  40
  41         # For boost-thread we need two additional settings on win32:
  42         set(Boost_USE_STATIC_LIBS on)
  43         add_definitions(-DBOOST_THREAD_USE_LIB)
  44
  45         # Windsws does not support UNIX signals
  46         set(ENABLE_SIGNALS FALSE)
  47 endif()
  48
  49 #===============================================================================
  50 #= Dependencies
  51 #-------------------------------------------------------------------------------
  52
  53 list(APPEND PKGDEPS
  54         libsigrok>=0.2.0
  55 )
  56
  57 if(ENABLE_SIGROKDECODE)
  58         list(APPEND PKGDEPS libsigrokdecode>=0.1.0)
  59 endif()
  60
  61 find_package(PkgConfig)
  62 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  63
  64 find_package(Qt4 REQUIRED)
  65
  66 # Find the platform's thread library (needed for boost-thread).
  67 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  68 find_package(Threads)
  69
  70 if(WIN32)
  71 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  72 # The library is named libboost_thread_win32* (not libboost_thread*).
  73 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  74 else()
  75 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  76 endif()
  77
  78 #===============================================================================
  79 #= Config Header
  80 #-------------------------------------------------------------------------------
  81
  82 set(PV_TITLE PulseView)
  83 set(PV_DESCRIPTION "A GUI for sigrok")
  84
  85 set(PV_VERSION_MAJOR 0)
  86 set(PV_VERSION_MINOR 1)
  87 set(PV_VERSION_MICRO 0)
  88 set(PV_VERSION_STRING
  89         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  90 )
  91
  92 configure_file (
  93         ${PROJECT_SOURCE_DIR}/config.h.in
  94         ${PROJECT_BINARY_DIR}/config.h
  95 )
  96
  97 #===============================================================================
  98 #= Sources
  99 #-------------------------------------------------------------------------------
 100
 101 set(pulseview_SOURCES
 102         main.cpp
 103         pv/mainwindow.cpp
 104         pv/sigsession.cpp
 105         pv/data/analog.cpp
 106         pv/data/analogsnapshot.cpp
 107         pv/data/logic.cpp
 108         pv/data/logicsnapshot.cpp
 109         pv/data/signaldata.cpp
 110         pv/data/snapshot.cpp
 111         pv/dialogs/about.cpp
 112         pv/dialogs/connect.cpp
 113         pv/dialogs/deviceoptions.cpp
 114         pv/prop/bool.cpp
 115         pv/prop/double.cpp
 116         pv/prop/enum.cpp
 117         pv/prop/int.cpp
 118         pv/prop/property.cpp
 119         pv/prop/binding/binding.cpp
 120         pv/prop/binding/deviceoptions.cpp
 121         pv/toolbars/samplingbar.cpp
 122         pv/view/analogsignal.cpp
 123         pv/view/cursor.cpp
 124         pv/view/cursorpair.cpp
 125         pv/view/header.cpp
 126         pv/view/logicsignal.cpp
 127         pv/view/ruler.cpp
 128         pv/view/signal.cpp
 129         pv/view/timemarker.cpp
 130         pv/view/view.cpp
 131         pv/view/viewport.cpp
 132 )
 133
 134 set(pulseview_HEADERS
 135         pv/mainwindow.h
 136         pv/sigsession.h
 137         pv/dialogs/about.h
 138         pv/dialogs/connect.h
 139         pv/dialogs/deviceoptions.h
 140         pv/toolbars/samplingbar.h
 141         pv/view/cursor.h
 142         pv/view/header.h
 143         pv/view/ruler.h
 144         pv/view/timemarker.h
 145         pv/view/view.h
 146         pv/view/viewport.h
 147 )
 148
 149 set(pulseview_FORMS
 150         pv/dialogs/about.ui
 151 )
 152
 153 set(pulseview_RESOURCES
 154         pulseview.qrc
 155 )
 156
 157 if(ENABLE_SIGNALS)
 158         list(APPEND pulseview_SOURCES signalhandler.cpp)
 159         list(APPEND pulseview_HEADERS signalhandler.h)
 160 endif()
 161
 162 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 163 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 164 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 165
 166 include(${QT_USE_FILE})
 167
 168 #===============================================================================
 169 #= Global Definitions
 170 #-------------------------------------------------------------------------------
 171
 172 add_definitions(${QT_DEFINITIONS})
 173 add_definitions(-Wall -Wextra)
 174
 175 if(ENABLE_SIGROKDECODE)
 176         add_definitions(-DENABLE_SIGROKDECODE)
 177 endif()
 178
 179 if(NOT DISABLE_WERROR)
 180         add_definitions(-Werror)
 181 endif()
 182
 183 #===============================================================================
 184 #= Global Include Directories
 185 #-------------------------------------------------------------------------------
 186
 187 include_directories(
 188         ${CMAKE_CURRENT_BINARY_DIR}
 189         ${CMAKE_CURRENT_SOURCE_DIR}
 190         ${Boost_INCLUDE_DIRS}
 191 )
 192
 193 if(STATIC_PKGDEPS_LIBS)
 194         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 195 else()
 196         include_directories(${PKGDEPS_INCLUDE_DIRS})
 197 endif()
 198
 199 #===============================================================================
 200 #= Linker Configuration
 201 #-------------------------------------------------------------------------------
 202
 203 link_directories(${Boost_LIBRARY_DIRS})
 204
 205 set(PULSEVIEW_LINK_LIBS
 206         ${Boost_LIBRARIES}
 207         ${CMAKE_THREAD_LIBS_INIT}
 208         ${QT_LIBRARIES}
 209 )
 210
 211 if(STATIC_PKGDEPS_LIBS)
 212         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 213         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 214 else()
 215         link_directories(${PKGDEPS_LIBRARY_DIRS})
 216         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 217 endif()
 218
 219 add_executable(${PROJECT_NAME}
 220         ${pulseview_SOURCES}
 221         ${pulseview_HEADERS_MOC}
 222         ${pulseview_FORMS_HEADERS}
 223         ${pulseview_RESOURCES_RCC}
 224 )
 225
 226 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 227
 228 if(WIN32)
 229 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 230 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 231 endif()
 232
 233 #===============================================================================
 234 #= Installation
 235 #-------------------------------------------------------------------------------
 236
 237 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 238
 239 #===============================================================================
 240 #= Packaging (handled by CPack)
 241 #-------------------------------------------------------------------------------
 242
 243 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 244 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 245 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 246 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 247 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 248 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 249 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 250         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 251 set(CPACK_SOURCE_GENERATOR "TGZ")
 252
 253 include(CPack)
 254
 255 #===============================================================================
 256 #= Tests
 257 #-------------------------------------------------------------------------------
 258
 259 if(ENABLE_TESTS)
 260         add_subdirectory(test)
 261         enable_testing()
 262         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 263 endif(ENABLE_TESTS)