CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27 include(cotire)
  28
  29 project(pulseview)
  30
  31 #===============================================================================
  32 #= User Options
  33 #-------------------------------------------------------------------------------
  34
  35 option(DISABLE_WERROR "Build without -Werror" FALSE)
  36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  39
  40 if(WIN32)
  41         # On Windows/MinGW we need to statically link to libraries.
  42         # This option is user configurable, but enable it by default on win32.
  43         set(STATIC_PKGDEPS_LIBS TRUE)
  44
  45         # For boost-thread we need two additional settings on win32:
  46         set(Boost_USE_STATIC_LIBS on)
  47         add_definitions(-DBOOST_THREAD_USE_LIB)
  48
  49         # Windsws does not support UNIX signals
  50         set(ENABLE_SIGNALS FALSE)
  51 endif()
  52
  53 #===============================================================================
  54 #= Dependencies
  55 #-------------------------------------------------------------------------------
  56
  57 list(APPEND PKGDEPS
  58         libsigrok>=0.2.0
  59         libsigrokdecode>=0.2.0
  60 )
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  66 find_package(Qt4 REQUIRED)
  67
  68 # Find the platform's thread library (needed for boost-thread).
  69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  70 find_package(Threads)
  71
  72 if(WIN32)
  73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  74 # The library is named libboost_thread_win32* (not libboost_thread*).
  75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  76 else()
  77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  78 endif()
  79
  80 #===============================================================================
  81 #= Config Header
  82 #-------------------------------------------------------------------------------
  83
  84 set(PV_TITLE PulseView)
  85 set(PV_DESCRIPTION "A GUI for sigrok")
  86
  87 set(PV_VERSION_MAJOR 0)
  88 set(PV_VERSION_MINOR 1)
  89 set(PV_VERSION_MICRO 0)
  90 set(PV_VERSION_STRING
  91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  92 )
  93
  94 configure_file (
  95         ${PROJECT_SOURCE_DIR}/config.h.in
  96         ${PROJECT_BINARY_DIR}/config.h
  97 )
  98
  99 #===============================================================================
 100 #= Sources
 101 #-------------------------------------------------------------------------------
 102
 103 set(pulseview_SOURCES
 104         main.cpp
 105         pv/devicemanager.cpp
 106         pv/mainwindow.cpp
 107         pv/sigsession.cpp
 108         pv/data/analog.cpp
 109         pv/data/analogsnapshot.cpp
 110         pv/data/decoder.cpp
 111         pv/data/logic.cpp
 112         pv/data/logicsnapshot.cpp
 113         pv/data/signaldata.cpp
 114         pv/data/snapshot.cpp
 115         pv/dialogs/about.cpp
 116         pv/dialogs/connect.cpp
 117         pv/dialogs/decoder.cpp
 118         pv/dialogs/deviceoptions.cpp
 119         pv/prop/bool.cpp
 120         pv/prop/double.cpp
 121         pv/prop/enum.cpp
 122         pv/prop/int.cpp
 123         pv/prop/property.cpp
 124         pv/prop/string.cpp
 125         pv/prop/binding/binding.cpp
 126         pv/prop/binding/decoderoptions.cpp
 127         pv/prop/binding/deviceoptions.cpp
 128         pv/toolbars/samplingbar.cpp
 129         pv/view/analogsignal.cpp
 130         pv/view/cursor.cpp
 131         pv/view/cursorpair.cpp
 132         pv/view/decodesignal.cpp
 133         pv/view/header.cpp
 134         pv/view/marginwidget.cpp
 135         pv/view/logicsignal.cpp
 136         pv/view/ruler.cpp
 137         pv/view/selectableitem.cpp
 138         pv/view/signal.cpp
 139         pv/view/timemarker.cpp
 140         pv/view/trace.cpp
 141         pv/view/view.cpp
 142         pv/view/viewport.cpp
 143         pv/view/decode/annotation.cpp
 144         pv/widgets/popup.cpp
 145 )
 146
 147 # This list includes only QObject derrived class headers
 148 set(pulseview_HEADERS
 149         pv/mainwindow.h
 150         pv/sigsession.h
 151         pv/data/decoder.h
 152         pv/dialogs/about.h
 153         pv/dialogs/connect.h
 154         pv/dialogs/deviceoptions.h
 155         pv/toolbars/samplingbar.h
 156         pv/view/cursor.h
 157         pv/view/decodesignal.h
 158         pv/view/header.h
 159         pv/view/logicsignal.h
 160         pv/view/marginwidget.h
 161         pv/view/ruler.h
 162         pv/view/selectableitem.h
 163         pv/view/signal.h
 164         pv/view/timemarker.h
 165         pv/view/trace.h
 166         pv/view/view.h
 167         pv/view/viewport.h
 168 )
 169
 170 set(pulseview_FORMS
 171         pv/dialogs/about.ui
 172 )
 173
 174 set(pulseview_RESOURCES
 175         pulseview.qrc
 176 )
 177
 178 if(ENABLE_SIGNALS)
 179         list(APPEND pulseview_SOURCES signalhandler.cpp)
 180         list(APPEND pulseview_HEADERS signalhandler.h)
 181 endif()
 182
 183 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 184 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 185 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 186
 187 include(${QT_USE_FILE})
 188
 189 #===============================================================================
 190 #= Global Definitions
 191 #-------------------------------------------------------------------------------
 192
 193 add_definitions(${QT_DEFINITIONS})
 194 add_definitions(-Wall -Wextra)
 195
 196 if(NOT DISABLE_WERROR)
 197         add_definitions(-Werror)
 198 endif()
 199
 200 #===============================================================================
 201 #= Global Include Directories
 202 #-------------------------------------------------------------------------------
 203
 204 include_directories(
 205         ${CMAKE_CURRENT_BINARY_DIR}
 206         ${CMAKE_CURRENT_SOURCE_DIR}
 207         ${Boost_INCLUDE_DIRS}
 208 )
 209
 210 if(STATIC_PKGDEPS_LIBS)
 211         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 212 else()
 213         include_directories(${PKGDEPS_INCLUDE_DIRS})
 214 endif()
 215
 216 #===============================================================================
 217 #= Linker Configuration
 218 #-------------------------------------------------------------------------------
 219
 220 link_directories(${Boost_LIBRARY_DIRS})
 221
 222 set(PULSEVIEW_LINK_LIBS
 223         ${Boost_LIBRARIES}
 224         ${CMAKE_THREAD_LIBS_INIT}
 225         ${QT_LIBRARIES}
 226 )
 227
 228 if(STATIC_PKGDEPS_LIBS)
 229         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 230         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 231 else()
 232         link_directories(${PKGDEPS_LIBRARY_DIRS})
 233         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 234 endif()
 235
 236 add_executable(${PROJECT_NAME}
 237         ${pulseview_SOURCES}
 238         ${pulseview_HEADERS_MOC}
 239         ${pulseview_FORMS_HEADERS}
 240         ${pulseview_RESOURCES_RCC}
 241 )
 242
 243 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 244 cotire(${PROJECT_NAME})
 245
 246 if(WIN32)
 247 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 248 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 249 endif()
 250
 251 #===============================================================================
 252 #= Installation
 253 #-------------------------------------------------------------------------------
 254
 255 # Install the executable.
 256 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 257
 258 # Install the manpage.
 259 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 260
 261 #===============================================================================
 262 #= Packaging (handled by CPack)
 263 #-------------------------------------------------------------------------------
 264
 265 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 266 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 267 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 268 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 269 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 270 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 271 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 272         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 273 set(CPACK_SOURCE_GENERATOR "TGZ")
 274
 275 include(CPack)
 276
 277 #===============================================================================
 278 #= Tests
 279 #-------------------------------------------------------------------------------
 280
 281 if(ENABLE_TESTS)
 282         add_subdirectory(test)
 283         enable_testing()
 284         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 285 endif(ENABLE_TESTS)