CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.4.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.4.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.48 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.48 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124 set(PV_VERSION_STRING "0.3.0")
 125
 126 include(GetGitRevisionDescription)
 127 git_describe(PV_TAG_VERSION_STRING --tags --dirty)
 128
 129 if(NOT PV_TAG_VERSION_STRING AND EXISTS "${PROJECT_SOURCE_DIR}/VERSION")
 130         # Read the version from a file that is distributed with
 131         # the source package (see writepackageversion.cmake).
 132         file(STRINGS "${PROJECT_SOURCE_DIR}/VERSION" PV_TAG_VERSION_STRING LIMIT_COUNT 1)
 133 endif()
 134
 135 if(PV_TAG_VERSION_STRING MATCHES
 136                 "^pulseview-([0-9]+\\.[0-9]+\\.[0-9]+)(-[0-9a-z]+)?(-g[-0-9a-z]+)?$")
 137         set(PV_TAG_VERSION ${CMAKE_MATCH_1})
 138         set(PV_TAG_PATCHLEVEL ${CMAKE_MATCH_2})
 139         set(PV_TAG_REVHASH ${CMAKE_MATCH_3})
 140
 141         if(PV_VERSION_STRING VERSION_GREATER ${PV_TAG_VERSION})
 142                 # Tagged version older than current one: indicate pre-release.
 143                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-pre${PV_TAG_REVHASH}")
 144         else()
 145                 # For post-release changes, indicate the patch level.
 146                 set(PV_VERSION_STRING "${PV_TAG_VERSION}${PV_TAG_PATCHLEVEL}${PV_TAG_REVHASH}")
 147         endif()
 148 endif()
 149
 150 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
 151         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 152         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 153         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 154         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 155 endif()
 156
 157 message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
 158
 159 configure_file (
 160         ${PROJECT_SOURCE_DIR}/config.h.in
 161         ${PROJECT_BINARY_DIR}/config.h
 162 )
 163
 164 #===============================================================================
 165 #= Sources
 166 #-------------------------------------------------------------------------------
 167
 168 set(pulseview_SOURCES
 169         main.cpp
 170         pv/application.cpp
 171         pv/devicemanager.cpp
 172         pv/mainwindow.cpp
 173         pv/session.cpp
 174         pv/storesession.cpp
 175         pv/util.cpp
 176         pv/binding/binding.cpp
 177         pv/binding/inputoutput.cpp
 178         pv/binding/device.cpp
 179         pv/data/analog.cpp
 180         pv/data/analogsegment.cpp
 181         pv/data/logic.cpp
 182         pv/data/logicsegment.cpp
 183         pv/data/signaldata.cpp
 184         pv/data/segment.cpp
 185         pv/devices/device.cpp
 186         pv/devices/file.cpp
 187         pv/devices/hardwaredevice.cpp
 188         pv/devices/inputfile.cpp
 189         pv/devices/sessionfile.cpp
 190         pv/dialogs/about.cpp
 191         pv/dialogs/connect.cpp
 192         pv/dialogs/inputoutputoptions.cpp
 193         pv/dialogs/storeprogress.cpp
 194         pv/popups/deviceoptions.cpp
 195         pv/popups/channels.cpp
 196         pv/prop/bool.cpp
 197         pv/prop/double.cpp
 198         pv/prop/enum.cpp
 199         pv/prop/int.cpp
 200         pv/prop/property.cpp
 201         pv/prop/string.cpp
 202         pv/toolbars/mainbar.cpp
 203         pv/view/analogsignal.cpp
 204         pv/view/cursor.cpp
 205         pv/view/cursorpair.cpp
 206         pv/view/flag.cpp
 207         pv/view/header.cpp
 208         pv/view/marginwidget.cpp
 209         pv/view/logicsignal.cpp
 210         pv/view/rowitem.cpp
 211         pv/view/rowitemowner.cpp
 212         pv/view/ruler.cpp
 213         pv/view/signal.cpp
 214         pv/view/timeitem.cpp
 215         pv/view/timemarker.cpp
 216         pv/view/trace.cpp
 217         pv/view/tracegroup.cpp
 218         pv/view/tracepalette.cpp
 219         pv/view/view.cpp
 220         pv/view/viewitem.cpp
 221         pv/view/viewitempaintparams.cpp
 222         pv/view/viewport.cpp
 223         pv/view/viewwidget.cpp
 224         pv/widgets/colourbutton.cpp
 225         pv/widgets/colourpopup.cpp
 226         pv/widgets/devicetoolbutton.cpp
 227         pv/widgets/exportmenu.cpp
 228         pv/widgets/hidingmenubar.cpp
 229         pv/widgets/importmenu.cpp
 230         pv/widgets/popup.cpp
 231         pv/widgets/popuptoolbutton.cpp
 232         pv/widgets/sweeptimingwidget.cpp
 233         pv/widgets/timestampspinbox.cpp
 234         pv/widgets/wellarray.cpp
 235 )
 236
 237 # This list includes only QObject derived class headers.
 238 set(pulseview_HEADERS
 239         pv/mainwindow.hpp
 240         pv/session.hpp
 241         pv/storesession.hpp
 242         pv/binding/device.hpp
 243         pv/dialogs/about.hpp
 244         pv/dialogs/connect.hpp
 245         pv/dialogs/inputoutputoptions.hpp
 246         pv/dialogs/storeprogress.hpp
 247         pv/popups/channels.hpp
 248         pv/popups/deviceoptions.hpp
 249         pv/prop/bool.hpp
 250         pv/prop/double.hpp
 251         pv/prop/enum.hpp
 252         pv/prop/int.hpp
 253         pv/prop/property.hpp
 254         pv/prop/string.hpp
 255         pv/toolbars/mainbar.hpp
 256         pv/view/cursor.hpp
 257         pv/view/flag.hpp
 258         pv/view/header.hpp
 259         pv/view/logicsignal.hpp
 260         pv/view/marginwidget.hpp
 261         pv/view/rowitem.hpp
 262         pv/view/ruler.hpp
 263         pv/view/signal.hpp
 264         pv/view/timeitem.hpp
 265         pv/view/timemarker.hpp
 266         pv/view/trace.hpp
 267         pv/view/tracegroup.hpp
 268         pv/view/view.hpp
 269         pv/view/viewitem.hpp
 270         pv/view/viewport.hpp
 271         pv/view/viewwidget.hpp
 272         pv/widgets/colourbutton.hpp
 273         pv/widgets/colourpopup.hpp
 274         pv/widgets/devicetoolbutton.hpp
 275         pv/widgets/exportmenu.hpp
 276         pv/widgets/hidingmenubar.hpp
 277         pv/widgets/importmenu.hpp
 278         pv/widgets/popup.hpp
 279         pv/widgets/popuptoolbutton.hpp
 280         pv/widgets/sweeptimingwidget.hpp
 281         pv/widgets/timestampspinbox.hpp
 282         pv/widgets/wellarray.hpp
 283 )
 284
 285 set(pulseview_FORMS
 286         pv/dialogs/about.ui
 287 )
 288
 289 set(pulseview_RESOURCES
 290         pulseview.qrc
 291 )
 292
 293 if(ENABLE_SIGNALS)
 294         list(APPEND pulseview_SOURCES signalhandler.cpp)
 295         list(APPEND pulseview_HEADERS signalhandler.hpp)
 296 endif()
 297
 298 if(ENABLE_DECODE)
 299         list(APPEND pulseview_SOURCES
 300                 pv/binding/decoder.cpp
 301                 pv/data/decoderstack.cpp
 302                 pv/data/decode/annotation.cpp
 303                 pv/data/decode/decoder.cpp
 304                 pv/data/decode/row.cpp
 305                 pv/data/decode/rowdata.cpp
 306                 pv/view/decodetrace.cpp
 307                 pv/widgets/decodergroupbox.cpp
 308                 pv/widgets/decodermenu.cpp
 309         )
 310
 311         list(APPEND pulseview_HEADERS
 312                 pv/data/decoderstack.hpp
 313                 pv/view/decodetrace.hpp
 314                 pv/widgets/decodergroupbox.hpp
 315                 pv/widgets/decodermenu.hpp
 316         )
 317 endif()
 318
 319 if(WIN32)
 320         # Use the sigrok icon for the pulseview.exe executable.
 321         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 322         enable_language(RC)
 323         list(APPEND pulseview_SOURCES pulseviewico.rc)
 324 endif()
 325
 326 if(ANDROID)
 327         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 328 endif()
 329
 330 if(Qt5Core_FOUND)
 331         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 332         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 333         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 334 else()
 335         # Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
 336         # https://bugreports.qt.io/browse/QTBUG-22829
 337         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
 338                 OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
 339         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 340         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 341         include(${QT_USE_FILE})
 342 endif()
 343
 344 #===============================================================================
 345 #= Global Definitions
 346 #-------------------------------------------------------------------------------
 347
 348 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 349 add_definitions(-D__STDC_LIMIT_MACROS)
 350 add_definitions(-Wall -Wextra)
 351 add_definitions(-std=c++11)
 352
 353 if(ENABLE_DECODE)
 354         add_definitions(-DENABLE_DECODE)
 355 endif()
 356
 357 if(NOT DISABLE_WERROR)
 358         add_definitions(-Werror)
 359 endif()
 360
 361 if(ENABLE_SIGNALS)
 362         add_definitions(-DENABLE_SIGNALS)
 363 endif()
 364
 365 #===============================================================================
 366 #= Global Include Directories
 367 #-------------------------------------------------------------------------------
 368
 369 include_directories(
 370         ${CMAKE_CURRENT_BINARY_DIR}
 371         ${CMAKE_CURRENT_SOURCE_DIR}
 372         ${Boost_INCLUDE_DIRS}
 373         ${QT_INCLUDE_DIRS}
 374 )
 375
 376 if(STATIC_PKGDEPS_LIBS)
 377         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 378 else()
 379         include_directories(${PKGDEPS_INCLUDE_DIRS})
 380 endif()
 381
 382 #===============================================================================
 383 #= Linker Configuration
 384 #-------------------------------------------------------------------------------
 385
 386 link_directories(${Boost_LIBRARY_DIRS})
 387
 388 set(PULSEVIEW_LINK_LIBS
 389         ${Boost_LIBRARIES}
 390         ${QT_LIBRARIES}
 391         ${CMAKE_THREAD_LIBS_INIT}
 392 )
 393
 394 if(STATIC_PKGDEPS_LIBS)
 395         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 396         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 397 if(WIN32)
 398         # Workaround for a MinGW linking issue.
 399         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 400 endif()
 401 else()
 402         link_directories(${PKGDEPS_LIBRARY_DIRS})
 403         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 404 endif()
 405
 406 if(WIN32)
 407         # On Windows we need to statically link the libqsvg imageformat
 408         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 409         add_definitions(-DQT_STATICPLUGIN)
 410         link_directories("${QT_PLUGINS_DIR}/imageformats")
 411         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 412         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 413 endif()
 414
 415 if(ANDROID)
 416         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 417 endif()
 418
 419 if(ANDROID)
 420 add_library(${PROJECT_NAME} SHARED
 421         ${pulseview_SOURCES}
 422         ${pulseview_HEADERS_MOC}
 423         ${pulseview_FORMS_HEADERS}
 424         ${pulseview_RESOURCES_RCC}
 425 )
 426 else()
 427 add_executable(${PROJECT_NAME}
 428         ${pulseview_SOURCES}
 429         ${pulseview_HEADERS_MOC}
 430         ${pulseview_FORMS_HEADERS}
 431         ${pulseview_RESOURCES_RCC}
 432 )
 433 endif()
 434
 435 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 436
 437 if(WIN32)
 438         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 439         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 440 endif()
 441
 442 #===============================================================================
 443 #= Installation
 444 #-------------------------------------------------------------------------------
 445
 446 # Install the executable.
 447 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 448
 449 # Install the manpage.
 450 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 451
 452 #===============================================================================
 453 #= Packaging (handled by CPack)
 454 #-------------------------------------------------------------------------------
 455
 456 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 457 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 458 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 459 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 460 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 461 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 462 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 463 set(CPACK_SOURCE_GENERATOR "TGZ")
 464 set(CPACK_INSTALL_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/CMake/writepackageversion.cmake)
 465
 466 include(CPack)
 467
 468 #===============================================================================
 469 #= Tests
 470 #-------------------------------------------------------------------------------
 471
 472 if(ENABLE_TESTS)
 473         add_subdirectory(test)
 474         enable_testing()
 475         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 476 endif()