CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokxx>=0.3.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 2)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_STRING
 129         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 130 )
 131
 132 configure_file (
 133         ${PROJECT_SOURCE_DIR}/config.h.in
 134         ${PROJECT_BINARY_DIR}/config.h
 135 )
 136
 137 #===============================================================================
 138 #= Sources
 139 #-------------------------------------------------------------------------------
 140
 141 set(pulseview_SOURCES
 142         main.cpp
 143         pv/application.cpp
 144         pv/devicemanager.cpp
 145         pv/mainwindow.cpp
 146         pv/session.cpp
 147         pv/storesession.cpp
 148         pv/util.cpp
 149         pv/data/analog.cpp
 150         pv/data/analogsnapshot.cpp
 151         pv/data/logic.cpp
 152         pv/data/logicsnapshot.cpp
 153         pv/data/signaldata.cpp
 154         pv/data/snapshot.cpp
 155         pv/dialogs/about.cpp
 156         pv/dialogs/connect.cpp
 157         pv/dialogs/storeprogress.cpp
 158         pv/popups/deviceoptions.cpp
 159         pv/popups/channels.cpp
 160         pv/prop/bool.cpp
 161         pv/prop/double.cpp
 162         pv/prop/enum.cpp
 163         pv/prop/int.cpp
 164         pv/prop/property.cpp
 165         pv/prop/string.cpp
 166         pv/prop/binding/binding.cpp
 167         pv/prop/binding/deviceoptions.cpp
 168         pv/toolbars/samplingbar.cpp
 169         pv/view/analogsignal.cpp
 170         pv/view/cursor.cpp
 171         pv/view/cursorheader.cpp
 172         pv/view/cursorpair.cpp
 173         pv/view/header.cpp
 174         pv/view/marginwidget.cpp
 175         pv/view/logicsignal.cpp
 176         pv/view/rowitem.cpp
 177         pv/view/rowitemowner.cpp
 178         pv/view/ruler.cpp
 179         pv/view/selectableitem.cpp
 180         pv/view/signal.cpp
 181         pv/view/timemarker.cpp
 182         pv/view/trace.cpp
 183         pv/view/tracegroup.cpp
 184         pv/view/tracepalette.cpp
 185         pv/view/view.cpp
 186         pv/view/viewport.cpp
 187         pv/widgets/colourbutton.cpp
 188         pv/widgets/colourpopup.cpp
 189         pv/widgets/popup.cpp
 190         pv/widgets/popuptoolbutton.cpp
 191         pv/widgets/sweeptimingwidget.cpp
 192         pv/widgets/wellarray.cpp
 193 )
 194
 195 # This list includes only QObject derived class headers.
 196 set(pulseview_HEADERS
 197         pv/mainwindow.hpp
 198         pv/session.hpp
 199         pv/storesession.hpp
 200         pv/dialogs/about.hpp
 201         pv/dialogs/connect.hpp
 202         pv/dialogs/storeprogress.hpp
 203         pv/popups/channels.hpp
 204         pv/popups/deviceoptions.hpp
 205         pv/prop/bool.hpp
 206         pv/prop/double.hpp
 207         pv/prop/enum.hpp
 208         pv/prop/int.hpp
 209         pv/prop/property.hpp
 210         pv/prop/string.hpp
 211         pv/prop/binding/deviceoptions.hpp
 212         pv/toolbars/samplingbar.hpp
 213         pv/view/cursor.hpp
 214         pv/view/cursorheader.hpp
 215         pv/view/header.hpp
 216         pv/view/logicsignal.hpp
 217         pv/view/marginwidget.hpp
 218         pv/view/rowitem.hpp
 219         pv/view/ruler.hpp
 220         pv/view/selectableitem.hpp
 221         pv/view/signal.hpp
 222         pv/view/timemarker.hpp
 223         pv/view/trace.hpp
 224         pv/view/tracegroup.hpp
 225         pv/view/view.hpp
 226         pv/view/viewport.hpp
 227         pv/widgets/colourbutton.hpp
 228         pv/widgets/colourpopup.hpp
 229         pv/widgets/popup.hpp
 230         pv/widgets/popuptoolbutton.hpp
 231         pv/widgets/sweeptimingwidget.hpp
 232         pv/widgets/wellarray.hpp
 233 )
 234
 235 set(pulseview_FORMS
 236         pv/dialogs/about.ui
 237 )
 238
 239 set(pulseview_RESOURCES
 240         pulseview.qrc
 241 )
 242
 243 if(ENABLE_SIGNALS)
 244         list(APPEND pulseview_SOURCES signalhandler.cpp)
 245         list(APPEND pulseview_HEADERS signalhandler.hpp)
 246 endif()
 247
 248 if(ENABLE_DECODE)
 249         list(APPEND pulseview_SOURCES
 250                 pv/data/decoderstack.cpp
 251                 pv/data/decode/annotation.cpp
 252                 pv/data/decode/decoder.cpp
 253                 pv/data/decode/row.cpp
 254                 pv/data/decode/rowdata.cpp
 255                 pv/prop/binding/decoderoptions.cpp
 256                 pv/view/decodetrace.cpp
 257                 pv/widgets/decodergroupbox.cpp
 258                 pv/widgets/decodermenu.cpp
 259         )
 260
 261         list(APPEND pulseview_HEADERS
 262                 pv/data/decoderstack.hpp
 263                 pv/view/decodetrace.hpp
 264                 pv/widgets/decodergroupbox.hpp
 265                 pv/widgets/decodermenu.hpp
 266         )
 267 endif()
 268
 269 if(WIN32)
 270         # Use the sigrok icon for the pulseview.exe executable.
 271         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 272         enable_language(RC)
 273         list(APPEND pulseview_SOURCES pulseviewico.rc)
 274 endif()
 275
 276 if(ANDROID)
 277         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 278 endif()
 279
 280 if(Qt5Core_FOUND)
 281         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 282         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 283         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 284 else()
 285         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 286         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 287         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 288         include(${QT_USE_FILE})
 289 endif()
 290
 291 #===============================================================================
 292 #= Global Definitions
 293 #-------------------------------------------------------------------------------
 294
 295 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 296 add_definitions(-D__STDC_LIMIT_MACROS)
 297 add_definitions(-Wall -Wextra)
 298 add_definitions(-std=c++11)
 299
 300 if(ENABLE_DECODE)
 301         add_definitions(-DENABLE_DECODE)
 302 endif()
 303
 304 if(NOT DISABLE_WERROR)
 305         add_definitions(-Werror)
 306 endif()
 307
 308 if(ENABLE_SIGNALS)
 309         add_definitions(-DENABLE_SIGNALS)
 310 endif()
 311
 312 #===============================================================================
 313 #= Global Include Directories
 314 #-------------------------------------------------------------------------------
 315
 316 include_directories(
 317         ${CMAKE_CURRENT_BINARY_DIR}
 318         ${CMAKE_CURRENT_SOURCE_DIR}
 319         ${Boost_INCLUDE_DIRS}
 320         ${QT_INCLUDE_DIRS}
 321 )
 322
 323 if(STATIC_PKGDEPS_LIBS)
 324         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 325 else()
 326         include_directories(${PKGDEPS_INCLUDE_DIRS})
 327 endif()
 328
 329 #===============================================================================
 330 #= Linker Configuration
 331 #-------------------------------------------------------------------------------
 332
 333 link_directories(${Boost_LIBRARY_DIRS})
 334
 335 set(PULSEVIEW_LINK_LIBS
 336         ${Boost_LIBRARIES}
 337         ${QT_LIBRARIES}
 338         ${CMAKE_THREAD_LIBS_INIT}
 339 )
 340
 341 if(STATIC_PKGDEPS_LIBS)
 342         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 343         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 344 if(WIN32)
 345         # Workaround for a MinGW linking issue.
 346         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 347 endif()
 348 else()
 349         link_directories(${PKGDEPS_LIBRARY_DIRS})
 350         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 351 endif()
 352
 353 if(WIN32)
 354         # On Windows we need to statically link the libqsvg imageformat
 355         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 356         add_definitions(-DQT_STATICPLUGIN)
 357         link_directories("${QT_PLUGINS_DIR}/imageformats")
 358         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 359         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 360 endif()
 361
 362 if(ANDROID)
 363         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 364 endif()
 365
 366 if(ANDROID)
 367 add_library(${PROJECT_NAME} SHARED
 368         ${pulseview_SOURCES}
 369         ${pulseview_HEADERS_MOC}
 370         ${pulseview_FORMS_HEADERS}
 371         ${pulseview_RESOURCES_RCC}
 372 )
 373 else()
 374 add_executable(${PROJECT_NAME}
 375         ${pulseview_SOURCES}
 376         ${pulseview_HEADERS_MOC}
 377         ${pulseview_FORMS_HEADERS}
 378         ${pulseview_RESOURCES_RCC}
 379 )
 380 endif()
 381
 382 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 383
 384 if(WIN32)
 385         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 386         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 387 endif()
 388
 389 #===============================================================================
 390 #= Installation
 391 #-------------------------------------------------------------------------------
 392
 393 # Install the executable.
 394 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 395
 396 # Install the manpage.
 397 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 398
 399 #===============================================================================
 400 #= Packaging (handled by CPack)
 401 #-------------------------------------------------------------------------------
 402
 403 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 404 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 405 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 406 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 407 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 408 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 409 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 410         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 411 set(CPACK_SOURCE_GENERATOR "TGZ")
 412
 413 include(CPack)
 414
 415 #===============================================================================
 416 #= Tests
 417 #-------------------------------------------------------------------------------
 418
 419 if(ENABLE_TESTS)
 420         add_subdirectory(test)
 421         enable_testing()
 422         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 423 endif()