CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.12)
  22
  23 include(GNUInstallDirs)
  24
  25 project(pulseview)
  26
  27 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  28
  29 #===============================================================================
  30 #= User Options
  31 #-------------------------------------------------------------------------------
  32
  33 option(DISABLE_WERROR "Build without -Werror" FALSE)
  34 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  35 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  36 option(ENABLE_TESTS "Enable unit tests" TRUE)
  37 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  38
  39 if(WIN32)
  40         # On Windows/MinGW we need to statically link to libraries.
  41         # This option is user configurable, but enable it by default on win32.
  42         set(STATIC_PKGDEPS_LIBS TRUE)
  43
  44         # Windows does not support UNIX signals.
  45         set(ENABLE_SIGNALS FALSE)
  46 endif()
  47
  48 if(NOT CMAKE_BUILD_TYPE)
  49         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  50         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  51         FORCE)
  52 endif()
  53
  54 #===============================================================================
  55 #= Dependencies
  56 #-------------------------------------------------------------------------------
  57
  58 list(APPEND PKGDEPS glib-2.0>=2.28.0)
  59 list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
  60
  61 list(APPEND PKGDEPS libsigrokcxx>=0.5.0)
  62
  63 if(ENABLE_DECODE)
  64         list(APPEND PKGDEPS libsigrokdecode>=0.5.0)
  65 endif()
  66
  67 if(ANDROID)
  68         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  69 endif()
  70
  71 find_package(PkgConfig)
  72 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  73
  74 set(CMAKE_AUTOMOC TRUE)
  75
  76 find_package(Qt5 COMPONENTS Core Gui Widgets Svg REQUIRED)
  77
  78 if(WIN32)
  79         # MXE workaround: Use pkg-config to find Qt5 libs.
  80         # https://github.com/mxe/mxe/issues/1642
  81         pkg_check_modules(QT5ALL REQUIRED Qt5Widgets Qt5Gui Qt5Svg)
  82 endif()
  83
  84 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  85
  86 set(BOOSTCOMPS filesystem serialization system)
  87 if(ENABLE_TESTS)
  88         list(APPEND BOOSTCOMPS unit_test_framework)
  89 endif()
  90 find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
  91
  92 # Find the platform's thread library (needed for C++11 threads).
  93 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  94 find_package(Threads REQUIRED)
  95
  96 # Check for explicit link against libatomic
  97 #
  98 # Depending on the toolchain, linking a program using atomic functions may need
  99 # "-latomic" explicitly passed to the linker
 100 #
 101 # This check first tests if atomics are available in the C-library, if not and
 102 # libatomic exists, then it runs the same test with -latomic added to the
 103 # linker flags.
 104
 105 # Helper for checking for atomics
 106 function(check_working_cxx_atomics varname additional_lib)
 107   include(CheckCXXSourceCompiles)
 108   include(CMakePushCheckState)
 109   cmake_push_check_state()
 110   set(CMAKE_REQUIRED_FLAGS "-std=c++11")
 111   set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
 112   set(CMAKE_REQUIRED_QUIET 1)
 113   CHECK_CXX_SOURCE_COMPILES("
 114 #include <atomic>
 115 std::atomic<int> x;
 116 int main() {
 117   return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
 118 }
 119 " ${varname})
 120   cmake_pop_check_state()
 121 endfunction(check_working_cxx_atomics)
 122
 123 # First check if atomics work without the library.
 124 # If not, check if the library exists, and atomics work with it.
 125 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
 126 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
 127   message(STATUS "Atomics provided by the C-library - yes")
 128 else()
 129   message(STATUS "Atomics provided by the C-library - no")
 130   find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
 131   if(LIBATOMIC_LIBRARY)
 132     check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
 133     if (HAVE_CXX_ATOMICS_WITH_LIB)
 134       message(STATUS "Atomics provided by libatomic - yes")
 135     else()
 136       message(STATUS "Atomics provided by libatomic - no")
 137       message(FATAL_ERROR "Compiler must support std::atomic!")
 138     endif()
 139   else()
 140     message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
 141   endif()
 142 endif()
 143
 144 #===============================================================================
 145 #= System Introspection
 146 #-------------------------------------------------------------------------------
 147
 148 include(memaccess)
 149 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 150
 151 #===============================================================================
 152 #= Config Header
 153 #-------------------------------------------------------------------------------
 154
 155 set(PV_TITLE PulseView)
 156 set(PV_VERSION_STRING "0.4.0")
 157
 158 set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
 159
 160 include(GetGitRevisionDescription)
 161
 162 # Append the revision hash unless we are exactly on a tagged release.
 163 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
 164 if(NOT PV_TAG_VERSION_STRING)
 165         get_git_head_revision(PV_REVSPEC PV_HASH)
 166         if(PV_HASH)
 167                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
 168                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
 169         endif()
 170 endif()
 171
 172 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
 173         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 174         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 175         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 176         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 177 endif()
 178
 179 message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
 180
 181 configure_file (
 182         ${PROJECT_SOURCE_DIR}/config.h.in
 183         ${PROJECT_BINARY_DIR}/config.h
 184 )
 185
 186 #===============================================================================
 187 #= Sources
 188 #-------------------------------------------------------------------------------
 189
 190 set(pulseview_SOURCES
 191         main.cpp
 192         pv/application.cpp
 193         pv/devicemanager.cpp
 194         pv/globalsettings.cpp
 195         pv/mainwindow.cpp
 196         pv/session.cpp
 197         pv/storesession.cpp
 198         pv/util.cpp
 199         pv/binding/binding.cpp
 200         pv/binding/inputoutput.cpp
 201         pv/binding/device.cpp
 202         pv/data/analog.cpp
 203         pv/data/analogsegment.cpp
 204         pv/data/logic.cpp
 205         pv/data/logicsegment.cpp
 206         pv/data/signalbase.cpp
 207         pv/data/signaldata.cpp
 208         pv/data/segment.cpp
 209         pv/devices/device.cpp
 210         pv/devices/file.cpp
 211         pv/devices/hardwaredevice.cpp
 212         pv/devices/inputfile.cpp
 213         pv/devices/sessionfile.cpp
 214         pv/dialogs/connect.cpp
 215         pv/dialogs/inputoutputoptions.cpp
 216         pv/dialogs/settings.cpp
 217         pv/dialogs/storeprogress.cpp
 218         pv/popups/deviceoptions.cpp
 219         pv/popups/channels.cpp
 220         pv/prop/bool.cpp
 221         pv/prop/double.cpp
 222         pv/prop/enum.cpp
 223         pv/prop/int.cpp
 224         pv/prop/property.cpp
 225         pv/prop/string.cpp
 226         pv/toolbars/mainbar.cpp
 227         pv/view/analogsignal.cpp
 228         pv/view/cursor.cpp
 229         pv/view/cursorpair.cpp
 230         pv/view/flag.cpp
 231         pv/view/header.cpp
 232         pv/view/marginwidget.cpp
 233         pv/view/logicsignal.cpp
 234         pv/view/rowitem.cpp
 235         pv/view/ruler.cpp
 236         pv/view/signal.cpp
 237         pv/view/signalscalehandle.cpp
 238         pv/view/timeitem.cpp
 239         pv/view/timemarker.cpp
 240         pv/view/trace.cpp
 241         pv/view/tracegroup.cpp
 242         pv/view/tracepalette.cpp
 243         pv/view/tracetreeitem.cpp
 244         pv/view/tracetreeitemowner.cpp
 245         pv/view/triggermarker.cpp
 246         pv/view/view.cpp
 247         pv/view/viewitem.cpp
 248         pv/view/viewitemowner.cpp
 249         pv/view/viewitempaintparams.cpp
 250         pv/view/viewport.cpp
 251         pv/view/viewwidget.cpp
 252         pv/views/viewbase.cpp
 253         pv/views/trace/standardbar.cpp
 254         pv/widgets/colourbutton.cpp
 255         pv/widgets/colourpopup.cpp
 256         pv/widgets/devicetoolbutton.cpp
 257         pv/widgets/exportmenu.cpp
 258         pv/widgets/importmenu.cpp
 259         pv/widgets/popup.cpp
 260         pv/widgets/popuptoolbutton.cpp
 261         pv/widgets/sweeptimingwidget.cpp
 262         pv/widgets/timestampspinbox.cpp
 263         pv/widgets/wellarray.cpp
 264 )
 265
 266 # This list includes only QObject derived class headers.
 267 set(pulseview_HEADERS
 268         pv/globalsettings.hpp
 269         pv/mainwindow.hpp
 270         pv/session.hpp
 271         pv/storesession.hpp
 272         pv/binding/device.hpp
 273         pv/data/analog.hpp
 274         pv/data/analogsegment.hpp
 275         pv/data/logic.hpp
 276         pv/data/logicsegment.hpp
 277         pv/data/signalbase.hpp
 278         pv/dialogs/connect.hpp
 279         pv/dialogs/inputoutputoptions.hpp
 280         pv/dialogs/settings.hpp
 281         pv/dialogs/storeprogress.hpp
 282         pv/popups/channels.hpp
 283         pv/popups/deviceoptions.hpp
 284         pv/prop/bool.hpp
 285         pv/prop/double.hpp
 286         pv/prop/enum.hpp
 287         pv/prop/int.hpp
 288         pv/prop/property.hpp
 289         pv/prop/string.hpp
 290         pv/toolbars/mainbar.hpp
 291         pv/view/analogsignal.hpp
 292         pv/view/cursor.hpp
 293         pv/view/flag.hpp
 294         pv/view/header.hpp
 295         pv/view/logicsignal.hpp
 296         pv/view/marginwidget.hpp
 297         pv/view/rowitem.hpp
 298         pv/view/ruler.hpp
 299         pv/view/signal.hpp
 300         pv/view/signalscalehandle.hpp
 301         pv/view/timeitem.hpp
 302         pv/view/timemarker.hpp
 303         pv/view/trace.hpp
 304         pv/view/tracegroup.hpp
 305         pv/view/tracetreeitem.hpp
 306         pv/view/triggermarker.hpp
 307         pv/view/view.hpp
 308         pv/view/viewitem.hpp
 309         pv/view/viewport.hpp
 310         pv/view/viewwidget.hpp
 311         pv/views/viewbase.hpp
 312         pv/views/trace/standardbar.hpp
 313         pv/widgets/colourbutton.hpp
 314         pv/widgets/colourpopup.hpp
 315         pv/widgets/devicetoolbutton.hpp
 316         pv/widgets/exportmenu.hpp
 317         pv/widgets/importmenu.hpp
 318         pv/widgets/popup.hpp
 319         pv/widgets/popuptoolbutton.hpp
 320         pv/widgets/sweeptimingwidget.hpp
 321         pv/widgets/timestampspinbox.hpp
 322         pv/widgets/wellarray.hpp
 323 )
 324
 325 set(pulseview_RESOURCES
 326         pulseview.qrc
 327 )
 328
 329 if(ENABLE_SIGNALS)
 330         list(APPEND pulseview_SOURCES signalhandler.cpp)
 331         list(APPEND pulseview_HEADERS signalhandler.hpp)
 332 endif()
 333
 334 if(ENABLE_DECODE)
 335         list(APPEND pulseview_SOURCES
 336                 pv/binding/decoder.cpp
 337                 pv/data/decoderstack.cpp
 338                 pv/data/decode/annotation.cpp
 339                 pv/data/decode/decoder.cpp
 340                 pv/data/decode/row.cpp
 341                 pv/data/decode/rowdata.cpp
 342                 pv/view/decodetrace.cpp
 343                 pv/widgets/decodergroupbox.cpp
 344                 pv/widgets/decodermenu.cpp
 345         )
 346
 347         list(APPEND pulseview_HEADERS
 348                 pv/data/decoderstack.hpp
 349                 pv/view/decodetrace.hpp
 350                 pv/widgets/decodergroupbox.hpp
 351                 pv/widgets/decodermenu.hpp
 352         )
 353 endif()
 354
 355 if(WIN32)
 356         # Use the sigrok icon for the pulseview.exe executable.
 357         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 358         enable_language(RC)
 359         list(APPEND pulseview_SOURCES pulseviewico.rc)
 360 endif()
 361
 362 if(ANDROID)
 363         list(APPEND pulseview_SOURCES
 364                 android/assetreader.cpp
 365                 android/loghandler.cpp
 366         )
 367 endif()
 368
 369 qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 370
 371 #===============================================================================
 372 #= Global Definitions
 373 #-------------------------------------------------------------------------------
 374
 375 add_definitions(-DQT_NO_KEYWORDS)
 376 add_definitions(-D__STDC_LIMIT_MACROS)
 377 add_definitions(-Wall -Wextra)
 378 add_definitions(-std=c++11)
 379 add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
 380
 381 if(ENABLE_DECODE)
 382         add_definitions(-DENABLE_DECODE)
 383 endif()
 384
 385 if(NOT DISABLE_WERROR)
 386         add_definitions(-Werror)
 387 endif()
 388
 389 if(ENABLE_SIGNALS)
 390         add_definitions(-DENABLE_SIGNALS)
 391 endif()
 392
 393 #===============================================================================
 394 #= Global Include Directories
 395 #-------------------------------------------------------------------------------
 396
 397 include_directories(
 398         ${CMAKE_CURRENT_BINARY_DIR}
 399         ${CMAKE_CURRENT_SOURCE_DIR}
 400         ${Boost_INCLUDE_DIRS}
 401 )
 402
 403 if(STATIC_PKGDEPS_LIBS)
 404         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 405 else()
 406         include_directories(${PKGDEPS_INCLUDE_DIRS})
 407 endif()
 408
 409 #===============================================================================
 410 #= Linker Configuration
 411 #-------------------------------------------------------------------------------
 412
 413 link_directories(${Boost_LIBRARY_DIRS})
 414
 415 set(PULSEVIEW_LINK_LIBS
 416         ${Boost_LIBRARIES}
 417         ${QT_LIBRARIES}
 418         ${CMAKE_THREAD_LIBS_INIT}
 419         ${LIBATOMIC_LIBRARY}
 420 )
 421
 422 if(STATIC_PKGDEPS_LIBS)
 423         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 424         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
 425 else()
 426         link_directories(${PKGDEPS_LIBRARY_DIRS})
 427         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 428 endif()
 429
 430 if(WIN32)
 431         # On Windows we need to statically link the libqsvg imageformat
 432         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 433         # We also need QWindowsIntegrationPlugin, Qt5PlatformSupport, and all
 434         # Qt libs and their dependencies.
 435         add_definitions(-DQT_STATICPLUGIN)
 436         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
 437         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
 438         list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport ${QT5ALL_LDFLAGS})
 439 endif()
 440
 441 if(ANDROID)
 442         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 443 endif()
 444
 445 if(ANDROID)
 446         add_library(${PROJECT_NAME} SHARED ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
 447 else()
 448         add_executable(${PROJECT_NAME} ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
 449 endif()
 450
 451 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 452
 453 if(WIN32)
 454         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 455         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 456 endif()
 457
 458 #===============================================================================
 459 #= Installation
 460 #-------------------------------------------------------------------------------
 461
 462 # Install the executable.
 463 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 464
 465 # Install the manpage.
 466 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 467
 468 # Generate Windows installer script.
 469 configure_file(contrib/pulseview_cross.nsi.in contrib/pulseview_cross.nsi @ONLY)
 470
 471 #===============================================================================
 472 #= Packaging (handled by CPack)
 473 #-------------------------------------------------------------------------------
 474
 475 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 476 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 477 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 478 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 479 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 480 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 481 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 482 set(CPACK_SOURCE_GENERATOR "TGZ")
 483
 484 include(CPack)
 485
 486 #===============================================================================
 487 #= Tests
 488 #-------------------------------------------------------------------------------
 489
 490 if(ENABLE_TESTS)
 491         add_subdirectory(test)
 492         enable_testing()
 493         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 494 endif()