CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 #===============================================================================
  55 #= Dependencies
  56 #-------------------------------------------------------------------------------
  57
  58 list(APPEND PKGDEPS libsigrok>=0.2.0)
  59
  60 if(ENABLE_DECODE)
  61         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  62 endif()
  63
  64 find_package(PkgConfig)
  65 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  66
  67 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  68 find_package(Qt4 REQUIRED)
  69
  70 # Find the platform's thread library (needed for boost-thread).
  71 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  72 find_package(Threads)
  73
  74 if(WIN32)
  75         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  76         # The library is named libboost_thread_win32* (not libboost_thread*).
  77         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  78 else()
  79         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  80 endif()
  81
  82 #===============================================================================
  83 #= Config Header
  84 #-------------------------------------------------------------------------------
  85
  86 set(PV_TITLE PulseView)
  87 set(PV_DESCRIPTION "A GUI for sigrok")
  88
  89 set(PV_VERSION_MAJOR 0)
  90 set(PV_VERSION_MINOR 1)
  91 set(PV_VERSION_MICRO 0)
  92 set(PV_VERSION_STRING
  93         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  94 )
  95
  96 configure_file (
  97         ${PROJECT_SOURCE_DIR}/config.h.in
  98         ${PROJECT_BINARY_DIR}/config.h
  99 )
 100
 101 #===============================================================================
 102 #= Sources
 103 #-------------------------------------------------------------------------------
 104
 105 set(pulseview_SOURCES
 106         main.cpp
 107         pv/devicemanager.cpp
 108         pv/mainwindow.cpp
 109         pv/sigsession.cpp
 110         pv/storesession.cpp
 111         pv/data/analog.cpp
 112         pv/data/analogsnapshot.cpp
 113         pv/data/logic.cpp
 114         pv/data/logicsnapshot.cpp
 115         pv/data/signaldata.cpp
 116         pv/data/snapshot.cpp
 117         pv/dialogs/about.cpp
 118         pv/dialogs/connect.cpp
 119         pv/dialogs/storeprogress.cpp
 120         pv/popups/deviceoptions.cpp
 121         pv/popups/probes.cpp
 122         pv/prop/bool.cpp
 123         pv/prop/double.cpp
 124         pv/prop/enum.cpp
 125         pv/prop/int.cpp
 126         pv/prop/property.cpp
 127         pv/prop/string.cpp
 128         pv/prop/binding/binding.cpp
 129         pv/prop/binding/deviceoptions.cpp
 130         pv/toolbars/samplingbar.cpp
 131         pv/view/analogsignal.cpp
 132         pv/view/cursor.cpp
 133         pv/view/cursorpair.cpp
 134         pv/view/header.cpp
 135         pv/view/marginwidget.cpp
 136         pv/view/logicsignal.cpp
 137         pv/view/ruler.cpp
 138         pv/view/selectableitem.cpp
 139         pv/view/signal.cpp
 140         pv/view/timemarker.cpp
 141         pv/view/trace.cpp
 142         pv/view/tracepalette.cpp
 143         pv/view/view.cpp
 144         pv/view/viewport.cpp
 145         pv/widgets/colourbutton.cpp
 146         pv/widgets/colourpopup.cpp
 147         pv/widgets/popup.cpp
 148         pv/widgets/popuptoolbutton.cpp
 149         pv/widgets/wellarray.cpp
 150 )
 151
 152 # This list includes only QObject derived class headers.
 153 set(pulseview_HEADERS
 154         pv/mainwindow.h
 155         pv/sigsession.h
 156         pv/storesession.h
 157         pv/dialogs/about.h
 158         pv/dialogs/connect.h
 159         pv/dialogs/storeprogress.h
 160         pv/popups/probes.h
 161         pv/popups/deviceoptions.h
 162         pv/prop/bool.h
 163         pv/prop/double.h
 164         pv/prop/enum.h
 165         pv/prop/int.h
 166         pv/prop/property.h
 167         pv/prop/string.h
 168         pv/toolbars/samplingbar.h
 169         pv/view/cursor.h
 170         pv/view/header.h
 171         pv/view/logicsignal.h
 172         pv/view/marginwidget.h
 173         pv/view/ruler.h
 174         pv/view/selectableitem.h
 175         pv/view/signal.h
 176         pv/view/timemarker.h
 177         pv/view/trace.h
 178         pv/view/view.h
 179         pv/view/viewport.h
 180         pv/widgets/colourbutton.h
 181         pv/widgets/colourpopup.h
 182         pv/widgets/popup.h
 183         pv/widgets/popuptoolbutton.h
 184         pv/widgets/wellarray.h
 185 )
 186
 187 set(pulseview_FORMS
 188         pv/dialogs/about.ui
 189 )
 190
 191 set(pulseview_RESOURCES
 192         pulseview.qrc
 193 )
 194
 195 if(ENABLE_SIGNALS)
 196         list(APPEND pulseview_SOURCES signalhandler.cpp)
 197         list(APPEND pulseview_HEADERS signalhandler.h)
 198 endif()
 199
 200 if(ENABLE_DECODE)
 201         list(APPEND pulseview_SOURCES
 202                 pv/data/decoderstack.cpp
 203                 pv/data/decode/annotation.cpp
 204                 pv/data/decode/decoder.cpp
 205                 pv/prop/binding/decoderoptions.cpp
 206                 pv/view/decodetrace.cpp
 207                 pv/widgets/decodergroupbox.cpp
 208                 pv/widgets/decodermenu.cpp
 209                 pv/widgets/wellarray.cpp
 210         )
 211
 212         list(APPEND pulseview_HEADERS
 213                 pv/data/decoderstack.h
 214                 pv/view/decodetrace.h
 215                 pv/widgets/decodergroupbox.h
 216                 pv/widgets/decodermenu.h
 217         )
 218 endif()
 219
 220 if(WIN32)
 221         # Use the sigrok icon for the pulseview.exe executable.
 222         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 223         enable_language(RC)
 224         list(APPEND pulseview_SOURCES pulseviewico.rc)
 225 endif()
 226
 227 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 228 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 229 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 230
 231 include(${QT_USE_FILE})
 232
 233 #===============================================================================
 234 #= Global Definitions
 235 #-------------------------------------------------------------------------------
 236
 237 add_definitions(${QT_DEFINITIONS})
 238 add_definitions(-D__STDC_LIMIT_MACROS)
 239 add_definitions(-Wall -Wextra)
 240
 241 if(ENABLE_DECODE)
 242         add_definitions(-DENABLE_DECODE)
 243 endif()
 244
 245 if(NOT DISABLE_WERROR)
 246         add_definitions(-Werror)
 247 endif()
 248
 249 #===============================================================================
 250 #= Global Include Directories
 251 #-------------------------------------------------------------------------------
 252
 253 include_directories(
 254         ${CMAKE_CURRENT_BINARY_DIR}
 255         ${CMAKE_CURRENT_SOURCE_DIR}
 256         ${Boost_INCLUDE_DIRS}
 257 )
 258
 259 if(STATIC_PKGDEPS_LIBS)
 260         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 261 else()
 262         include_directories(${PKGDEPS_INCLUDE_DIRS})
 263 endif()
 264
 265 #===============================================================================
 266 #= Linker Configuration
 267 #-------------------------------------------------------------------------------
 268
 269 link_directories(${Boost_LIBRARY_DIRS})
 270
 271 set(PULSEVIEW_LINK_LIBS
 272         ${Boost_LIBRARIES}
 273         ${CMAKE_THREAD_LIBS_INIT}
 274         ${QT_LIBRARIES}
 275 )
 276
 277 if(STATIC_PKGDEPS_LIBS)
 278         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 279         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 280 else()
 281         link_directories(${PKGDEPS_LIBRARY_DIRS})
 282         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 283 endif()
 284
 285 if(WIN32)
 286         # On Windows we need to statically link the libqsvg imageformat
 287         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 288         add_definitions(-DQT_STATICPLUGIN)
 289         link_directories("${QT_PLUGINS_DIR}/imageformats")
 290         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 291         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 292 endif()
 293
 294 add_executable(${PROJECT_NAME}
 295         ${pulseview_SOURCES}
 296         ${pulseview_HEADERS_MOC}
 297         ${pulseview_FORMS_HEADERS}
 298         ${pulseview_RESOURCES_RCC}
 299 )
 300
 301 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 302
 303 if(WIN32)
 304         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 305         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 306 endif()
 307
 308 if(ENABLE_COTIRE)
 309         include(cotire)
 310         cotire(${PROJECT_NAME})
 311 endif()
 312
 313 #===============================================================================
 314 #= Installation
 315 #-------------------------------------------------------------------------------
 316
 317 # Install the executable.
 318 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 319
 320 # Install the manpage.
 321 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 322
 323 #===============================================================================
 324 #= Packaging (handled by CPack)
 325 #-------------------------------------------------------------------------------
 326
 327 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 328 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 329 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 330 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 331 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 332 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 333 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 334         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 335 set(CPACK_SOURCE_GENERATOR "TGZ")
 336
 337 include(CPack)
 338
 339 #===============================================================================
 340 #= Tests
 341 #-------------------------------------------------------------------------------
 342
 343 if(ENABLE_TESTS)
 344         add_subdirectory(test)
 345         enable_testing()
 346         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 347 endif()