CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  57         FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrokxx>=0.3.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  68 endif()
  69
  70 if(ANDROID)
  71         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  72 endif()
  73
  74 find_package(PkgConfig)
  75 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  76
  77 if(FORCE_QT4)
  78         set(Qt5Core_FOUND FALSE)
  79 else()
  80         find_package(Qt5Core QUIET)
  81 endif()
  82
  83 if(Qt5Core_FOUND)
  84         message("-- Using Qt5")
  85         find_package(Qt5Widgets REQUIRED)
  86         find_package(Qt5Gui REQUIRED)
  87         find_package(Qt5Svg REQUIRED)
  88         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  89         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  90         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  91         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  92 else()
  93         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  94         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  95 endif()
  96
  97 if(WIN32)
  98 if(ENABLE_TESTS)
  99         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
 100         # The library is named libboost_thread_win32* (not libboost_thread*).
 101         find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 unit_test_framework REQUIRED)
 102 else()
 103         find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 REQUIRED)
 104 endif()
 105 else()
 106 if(ENABLE_TESTS)
 107         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 108 else()
 109         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 110 endif()
 111 endif()
 112
 113 # Find the platform's thread library (needed for C++11 threads).
 114 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 115 find_package(Threads REQUIRED)
 116
 117 #===============================================================================
 118 #= System Introspection
 119 #-------------------------------------------------------------------------------
 120
 121 include(memaccess)
 122 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 123
 124 #===============================================================================
 125 #= Config Header
 126 #-------------------------------------------------------------------------------
 127
 128 set(PV_TITLE PulseView)
 129 set(PV_DESCRIPTION "A GUI for sigrok")
 130
 131 set(PV_VERSION_MAJOR 0)
 132 set(PV_VERSION_MINOR 2)
 133 set(PV_VERSION_MICRO 0)
 134 set(PV_VERSION_STRING
 135         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 136 )
 137
 138 configure_file (
 139         ${PROJECT_SOURCE_DIR}/config.h.in
 140         ${PROJECT_BINARY_DIR}/config.h
 141 )
 142
 143 #===============================================================================
 144 #= Sources
 145 #-------------------------------------------------------------------------------
 146
 147 set(pulseview_SOURCES
 148         main.cpp
 149         pv/application.cpp
 150         pv/devicemanager.cpp
 151         pv/mainwindow.cpp
 152         pv/session.cpp
 153         pv/storesession.cpp
 154         pv/util.cpp
 155         pv/data/analog.cpp
 156         pv/data/analogsnapshot.cpp
 157         pv/data/logic.cpp
 158         pv/data/logicsnapshot.cpp
 159         pv/data/signaldata.cpp
 160         pv/data/snapshot.cpp
 161         pv/dialogs/about.cpp
 162         pv/dialogs/connect.cpp
 163         pv/dialogs/storeprogress.cpp
 164         pv/popups/deviceoptions.cpp
 165         pv/popups/channels.cpp
 166         pv/prop/bool.cpp
 167         pv/prop/double.cpp
 168         pv/prop/enum.cpp
 169         pv/prop/int.cpp
 170         pv/prop/property.cpp
 171         pv/prop/string.cpp
 172         pv/prop/binding/binding.cpp
 173         pv/prop/binding/deviceoptions.cpp
 174         pv/toolbars/samplingbar.cpp
 175         pv/view/analogsignal.cpp
 176         pv/view/cursor.cpp
 177         pv/view/cursorheader.cpp
 178         pv/view/cursorpair.cpp
 179         pv/view/header.cpp
 180         pv/view/marginwidget.cpp
 181         pv/view/logicsignal.cpp
 182         pv/view/rowitem.cpp
 183         pv/view/rowitemowner.cpp
 184         pv/view/ruler.cpp
 185         pv/view/selectableitem.cpp
 186         pv/view/signal.cpp
 187         pv/view/timemarker.cpp
 188         pv/view/trace.cpp
 189         pv/view/tracegroup.cpp
 190         pv/view/tracepalette.cpp
 191         pv/view/view.cpp
 192         pv/view/viewport.cpp
 193         pv/widgets/colourbutton.cpp
 194         pv/widgets/colourpopup.cpp
 195         pv/widgets/popup.cpp
 196         pv/widgets/popuptoolbutton.cpp
 197         pv/widgets/sweeptimingwidget.cpp
 198         pv/widgets/wellarray.cpp
 199 )
 200
 201 # This list includes only QObject derived class headers.
 202 set(pulseview_HEADERS
 203         pv/mainwindow.hpp
 204         pv/session.hpp
 205         pv/storesession.hpp
 206         pv/dialogs/about.hpp
 207         pv/dialogs/connect.hpp
 208         pv/dialogs/storeprogress.hpp
 209         pv/popups/channels.hpp
 210         pv/popups/deviceoptions.hpp
 211         pv/prop/bool.hpp
 212         pv/prop/double.hpp
 213         pv/prop/enum.hpp
 214         pv/prop/int.hpp
 215         pv/prop/property.hpp
 216         pv/prop/string.hpp
 217         pv/prop/binding/deviceoptions.hpp
 218         pv/toolbars/samplingbar.hpp
 219         pv/view/cursor.hpp
 220         pv/view/cursorheader.hpp
 221         pv/view/header.hpp
 222         pv/view/logicsignal.hpp
 223         pv/view/marginwidget.hpp
 224         pv/view/rowitem.hpp
 225         pv/view/ruler.hpp
 226         pv/view/selectableitem.hpp
 227         pv/view/signal.hpp
 228         pv/view/timemarker.hpp
 229         pv/view/trace.hpp
 230         pv/view/tracegroup.hpp
 231         pv/view/view.hpp
 232         pv/view/viewport.hpp
 233         pv/widgets/colourbutton.hpp
 234         pv/widgets/colourpopup.hpp
 235         pv/widgets/popup.hpp
 236         pv/widgets/popuptoolbutton.hpp
 237         pv/widgets/sweeptimingwidget.hpp
 238         pv/widgets/wellarray.hpp
 239 )
 240
 241 set(pulseview_FORMS
 242         pv/dialogs/about.ui
 243 )
 244
 245 set(pulseview_RESOURCES
 246         pulseview.qrc
 247 )
 248
 249 if(ENABLE_SIGNALS)
 250         list(APPEND pulseview_SOURCES signalhandler.cpp)
 251         list(APPEND pulseview_HEADERS signalhandler.hpp)
 252 endif()
 253
 254 if(ENABLE_DECODE)
 255         list(APPEND pulseview_SOURCES
 256                 pv/data/decoderstack.cpp
 257                 pv/data/decode/annotation.cpp
 258                 pv/data/decode/decoder.cpp
 259                 pv/data/decode/row.cpp
 260                 pv/data/decode/rowdata.cpp
 261                 pv/prop/binding/decoderoptions.cpp
 262                 pv/view/decodetrace.cpp
 263                 pv/widgets/decodergroupbox.cpp
 264                 pv/widgets/decodermenu.cpp
 265         )
 266
 267         list(APPEND pulseview_HEADERS
 268                 pv/data/decoderstack.hpp
 269                 pv/view/decodetrace.hpp
 270                 pv/widgets/decodergroupbox.hpp
 271                 pv/widgets/decodermenu.hpp
 272         )
 273 endif()
 274
 275 if(WIN32)
 276         # Use the sigrok icon for the pulseview.exe executable.
 277         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 278         enable_language(RC)
 279         list(APPEND pulseview_SOURCES pulseviewico.rc)
 280 endif()
 281
 282 if(ANDROID)
 283         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 284 endif()
 285
 286 if(Qt5Core_FOUND)
 287         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 288         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 289         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 290 else()
 291         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 292         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 293         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 294         include(${QT_USE_FILE})
 295 endif()
 296
 297 #===============================================================================
 298 #= Global Definitions
 299 #-------------------------------------------------------------------------------
 300
 301 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 302 add_definitions(-D__STDC_LIMIT_MACROS)
 303 add_definitions(-Wall -Wextra)
 304 add_definitions(-std=c++11)
 305
 306 if(ENABLE_DECODE)
 307         add_definitions(-DENABLE_DECODE)
 308 endif()
 309
 310 if(NOT DISABLE_WERROR)
 311         add_definitions(-Werror)
 312 endif()
 313
 314 if(ENABLE_SIGNALS)
 315         add_definitions(-DENABLE_SIGNALS)
 316 endif()
 317
 318 #===============================================================================
 319 #= Global Include Directories
 320 #-------------------------------------------------------------------------------
 321
 322 include_directories(
 323         ${CMAKE_CURRENT_BINARY_DIR}
 324         ${CMAKE_CURRENT_SOURCE_DIR}
 325         ${Boost_INCLUDE_DIRS}
 326         ${QT_INCLUDE_DIRS}
 327 )
 328
 329 if(STATIC_PKGDEPS_LIBS)
 330         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 331 else()
 332         include_directories(${PKGDEPS_INCLUDE_DIRS})
 333 endif()
 334
 335 #===============================================================================
 336 #= Linker Configuration
 337 #-------------------------------------------------------------------------------
 338
 339 link_directories(${Boost_LIBRARY_DIRS})
 340
 341 set(PULSEVIEW_LINK_LIBS
 342         ${Boost_LIBRARIES}
 343         ${QT_LIBRARIES}
 344         ${CMAKE_THREAD_LIBS_INIT}
 345 )
 346
 347 if(STATIC_PKGDEPS_LIBS)
 348         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 349         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 350 if(WIN32)
 351         # Workaround for a MinGW linking issue.
 352         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 353 endif()
 354 else()
 355         link_directories(${PKGDEPS_LIBRARY_DIRS})
 356         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 357 endif()
 358
 359 if(WIN32)
 360         # On Windows we need to statically link the libqsvg imageformat
 361         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 362         add_definitions(-DQT_STATICPLUGIN)
 363         link_directories("${QT_PLUGINS_DIR}/imageformats")
 364         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 365         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 366 endif()
 367
 368 if(ANDROID)
 369         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 370 endif()
 371
 372 if(ANDROID)
 373 add_library(${PROJECT_NAME} SHARED
 374         ${pulseview_SOURCES}
 375         ${pulseview_HEADERS_MOC}
 376         ${pulseview_FORMS_HEADERS}
 377         ${pulseview_RESOURCES_RCC}
 378 )
 379 else()
 380 add_executable(${PROJECT_NAME}
 381         ${pulseview_SOURCES}
 382         ${pulseview_HEADERS_MOC}
 383         ${pulseview_FORMS_HEADERS}
 384         ${pulseview_RESOURCES_RCC}
 385 )
 386 endif()
 387
 388 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 389
 390 if(WIN32)
 391         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 392         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 393 endif()
 394
 395 #===============================================================================
 396 #= Installation
 397 #-------------------------------------------------------------------------------
 398
 399 # Install the executable.
 400 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 401
 402 # Install the manpage.
 403 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 404
 405 #===============================================================================
 406 #= Packaging (handled by CPack)
 407 #-------------------------------------------------------------------------------
 408
 409 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 410 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 411 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 412 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 413 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 414 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 415 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 416         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 417 set(CPACK_SOURCE_GENERATOR "TGZ")
 418
 419 include(CPack)
 420
 421 #===============================================================================
 422 #= Tests
 423 #-------------------------------------------------------------------------------
 424
 425 if(ENABLE_TESTS)
 426         add_subdirectory(test)
 427         enable_testing()
 428         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 429 endif()