CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  41
  42 if(WIN32)
  43         # On Windows/MinGW we need to statically link to libraries.
  44         # This option is user configurable, but enable it by default on win32.
  45         set(STATIC_PKGDEPS_LIBS TRUE)
  46
  47         # Windows does not support UNIX signals.
  48         set(ENABLE_SIGNALS FALSE)
  49 endif()
  50
  51 if(NOT CMAKE_BUILD_TYPE)
  52   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  53       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  54       FORCE)
  55 endif()
  56
  57 #===============================================================================
  58 #= Dependencies
  59 #-------------------------------------------------------------------------------
  60
  61 list(APPEND PKGDEPS libsigrokxx>=0.3.0)
  62
  63 if(ENABLE_DECODE)
  64         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  65 endif()
  66
  67 if(ANDROID)
  68         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  69 endif()
  70
  71 find_package(PkgConfig)
  72 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  73
  74 if(FORCE_QT4)
  75         set(Qt5Core_FOUND FALSE)
  76 else()
  77         find_package(Qt5Core QUIET)
  78 endif()
  79
  80 if(Qt5Core_FOUND)
  81         message("-- Using Qt5")
  82         find_package(Qt5Widgets REQUIRED)
  83         find_package(Qt5Gui REQUIRED)
  84         find_package(Qt5Svg REQUIRED)
  85         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  86         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  87         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  88         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  89 else()
  90         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  91         find_package(Qt4 REQUIRED)
  92         set(QT_USE_QTSVG TRUE)
  93 endif()
  94
  95 find_package(Boost 1.42 COMPONENTS filesystem system REQUIRED)
  96
  97 # Find the platform's thread library (needed for C++11 threads).
  98 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  99 find_package(Threads REQUIRED)
 100
 101 #===============================================================================
 102 #= System Introspection
 103 #-------------------------------------------------------------------------------
 104
 105 include(memaccess)
 106 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 107
 108 #===============================================================================
 109 #= Config Header
 110 #-------------------------------------------------------------------------------
 111
 112 set(PV_TITLE PulseView)
 113 set(PV_DESCRIPTION "A GUI for sigrok")
 114
 115 set(PV_VERSION_MAJOR 0)
 116 set(PV_VERSION_MINOR 2)
 117 set(PV_VERSION_MICRO 0)
 118 set(PV_VERSION_STRING
 119         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 120 )
 121
 122 configure_file (
 123         ${PROJECT_SOURCE_DIR}/config.h.in
 124         ${PROJECT_BINARY_DIR}/config.h
 125 )
 126
 127 #===============================================================================
 128 #= Sources
 129 #-------------------------------------------------------------------------------
 130
 131 set(pulseview_SOURCES
 132         main.cpp
 133         pv/application.cpp
 134         pv/devicemanager.cpp
 135         pv/mainwindow.cpp
 136         pv/sigsession.cpp
 137         pv/storesession.cpp
 138         pv/util.cpp
 139         pv/data/analog.cpp
 140         pv/data/analogsnapshot.cpp
 141         pv/data/logic.cpp
 142         pv/data/logicsnapshot.cpp
 143         pv/data/signaldata.cpp
 144         pv/data/snapshot.cpp
 145         pv/dialogs/about.cpp
 146         pv/dialogs/connect.cpp
 147         pv/dialogs/storeprogress.cpp
 148         pv/popups/deviceoptions.cpp
 149         pv/popups/channels.cpp
 150         pv/prop/bool.cpp
 151         pv/prop/double.cpp
 152         pv/prop/enum.cpp
 153         pv/prop/int.cpp
 154         pv/prop/property.cpp
 155         pv/prop/string.cpp
 156         pv/prop/binding/binding.cpp
 157         pv/prop/binding/deviceoptions.cpp
 158         pv/toolbars/samplingbar.cpp
 159         pv/view/analogsignal.cpp
 160         pv/view/cursor.cpp
 161         pv/view/cursorheader.cpp
 162         pv/view/cursorpair.cpp
 163         pv/view/header.cpp
 164         pv/view/marginwidget.cpp
 165         pv/view/logicsignal.cpp
 166         pv/view/ruler.cpp
 167         pv/view/selectableitem.cpp
 168         pv/view/signal.cpp
 169         pv/view/timemarker.cpp
 170         pv/view/trace.cpp
 171         pv/view/tracepalette.cpp
 172         pv/view/view.cpp
 173         pv/view/viewport.cpp
 174         pv/widgets/colourbutton.cpp
 175         pv/widgets/colourpopup.cpp
 176         pv/widgets/popup.cpp
 177         pv/widgets/popuptoolbutton.cpp
 178         pv/widgets/sweeptimingwidget.cpp
 179         pv/widgets/wellarray.cpp
 180 )
 181
 182 # This list includes only QObject derived class headers.
 183 set(pulseview_HEADERS
 184         pv/mainwindow.h
 185         pv/sigsession.h
 186         pv/storesession.h
 187         pv/dialogs/about.h
 188         pv/dialogs/connect.h
 189         pv/dialogs/storeprogress.h
 190         pv/popups/channels.h
 191         pv/popups/deviceoptions.h
 192         pv/prop/bool.h
 193         pv/prop/double.h
 194         pv/prop/enum.h
 195         pv/prop/int.h
 196         pv/prop/property.h
 197         pv/prop/string.h
 198         pv/prop/binding/deviceoptions.h
 199         pv/toolbars/samplingbar.h
 200         pv/view/cursor.h
 201         pv/view/cursorheader.h
 202         pv/view/header.h
 203         pv/view/logicsignal.h
 204         pv/view/marginwidget.h
 205         pv/view/ruler.h
 206         pv/view/selectableitem.h
 207         pv/view/signal.h
 208         pv/view/timemarker.h
 209         pv/view/trace.h
 210         pv/view/view.h
 211         pv/view/viewport.h
 212         pv/widgets/colourbutton.h
 213         pv/widgets/colourpopup.h
 214         pv/widgets/popup.h
 215         pv/widgets/popuptoolbutton.h
 216         pv/widgets/sweeptimingwidget.h
 217         pv/widgets/wellarray.h
 218 )
 219
 220 set(pulseview_FORMS
 221         pv/dialogs/about.ui
 222 )
 223
 224 set(pulseview_RESOURCES
 225         pulseview.qrc
 226 )
 227
 228 if(ENABLE_SIGNALS)
 229         list(APPEND pulseview_SOURCES signalhandler.cpp)
 230         list(APPEND pulseview_HEADERS signalhandler.h)
 231 endif()
 232
 233 if(ENABLE_DECODE)
 234         list(APPEND pulseview_SOURCES
 235                 pv/data/decoderstack.cpp
 236                 pv/data/decode/annotation.cpp
 237                 pv/data/decode/decoder.cpp
 238                 pv/data/decode/row.cpp
 239                 pv/data/decode/rowdata.cpp
 240                 pv/prop/binding/decoderoptions.cpp
 241                 pv/view/decodetrace.cpp
 242                 pv/widgets/decodergroupbox.cpp
 243                 pv/widgets/decodermenu.cpp
 244         )
 245
 246         list(APPEND pulseview_HEADERS
 247                 pv/data/decoderstack.h
 248                 pv/view/decodetrace.h
 249                 pv/widgets/decodergroupbox.h
 250                 pv/widgets/decodermenu.h
 251         )
 252 endif()
 253
 254 if(WIN32)
 255         # Use the sigrok icon for the pulseview.exe executable.
 256         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 257         enable_language(RC)
 258         list(APPEND pulseview_SOURCES pulseviewico.rc)
 259 endif()
 260
 261 if(ANDROID)
 262         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 263 endif()
 264
 265 if(Qt5Core_FOUND)
 266         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 267         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 268         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 269 else()
 270         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 271         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 272         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 273         include(${QT_USE_FILE})
 274 endif()
 275
 276 #===============================================================================
 277 #= Global Definitions
 278 #-------------------------------------------------------------------------------
 279
 280 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 281 add_definitions(-D__STDC_LIMIT_MACROS)
 282 add_definitions(-Wall -Wextra)
 283 add_definitions(-std=c++11)
 284
 285 if(ENABLE_DECODE)
 286         add_definitions(-DENABLE_DECODE)
 287 endif()
 288
 289 if(NOT DISABLE_WERROR)
 290         add_definitions(-Werror)
 291 endif()
 292
 293 if(ENABLE_SIGNALS)
 294         add_definitions(-DENABLE_SIGNALS)
 295 endif()
 296
 297 #===============================================================================
 298 #= Global Include Directories
 299 #-------------------------------------------------------------------------------
 300
 301 include_directories(
 302         ${CMAKE_CURRENT_BINARY_DIR}
 303         ${CMAKE_CURRENT_SOURCE_DIR}
 304         ${Boost_INCLUDE_DIRS}
 305         ${QT_INCLUDE_DIRS}
 306 )
 307
 308 if(STATIC_PKGDEPS_LIBS)
 309         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 310 else()
 311         include_directories(${PKGDEPS_INCLUDE_DIRS})
 312 endif()
 313
 314 #===============================================================================
 315 #= Linker Configuration
 316 #-------------------------------------------------------------------------------
 317
 318 link_directories(${Boost_LIBRARY_DIRS})
 319
 320 set(PULSEVIEW_LINK_LIBS
 321         ${Boost_LIBRARIES}
 322         ${QT_LIBRARIES}
 323         ${CMAKE_THREAD_LIBS_INIT}
 324 )
 325
 326 if(STATIC_PKGDEPS_LIBS)
 327         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 328         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 329 if(WIN32)
 330         # Workaround for a MinGW linking issue.
 331         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 332 endif()
 333 else()
 334         link_directories(${PKGDEPS_LIBRARY_DIRS})
 335         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 336 endif()
 337
 338 if(WIN32)
 339         # On Windows we need to statically link the libqsvg imageformat
 340         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 341         add_definitions(-DQT_STATICPLUGIN)
 342         link_directories("${QT_PLUGINS_DIR}/imageformats")
 343         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 344         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 345 endif()
 346
 347 if(ANDROID)
 348         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 349 endif()
 350
 351 if(ANDROID)
 352 add_library(${PROJECT_NAME} SHARED
 353         ${pulseview_SOURCES}
 354         ${pulseview_HEADERS_MOC}
 355         ${pulseview_FORMS_HEADERS}
 356         ${pulseview_RESOURCES_RCC}
 357 )
 358 else()
 359 add_executable(${PROJECT_NAME}
 360         ${pulseview_SOURCES}
 361         ${pulseview_HEADERS_MOC}
 362         ${pulseview_FORMS_HEADERS}
 363         ${pulseview_RESOURCES_RCC}
 364 )
 365 endif()
 366
 367 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 368
 369 if(WIN32)
 370         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 371         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 372 endif()
 373
 374 if(ENABLE_COTIRE)
 375         include(cotire)
 376         cotire(${PROJECT_NAME})
 377 endif()
 378
 379 #===============================================================================
 380 #= Installation
 381 #-------------------------------------------------------------------------------
 382
 383 # Install the executable.
 384 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 385
 386 # Install the manpage.
 387 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 388
 389 #===============================================================================
 390 #= Packaging (handled by CPack)
 391 #-------------------------------------------------------------------------------
 392
 393 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 394 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 395 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 396 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 397 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 398 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 399 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 400         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 401 set(CPACK_SOURCE_GENERATOR "TGZ")
 402
 403 include(CPack)
 404
 405 #===============================================================================
 406 #= Tests
 407 #-------------------------------------------------------------------------------
 408
 409 if(ENABLE_TESTS)
 410         add_subdirectory(test)
 411         enable_testing()
 412         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 413 endif()