CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_TESTS "Enable unit tests" FALSE)
  32 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  33
  34 if(WIN32)
  35         # On Windows/MinGW we need to statically link to libraries.
  36         # This option is user configurable, but enable it by default on win32.
  37         set(STATIC_PKGDEPS_LIBS TRUE)
  38 endif()
  39
  40 #===============================================================================
  41 #= Dependencies
  42 #-------------------------------------------------------------------------------
  43
  44 find_package(PkgConfig)
  45 pkg_check_modules(PKGDEPS REQUIRED
  46         libsigrokdecode>=0.1.0
  47         libsigrok>=0.2.0
  48 )
  49
  50 find_package(Qt4 REQUIRED)
  51
  52 # On Windows/MinGW we explicitly point cmake to the Boost directory.
  53 if(WIN32)
  54         set(BOOST_ROOT /usr/local)
  55 endif()
  56
  57 find_package(Boost 1.46 COMPONENTS system thread)
  58
  59 #===============================================================================
  60 #= Config Header
  61 #-------------------------------------------------------------------------------
  62
  63 set(PV_TITLE PulseView)
  64 set(PV_DESCRIPTION "A GUI for sigrok")
  65
  66 set(PV_VERSION_MAJOR 0)
  67 set(PV_VERSION_MINOR 1)
  68 set(PV_VERSION_MICRO 0)
  69 set(PV_VERSION_STRING
  70         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  71 )
  72
  73 configure_file (
  74         ${PROJECT_SOURCE_DIR}/config.h.in
  75         ${PROJECT_BINARY_DIR}/config.h
  76 )
  77
  78 #===============================================================================
  79 #= Sources
  80 #-------------------------------------------------------------------------------
  81
  82 set(pulseview_SOURCES
  83         main.cpp
  84         pv/mainwindow.cpp
  85         pv/samplingbar.cpp
  86         pv/sigsession.cpp
  87         pv/data/analog.cpp
  88         pv/data/analogsnapshot.cpp
  89         pv/data/logic.cpp
  90         pv/data/logicsnapshot.cpp
  91         pv/data/signaldata.cpp
  92         pv/data/snapshot.cpp
  93         pv/dialogs/about.cpp
  94         pv/dialogs/hwcap.cpp
  95         pv/prop/enum.cpp
  96         pv/prop/property.cpp
  97         pv/prop/binding/binding.cpp
  98         pv/prop/binding/hwcap.cpp
  99         pv/view/analogsignal.cpp
 100         pv/view/cursor.cpp
 101         pv/view/header.cpp
 102         pv/view/logicsignal.cpp
 103         pv/view/ruler.cpp
 104         pv/view/signal.cpp
 105         pv/view/timemarker.cpp
 106         pv/view/view.cpp
 107         pv/view/viewport.cpp
 108 )
 109
 110 set(pulseview_HEADERS
 111         pv/mainwindow.h
 112         pv/samplingbar.h
 113         pv/sigsession.h
 114         pv/dialogs/about.h
 115         pv/view/cursor.h
 116         pv/view/header.h
 117         pv/view/ruler.h
 118         pv/view/timemarker.h
 119         pv/view/view.h
 120         pv/view/viewport.h
 121 )
 122
 123 set(pulseview_FORMS
 124         pv/dialogs/about.ui
 125 )
 126
 127 set(pulseview_RESOURCES
 128         pulseview.qrc
 129 )
 130
 131 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 132 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 133 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 134
 135 include(${QT_USE_FILE})
 136
 137 #===============================================================================
 138 #= Global Definitions
 139 #-------------------------------------------------------------------------------
 140
 141 add_definitions(${QT_DEFINITIONS})
 142 add_definitions(-Wextra)
 143
 144 if(NOT DISABLE_WERROR)
 145         add_definitions(-Werror)
 146 endif()
 147
 148 #===============================================================================
 149 #= Global Include Directories
 150 #-------------------------------------------------------------------------------
 151
 152 include_directories(
 153         ${CMAKE_CURRENT_BINARY_DIR}
 154         ${CMAKE_CURRENT_SOURCE_DIR}
 155         ${Boost_INCLUDE_DIRS}
 156 )
 157
 158 if(STATIC_PKGDEPS_LIBS)
 159         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 160 else()
 161         include_directories(${PKGDEPS_INCLUDE_DIRS})
 162 endif()
 163
 164 #===============================================================================
 165 #= Linker Configuration
 166 #-------------------------------------------------------------------------------
 167
 168 link_directories(${Boost_LIBRARY_DIRS})
 169
 170 set(PULSEVIEW_LINK_LIBS
 171         ${Boost_LIBRARIES}
 172         ${QT_LIBRARIES}
 173 )
 174
 175 if(STATIC_PKGDEPS_LIBS)
 176         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 177         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 178 else()
 179         link_directories(${PKGDEPS_LIBRARY_DIRS})
 180         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 181 endif()
 182
 183 add_executable(${PROJECT_NAME}
 184         ${pulseview_SOURCES}
 185         ${pulseview_HEADERS_MOC}
 186         ${pulseview_FORMS_HEADERS}
 187         ${pulseview_RESOURCES_RCC}
 188 )
 189
 190 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 191
 192 #===============================================================================
 193 #= Installation
 194 #-------------------------------------------------------------------------------
 195
 196 install(PROGRAMS ${PROJECT_NAME} DESTINATION bin/)
 197
 198 #===============================================================================
 199 #= Tests
 200 #-------------------------------------------------------------------------------
 201
 202 if(ENABLE_TESTS)
 203         add_subdirectory(test)
 204         enable_testing()
 205         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 206 endif(ENABLE_TESTS)