CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.3.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 2)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_STRING
 129         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 130 )
 131
 132 configure_file (
 133         ${PROJECT_SOURCE_DIR}/config.h.in
 134         ${PROJECT_BINARY_DIR}/config.h
 135 )
 136
 137 #===============================================================================
 138 #= Sources
 139 #-------------------------------------------------------------------------------
 140
 141 set(pulseview_SOURCES
 142         main.cpp
 143         pv/application.cpp
 144         pv/devicemanager.cpp
 145         pv/mainwindow.cpp
 146         pv/session.cpp
 147         pv/storesession.cpp
 148         pv/util.cpp
 149         pv/binding/binding.cpp
 150         pv/binding/inputoutput.cpp
 151         pv/binding/device.cpp
 152         pv/data/analog.cpp
 153         pv/data/analogsegment.cpp
 154         pv/data/logic.cpp
 155         pv/data/logicsegment.cpp
 156         pv/data/signaldata.cpp
 157         pv/data/segment.cpp
 158         pv/dialogs/about.cpp
 159         pv/dialogs/connect.cpp
 160         pv/dialogs/inputoutputoptions.cpp
 161         pv/dialogs/storeprogress.cpp
 162         pv/popups/deviceoptions.cpp
 163         pv/popups/channels.cpp
 164         pv/prop/bool.cpp
 165         pv/prop/double.cpp
 166         pv/prop/enum.cpp
 167         pv/prop/int.cpp
 168         pv/prop/property.cpp
 169         pv/prop/string.cpp
 170         pv/toolbars/mainbar.cpp
 171         pv/view/analogsignal.cpp
 172         pv/view/cursor.cpp
 173         pv/view/cursorpair.cpp
 174         pv/view/flag.cpp
 175         pv/view/header.cpp
 176         pv/view/marginwidget.cpp
 177         pv/view/logicsignal.cpp
 178         pv/view/rowitem.cpp
 179         pv/view/rowitemowner.cpp
 180         pv/view/ruler.cpp
 181         pv/view/signal.cpp
 182         pv/view/timeitem.cpp
 183         pv/view/timemarker.cpp
 184         pv/view/trace.cpp
 185         pv/view/tracegroup.cpp
 186         pv/view/tracepalette.cpp
 187         pv/view/view.cpp
 188         pv/view/viewitem.cpp
 189         pv/view/viewitempaintparams.cpp
 190         pv/view/viewport.cpp
 191         pv/view/viewwidget.cpp
 192         pv/widgets/colourbutton.cpp
 193         pv/widgets/colourpopup.cpp
 194         pv/widgets/devicetoolbutton.cpp
 195         pv/widgets/exportmenu.cpp
 196         pv/widgets/hidingmenubar.cpp
 197         pv/widgets/popup.cpp
 198         pv/widgets/popuptoolbutton.cpp
 199         pv/widgets/sweeptimingwidget.cpp
 200         pv/widgets/wellarray.cpp
 201 )
 202
 203 # This list includes only QObject derived class headers.
 204 set(pulseview_HEADERS
 205         pv/mainwindow.hpp
 206         pv/session.hpp
 207         pv/storesession.hpp
 208         pv/binding/device.hpp
 209         pv/dialogs/about.hpp
 210         pv/dialogs/connect.hpp
 211         pv/dialogs/inputoutputoptions.hpp
 212         pv/dialogs/storeprogress.hpp
 213         pv/popups/channels.hpp
 214         pv/popups/deviceoptions.hpp
 215         pv/prop/bool.hpp
 216         pv/prop/double.hpp
 217         pv/prop/enum.hpp
 218         pv/prop/int.hpp
 219         pv/prop/property.hpp
 220         pv/prop/string.hpp
 221         pv/toolbars/mainbar.hpp
 222         pv/view/cursor.hpp
 223         pv/view/flag.hpp
 224         pv/view/header.hpp
 225         pv/view/logicsignal.hpp
 226         pv/view/marginwidget.hpp
 227         pv/view/rowitem.hpp
 228         pv/view/ruler.hpp
 229         pv/view/signal.hpp
 230         pv/view/timeitem.hpp
 231         pv/view/timemarker.hpp
 232         pv/view/trace.hpp
 233         pv/view/tracegroup.hpp
 234         pv/view/view.hpp
 235         pv/view/viewitem.hpp
 236         pv/view/viewport.hpp
 237         pv/view/viewwidget.hpp
 238         pv/widgets/colourbutton.hpp
 239         pv/widgets/colourpopup.hpp
 240         pv/widgets/devicetoolbutton.hpp
 241         pv/widgets/exportmenu.hpp
 242         pv/widgets/hidingmenubar.hpp
 243         pv/widgets/popup.hpp
 244         pv/widgets/popuptoolbutton.hpp
 245         pv/widgets/sweeptimingwidget.hpp
 246         pv/widgets/wellarray.hpp
 247 )
 248
 249 set(pulseview_FORMS
 250         pv/dialogs/about.ui
 251 )
 252
 253 set(pulseview_RESOURCES
 254         pulseview.qrc
 255 )
 256
 257 if(ENABLE_SIGNALS)
 258         list(APPEND pulseview_SOURCES signalhandler.cpp)
 259         list(APPEND pulseview_HEADERS signalhandler.hpp)
 260 endif()
 261
 262 if(ENABLE_DECODE)
 263         list(APPEND pulseview_SOURCES
 264                 pv/binding/decoder.cpp
 265                 pv/data/decoderstack.cpp
 266                 pv/data/decode/annotation.cpp
 267                 pv/data/decode/decoder.cpp
 268                 pv/data/decode/row.cpp
 269                 pv/data/decode/rowdata.cpp
 270                 pv/view/decodetrace.cpp
 271                 pv/widgets/decodergroupbox.cpp
 272                 pv/widgets/decodermenu.cpp
 273         )
 274
 275         list(APPEND pulseview_HEADERS
 276                 pv/data/decoderstack.hpp
 277                 pv/view/decodetrace.hpp
 278                 pv/widgets/decodergroupbox.hpp
 279                 pv/widgets/decodermenu.hpp
 280         )
 281 endif()
 282
 283 if(WIN32)
 284         # Use the sigrok icon for the pulseview.exe executable.
 285         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 286         enable_language(RC)
 287         list(APPEND pulseview_SOURCES pulseviewico.rc)
 288 endif()
 289
 290 if(ANDROID)
 291         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 292 endif()
 293
 294 if(Qt5Core_FOUND)
 295         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 296         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 297         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 298 else()
 299         # Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
 300         # https://bugreports.qt.io/browse/QTBUG-22829
 301         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
 302                 OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
 303         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 304         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 305         include(${QT_USE_FILE})
 306 endif()
 307
 308 #===============================================================================
 309 #= Global Definitions
 310 #-------------------------------------------------------------------------------
 311
 312 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 313 add_definitions(-D__STDC_LIMIT_MACROS)
 314 add_definitions(-Wall -Wextra)
 315 add_definitions(-std=c++11)
 316
 317 if(ENABLE_DECODE)
 318         add_definitions(-DENABLE_DECODE)
 319 endif()
 320
 321 if(NOT DISABLE_WERROR)
 322         add_definitions(-Werror)
 323 endif()
 324
 325 if(ENABLE_SIGNALS)
 326         add_definitions(-DENABLE_SIGNALS)
 327 endif()
 328
 329 #===============================================================================
 330 #= Global Include Directories
 331 #-------------------------------------------------------------------------------
 332
 333 include_directories(
 334         ${CMAKE_CURRENT_BINARY_DIR}
 335         ${CMAKE_CURRENT_SOURCE_DIR}
 336         ${Boost_INCLUDE_DIRS}
 337         ${QT_INCLUDE_DIRS}
 338 )
 339
 340 if(STATIC_PKGDEPS_LIBS)
 341         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 342 else()
 343         include_directories(${PKGDEPS_INCLUDE_DIRS})
 344 endif()
 345
 346 #===============================================================================
 347 #= Linker Configuration
 348 #-------------------------------------------------------------------------------
 349
 350 link_directories(${Boost_LIBRARY_DIRS})
 351
 352 set(PULSEVIEW_LINK_LIBS
 353         ${Boost_LIBRARIES}
 354         ${QT_LIBRARIES}
 355         ${CMAKE_THREAD_LIBS_INIT}
 356 )
 357
 358 if(STATIC_PKGDEPS_LIBS)
 359         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 360         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 361 if(WIN32)
 362         # Workaround for a MinGW linking issue.
 363         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 364 endif()
 365 else()
 366         link_directories(${PKGDEPS_LIBRARY_DIRS})
 367         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 368 endif()
 369
 370 if(WIN32)
 371         # On Windows we need to statically link the libqsvg imageformat
 372         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 373         add_definitions(-DQT_STATICPLUGIN)
 374         link_directories("${QT_PLUGINS_DIR}/imageformats")
 375         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 376         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 377 endif()
 378
 379 if(ANDROID)
 380         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 381 endif()
 382
 383 if(ANDROID)
 384 add_library(${PROJECT_NAME} SHARED
 385         ${pulseview_SOURCES}
 386         ${pulseview_HEADERS_MOC}
 387         ${pulseview_FORMS_HEADERS}
 388         ${pulseview_RESOURCES_RCC}
 389 )
 390 else()
 391 add_executable(${PROJECT_NAME}
 392         ${pulseview_SOURCES}
 393         ${pulseview_HEADERS_MOC}
 394         ${pulseview_FORMS_HEADERS}
 395         ${pulseview_RESOURCES_RCC}
 396 )
 397 endif()
 398
 399 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 400
 401 if(WIN32)
 402         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 403         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 404 endif()
 405
 406 #===============================================================================
 407 #= Installation
 408 #-------------------------------------------------------------------------------
 409
 410 # Install the executable.
 411 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 412
 413 # Install the manpage.
 414 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 415
 416 #===============================================================================
 417 #= Packaging (handled by CPack)
 418 #-------------------------------------------------------------------------------
 419
 420 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 421 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 422 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 423 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 424 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 425 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 426 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 427         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 428 set(CPACK_SOURCE_GENERATOR "TGZ")
 429
 430 include(CPack)
 431
 432 #===============================================================================
 433 #= Tests
 434 #-------------------------------------------------------------------------------
 435
 436 if(ENABLE_TESTS)
 437         add_subdirectory(test)
 438         enable_testing()
 439         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 440 endif()