CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_TESTS "Enable unit tests" FALSE)
  32 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  33
  34 if(WIN32)
  35         # On Windows/MinGW we need to statically link to libraries.
  36         # This option is user configurable, but enable it by default on win32.
  37         set(STATIC_PKGDEPS_LIBS TRUE)
  38
  39         # For boost-thread we need two additional settings on win32:
  40         set(Boost_USE_STATIC_LIBS on)
  41         add_definitions(-DBOOST_THREAD_USE_LIB)
  42 endif()
  43
  44 #===============================================================================
  45 #= Dependencies
  46 #-------------------------------------------------------------------------------
  47
  48 find_package(PkgConfig)
  49 pkg_check_modules(PKGDEPS REQUIRED
  50         libsigrokdecode>=0.1.0
  51         libsigrok>=0.2.0
  52 )
  53
  54 find_package(Qt4 REQUIRED)
  55
  56 # Find the platform's thread library (needed for boost-thread).
  57 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  58 find_package(Threads)
  59
  60 if(WIN32)
  61 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  62 # The library is named libboost_thread_win32* (not libboost_thread*).
  63 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  64 else()
  65 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  66 endif()
  67
  68 #===============================================================================
  69 #= Config Header
  70 #-------------------------------------------------------------------------------
  71
  72 set(PV_TITLE PulseView)
  73 set(PV_DESCRIPTION "A GUI for sigrok")
  74
  75 set(PV_VERSION_MAJOR 0)
  76 set(PV_VERSION_MINOR 1)
  77 set(PV_VERSION_MICRO 0)
  78 set(PV_VERSION_STRING
  79         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  80 )
  81
  82 configure_file (
  83         ${PROJECT_SOURCE_DIR}/config.h.in
  84         ${PROJECT_BINARY_DIR}/config.h
  85 )
  86
  87 #===============================================================================
  88 #= Sources
  89 #-------------------------------------------------------------------------------
  90
  91 set(pulseview_SOURCES
  92         main.cpp
  93         pv/mainwindow.cpp
  94         pv/samplingbar.cpp
  95         pv/sigsession.cpp
  96         pv/data/analog.cpp
  97         pv/data/analogsnapshot.cpp
  98         pv/data/logic.cpp
  99         pv/data/logicsnapshot.cpp
 100         pv/data/signaldata.cpp
 101         pv/data/snapshot.cpp
 102         pv/dialogs/about.cpp
 103         pv/dialogs/connect.cpp
 104         pv/dialogs/deviceoptions.cpp
 105         pv/prop/double.cpp
 106         pv/prop/enum.cpp
 107         pv/prop/property.cpp
 108         pv/prop/binding/binding.cpp
 109         pv/prop/binding/deviceoptions.cpp
 110         pv/view/analogsignal.cpp
 111         pv/view/cursor.cpp
 112         pv/view/header.cpp
 113         pv/view/logicsignal.cpp
 114         pv/view/ruler.cpp
 115         pv/view/signal.cpp
 116         pv/view/timemarker.cpp
 117         pv/view/view.cpp
 118         pv/view/viewport.cpp
 119 )
 120
 121 set(pulseview_HEADERS
 122         pv/mainwindow.h
 123         pv/samplingbar.h
 124         pv/sigsession.h
 125         pv/dialogs/about.h
 126         pv/dialogs/connect.h
 127         pv/view/cursor.h
 128         pv/view/header.h
 129         pv/view/ruler.h
 130         pv/view/timemarker.h
 131         pv/view/view.h
 132         pv/view/viewport.h
 133 )
 134
 135 set(pulseview_FORMS
 136         pv/dialogs/about.ui
 137 )
 138
 139 set(pulseview_RESOURCES
 140         pulseview.qrc
 141 )
 142
 143 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 144 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 145 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 146
 147 include(${QT_USE_FILE})
 148
 149 #===============================================================================
 150 #= Global Definitions
 151 #-------------------------------------------------------------------------------
 152
 153 add_definitions(${QT_DEFINITIONS})
 154 add_definitions(-Wall -Wextra)
 155
 156 if(NOT DISABLE_WERROR)
 157         add_definitions(-Werror)
 158 endif()
 159
 160 #===============================================================================
 161 #= Global Include Directories
 162 #-------------------------------------------------------------------------------
 163
 164 include_directories(
 165         ${CMAKE_CURRENT_BINARY_DIR}
 166         ${CMAKE_CURRENT_SOURCE_DIR}
 167         ${Boost_INCLUDE_DIRS}
 168 )
 169
 170 if(STATIC_PKGDEPS_LIBS)
 171         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 172 else()
 173         include_directories(${PKGDEPS_INCLUDE_DIRS})
 174 endif()
 175
 176 #===============================================================================
 177 #= Linker Configuration
 178 #-------------------------------------------------------------------------------
 179
 180 link_directories(${Boost_LIBRARY_DIRS})
 181
 182 set(PULSEVIEW_LINK_LIBS
 183         ${Boost_LIBRARIES}
 184         ${CMAKE_THREAD_LIBS_INIT}
 185         ${QT_LIBRARIES}
 186 )
 187
 188 if(STATIC_PKGDEPS_LIBS)
 189         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 190         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 191 else()
 192         link_directories(${PKGDEPS_LIBRARY_DIRS})
 193         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 194 endif()
 195
 196 add_executable(${PROJECT_NAME}
 197         ${pulseview_SOURCES}
 198         ${pulseview_HEADERS_MOC}
 199         ${pulseview_FORMS_HEADERS}
 200         ${pulseview_RESOURCES_RCC}
 201 )
 202
 203 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 204
 205 #===============================================================================
 206 #= Installation
 207 #-------------------------------------------------------------------------------
 208
 209 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 210
 211 #===============================================================================
 212 #= Packaging (handled by CPack)
 213 #-------------------------------------------------------------------------------
 214
 215 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 216 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 217 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 218 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 219 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 220 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 221 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 222         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 223 set(CPACK_SOURCE_GENERATOR "TGZ")
 224
 225 include(CPack)
 226
 227 #===============================================================================
 228 #= Tests
 229 #-------------------------------------------------------------------------------
 230
 231 if(ENABLE_TESTS)
 232         add_subdirectory(test)
 233         enable_testing()
 234         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 235 endif(ENABLE_TESTS)