CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57       FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrok>=0.2.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  68 endif()
  69
  70 find_package(PkgConfig)
  71 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  72
  73 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  74 find_package(Qt4 REQUIRED)
  75
  76 # Find the platform's thread library (needed for boost-thread).
  77 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  78 find_package(Threads)
  79
  80 if(WIN32)
  81         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  82         # The library is named libboost_thread_win32* (not libboost_thread*).
  83         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  84 else()
  85         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  86 endif()
  87
  88 #===============================================================================
  89 #= Config Header
  90 #-------------------------------------------------------------------------------
  91
  92 set(PV_TITLE PulseView)
  93 set(PV_DESCRIPTION "A GUI for sigrok")
  94
  95 set(PV_VERSION_MAJOR 0)
  96 set(PV_VERSION_MINOR 1)
  97 set(PV_VERSION_MICRO 0)
  98 set(PV_VERSION_STRING
  99         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 100 )
 101
 102 configure_file (
 103         ${PROJECT_SOURCE_DIR}/config.h.in
 104         ${PROJECT_BINARY_DIR}/config.h
 105 )
 106
 107 #===============================================================================
 108 #= Sources
 109 #-------------------------------------------------------------------------------
 110
 111 set(pulseview_SOURCES
 112         main.cpp
 113         pv/devicemanager.cpp
 114         pv/devinst.cpp
 115         pv/mainwindow.cpp
 116         pv/sigsession.cpp
 117         pv/storesession.cpp
 118         pv/data/analog.cpp
 119         pv/data/analogsnapshot.cpp
 120         pv/data/logic.cpp
 121         pv/data/logicsnapshot.cpp
 122         pv/data/signaldata.cpp
 123         pv/data/snapshot.cpp
 124         pv/dialogs/about.cpp
 125         pv/dialogs/connect.cpp
 126         pv/dialogs/storeprogress.cpp
 127         pv/popups/deviceoptions.cpp
 128         pv/popups/probes.cpp
 129         pv/prop/bool.cpp
 130         pv/prop/double.cpp
 131         pv/prop/enum.cpp
 132         pv/prop/int.cpp
 133         pv/prop/property.cpp
 134         pv/prop/string.cpp
 135         pv/prop/binding/binding.cpp
 136         pv/prop/binding/deviceoptions.cpp
 137         pv/toolbars/samplingbar.cpp
 138         pv/view/analogsignal.cpp
 139         pv/view/cursor.cpp
 140         pv/view/cursorpair.cpp
 141         pv/view/header.cpp
 142         pv/view/marginwidget.cpp
 143         pv/view/logicsignal.cpp
 144         pv/view/ruler.cpp
 145         pv/view/selectableitem.cpp
 146         pv/view/signal.cpp
 147         pv/view/timemarker.cpp
 148         pv/view/trace.cpp
 149         pv/view/tracepalette.cpp
 150         pv/view/view.cpp
 151         pv/view/viewport.cpp
 152         pv/widgets/colourbutton.cpp
 153         pv/widgets/colourpopup.cpp
 154         pv/widgets/popup.cpp
 155         pv/widgets/popuptoolbutton.cpp
 156         pv/widgets/sweeptimingwidget.cpp
 157         pv/widgets/wellarray.cpp
 158 )
 159
 160 # This list includes only QObject derived class headers.
 161 set(pulseview_HEADERS
 162         pv/mainwindow.h
 163         pv/sigsession.h
 164         pv/storesession.h
 165         pv/dialogs/about.h
 166         pv/dialogs/connect.h
 167         pv/dialogs/storeprogress.h
 168         pv/popups/probes.h
 169         pv/popups/deviceoptions.h
 170         pv/prop/bool.h
 171         pv/prop/double.h
 172         pv/prop/enum.h
 173         pv/prop/int.h
 174         pv/prop/property.h
 175         pv/prop/string.h
 176         pv/toolbars/samplingbar.h
 177         pv/view/cursor.h
 178         pv/view/header.h
 179         pv/view/logicsignal.h
 180         pv/view/marginwidget.h
 181         pv/view/ruler.h
 182         pv/view/selectableitem.h
 183         pv/view/signal.h
 184         pv/view/timemarker.h
 185         pv/view/trace.h
 186         pv/view/view.h
 187         pv/view/viewport.h
 188         pv/widgets/colourbutton.h
 189         pv/widgets/colourpopup.h
 190         pv/widgets/popup.h
 191         pv/widgets/popuptoolbutton.h
 192         pv/widgets/sweeptimingwidget.h
 193         pv/widgets/wellarray.h
 194 )
 195
 196 set(pulseview_FORMS
 197         pv/dialogs/about.ui
 198 )
 199
 200 set(pulseview_RESOURCES
 201         pulseview.qrc
 202 )
 203
 204 if(ENABLE_SIGNALS)
 205         list(APPEND pulseview_SOURCES signalhandler.cpp)
 206         list(APPEND pulseview_HEADERS signalhandler.h)
 207 endif()
 208
 209 if(ENABLE_DECODE)
 210         list(APPEND pulseview_SOURCES
 211                 pv/data/decoderstack.cpp
 212                 pv/data/decode/annotation.cpp
 213                 pv/data/decode/decoder.cpp
 214                 pv/data/decode/row.cpp
 215                 pv/data/decode/rowdata.cpp
 216                 pv/prop/binding/decoderoptions.cpp
 217                 pv/view/decodetrace.cpp
 218                 pv/widgets/decodergroupbox.cpp
 219                 pv/widgets/decodermenu.cpp
 220         )
 221
 222         list(APPEND pulseview_HEADERS
 223                 pv/data/decoderstack.h
 224                 pv/view/decodetrace.h
 225                 pv/widgets/decodergroupbox.h
 226                 pv/widgets/decodermenu.h
 227         )
 228 endif()
 229
 230 if(WIN32)
 231         # Use the sigrok icon for the pulseview.exe executable.
 232         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 233         enable_language(RC)
 234         list(APPEND pulseview_SOURCES pulseviewico.rc)
 235 endif()
 236
 237 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 238 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 239 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 240
 241 include(${QT_USE_FILE})
 242
 243 #===============================================================================
 244 #= Global Definitions
 245 #-------------------------------------------------------------------------------
 246
 247 add_definitions(${QT_DEFINITIONS})
 248 add_definitions(-D__STDC_LIMIT_MACROS)
 249 add_definitions(-Wall -Wextra)
 250
 251 if(ENABLE_DECODE)
 252         add_definitions(-DENABLE_DECODE)
 253 endif()
 254
 255 if(NOT DISABLE_WERROR)
 256         add_definitions(-Werror)
 257 endif()
 258
 259 #===============================================================================
 260 #= Global Include Directories
 261 #-------------------------------------------------------------------------------
 262
 263 include_directories(
 264         ${CMAKE_CURRENT_BINARY_DIR}
 265         ${CMAKE_CURRENT_SOURCE_DIR}
 266         ${Boost_INCLUDE_DIRS}
 267 )
 268
 269 if(STATIC_PKGDEPS_LIBS)
 270         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 271 else()
 272         include_directories(${PKGDEPS_INCLUDE_DIRS})
 273 endif()
 274
 275 #===============================================================================
 276 #= Linker Configuration
 277 #-------------------------------------------------------------------------------
 278
 279 link_directories(${Boost_LIBRARY_DIRS})
 280
 281 set(PULSEVIEW_LINK_LIBS
 282         ${Boost_LIBRARIES}
 283         ${CMAKE_THREAD_LIBS_INIT}
 284         ${QT_LIBRARIES}
 285 )
 286
 287 if(STATIC_PKGDEPS_LIBS)
 288         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 289         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 290 if(WIN32)
 291         # Workaround for a MinGW linking issue.
 292         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 293 endif()
 294 else()
 295         link_directories(${PKGDEPS_LIBRARY_DIRS})
 296         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 297 endif()
 298
 299 if(WIN32)
 300         # On Windows we need to statically link the libqsvg imageformat
 301         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 302         add_definitions(-DQT_STATICPLUGIN)
 303         link_directories("${QT_PLUGINS_DIR}/imageformats")
 304         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 305         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 306 endif()
 307
 308 add_executable(${PROJECT_NAME}
 309         ${pulseview_SOURCES}
 310         ${pulseview_HEADERS_MOC}
 311         ${pulseview_FORMS_HEADERS}
 312         ${pulseview_RESOURCES_RCC}
 313 )
 314
 315 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 316
 317 if(WIN32)
 318         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 319         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 320 endif()
 321
 322 if(ENABLE_COTIRE)
 323         include(cotire)
 324         cotire(${PROJECT_NAME})
 325 endif()
 326
 327 #===============================================================================
 328 #= Installation
 329 #-------------------------------------------------------------------------------
 330
 331 # Install the executable.
 332 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 333
 334 # Install the manpage.
 335 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 336
 337 #===============================================================================
 338 #= Packaging (handled by CPack)
 339 #-------------------------------------------------------------------------------
 340
 341 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 342 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 343 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 344 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 345 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 346 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 347 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 348         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 349 set(CPACK_SOURCE_GENERATOR "TGZ")
 350
 351 include(CPack)
 352
 353 #===============================================================================
 354 #= Tests
 355 #-------------------------------------------------------------------------------
 356
 357 if(ENABLE_TESTS)
 358         add_subdirectory(test)
 359         enable_testing()
 360         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 361 endif()