CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.3.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 2)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_STRING
 129         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 130 )
 131
 132 configure_file (
 133         ${PROJECT_SOURCE_DIR}/config.h.in
 134         ${PROJECT_BINARY_DIR}/config.h
 135 )
 136
 137 #===============================================================================
 138 #= Sources
 139 #-------------------------------------------------------------------------------
 140
 141 set(pulseview_SOURCES
 142         main.cpp
 143         pv/application.cpp
 144         pv/devicemanager.cpp
 145         pv/mainwindow.cpp
 146         pv/session.cpp
 147         pv/storesession.cpp
 148         pv/util.cpp
 149         pv/binding/binding.cpp
 150         pv/binding/device.cpp
 151         pv/data/analog.cpp
 152         pv/data/analogsegment.cpp
 153         pv/data/logic.cpp
 154         pv/data/logicsegment.cpp
 155         pv/data/signaldata.cpp
 156         pv/data/segment.cpp
 157         pv/dialogs/about.cpp
 158         pv/dialogs/connect.cpp
 159         pv/dialogs/storeprogress.cpp
 160         pv/popups/deviceoptions.cpp
 161         pv/popups/channels.cpp
 162         pv/prop/bool.cpp
 163         pv/prop/double.cpp
 164         pv/prop/enum.cpp
 165         pv/prop/int.cpp
 166         pv/prop/property.cpp
 167         pv/prop/string.cpp
 168         pv/toolbars/mainbar.cpp
 169         pv/view/analogsignal.cpp
 170         pv/view/cursor.cpp
 171         pv/view/cursorpair.cpp
 172         pv/view/flag.cpp
 173         pv/view/header.cpp
 174         pv/view/marginwidget.cpp
 175         pv/view/logicsignal.cpp
 176         pv/view/rowitem.cpp
 177         pv/view/rowitemowner.cpp
 178         pv/view/ruler.cpp
 179         pv/view/signal.cpp
 180         pv/view/timeitem.cpp
 181         pv/view/timemarker.cpp
 182         pv/view/trace.cpp
 183         pv/view/tracegroup.cpp
 184         pv/view/tracepalette.cpp
 185         pv/view/view.cpp
 186         pv/view/viewitem.cpp
 187         pv/view/viewitempaintparams.cpp
 188         pv/view/viewport.cpp
 189         pv/view/viewwidget.cpp
 190         pv/widgets/colourbutton.cpp
 191         pv/widgets/colourpopup.cpp
 192         pv/widgets/devicetoolbutton.cpp
 193         pv/widgets/exportmenu.cpp
 194         pv/widgets/hidingmenubar.cpp
 195         pv/widgets/popup.cpp
 196         pv/widgets/popuptoolbutton.cpp
 197         pv/widgets/sweeptimingwidget.cpp
 198         pv/widgets/wellarray.cpp
 199 )
 200
 201 # This list includes only QObject derived class headers.
 202 set(pulseview_HEADERS
 203         pv/mainwindow.hpp
 204         pv/session.hpp
 205         pv/storesession.hpp
 206         pv/binding/device.hpp
 207         pv/dialogs/about.hpp
 208         pv/dialogs/connect.hpp
 209         pv/dialogs/storeprogress.hpp
 210         pv/popups/channels.hpp
 211         pv/popups/deviceoptions.hpp
 212         pv/prop/bool.hpp
 213         pv/prop/double.hpp
 214         pv/prop/enum.hpp
 215         pv/prop/int.hpp
 216         pv/prop/property.hpp
 217         pv/prop/string.hpp
 218         pv/toolbars/mainbar.hpp
 219         pv/view/cursor.hpp
 220         pv/view/flag.hpp
 221         pv/view/header.hpp
 222         pv/view/logicsignal.hpp
 223         pv/view/marginwidget.hpp
 224         pv/view/rowitem.hpp
 225         pv/view/ruler.hpp
 226         pv/view/signal.hpp
 227         pv/view/timeitem.hpp
 228         pv/view/timemarker.hpp
 229         pv/view/trace.hpp
 230         pv/view/tracegroup.hpp
 231         pv/view/view.hpp
 232         pv/view/viewitem.hpp
 233         pv/view/viewport.hpp
 234         pv/view/viewwidget.hpp
 235         pv/widgets/colourbutton.hpp
 236         pv/widgets/colourpopup.hpp
 237         pv/widgets/devicetoolbutton.hpp
 238         pv/widgets/exportmenu.hpp
 239         pv/widgets/hidingmenubar.hpp
 240         pv/widgets/popup.hpp
 241         pv/widgets/popuptoolbutton.hpp
 242         pv/widgets/sweeptimingwidget.hpp
 243         pv/widgets/wellarray.hpp
 244 )
 245
 246 set(pulseview_FORMS
 247         pv/dialogs/about.ui
 248 )
 249
 250 set(pulseview_RESOURCES
 251         pulseview.qrc
 252 )
 253
 254 if(ENABLE_SIGNALS)
 255         list(APPEND pulseview_SOURCES signalhandler.cpp)
 256         list(APPEND pulseview_HEADERS signalhandler.hpp)
 257 endif()
 258
 259 if(ENABLE_DECODE)
 260         list(APPEND pulseview_SOURCES
 261                 pv/binding/decoder.cpp
 262                 pv/data/decoderstack.cpp
 263                 pv/data/decode/annotation.cpp
 264                 pv/data/decode/decoder.cpp
 265                 pv/data/decode/row.cpp
 266                 pv/data/decode/rowdata.cpp
 267                 pv/view/decodetrace.cpp
 268                 pv/widgets/decodergroupbox.cpp
 269                 pv/widgets/decodermenu.cpp
 270         )
 271
 272         list(APPEND pulseview_HEADERS
 273                 pv/data/decoderstack.hpp
 274                 pv/view/decodetrace.hpp
 275                 pv/widgets/decodergroupbox.hpp
 276                 pv/widgets/decodermenu.hpp
 277         )
 278 endif()
 279
 280 if(WIN32)
 281         # Use the sigrok icon for the pulseview.exe executable.
 282         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 283         enable_language(RC)
 284         list(APPEND pulseview_SOURCES pulseviewico.rc)
 285 endif()
 286
 287 if(ANDROID)
 288         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 289 endif()
 290
 291 if(Qt5Core_FOUND)
 292         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 293         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 294         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 295 else()
 296         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 297         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 298         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 299         include(${QT_USE_FILE})
 300 endif()
 301
 302 #===============================================================================
 303 #= Global Definitions
 304 #-------------------------------------------------------------------------------
 305
 306 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 307 add_definitions(-D__STDC_LIMIT_MACROS)
 308 add_definitions(-Wall -Wextra)
 309 add_definitions(-std=c++11)
 310
 311 if(ENABLE_DECODE)
 312         add_definitions(-DENABLE_DECODE)
 313 endif()
 314
 315 if(NOT DISABLE_WERROR)
 316         add_definitions(-Werror)
 317 endif()
 318
 319 if(ENABLE_SIGNALS)
 320         add_definitions(-DENABLE_SIGNALS)
 321 endif()
 322
 323 #===============================================================================
 324 #= Global Include Directories
 325 #-------------------------------------------------------------------------------
 326
 327 include_directories(
 328         ${CMAKE_CURRENT_BINARY_DIR}
 329         ${CMAKE_CURRENT_SOURCE_DIR}
 330         ${Boost_INCLUDE_DIRS}
 331         ${QT_INCLUDE_DIRS}
 332 )
 333
 334 if(STATIC_PKGDEPS_LIBS)
 335         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 336 else()
 337         include_directories(${PKGDEPS_INCLUDE_DIRS})
 338 endif()
 339
 340 #===============================================================================
 341 #= Linker Configuration
 342 #-------------------------------------------------------------------------------
 343
 344 link_directories(${Boost_LIBRARY_DIRS})
 345
 346 set(PULSEVIEW_LINK_LIBS
 347         ${Boost_LIBRARIES}
 348         ${QT_LIBRARIES}
 349         ${CMAKE_THREAD_LIBS_INIT}
 350 )
 351
 352 if(STATIC_PKGDEPS_LIBS)
 353         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 354         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 355 if(WIN32)
 356         # Workaround for a MinGW linking issue.
 357         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 358 endif()
 359 else()
 360         link_directories(${PKGDEPS_LIBRARY_DIRS})
 361         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 362 endif()
 363
 364 if(WIN32)
 365         # On Windows we need to statically link the libqsvg imageformat
 366         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 367         add_definitions(-DQT_STATICPLUGIN)
 368         link_directories("${QT_PLUGINS_DIR}/imageformats")
 369         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 370         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 371 endif()
 372
 373 if(ANDROID)
 374         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 375 endif()
 376
 377 if(ANDROID)
 378 add_library(${PROJECT_NAME} SHARED
 379         ${pulseview_SOURCES}
 380         ${pulseview_HEADERS_MOC}
 381         ${pulseview_FORMS_HEADERS}
 382         ${pulseview_RESOURCES_RCC}
 383 )
 384 else()
 385 add_executable(${PROJECT_NAME}
 386         ${pulseview_SOURCES}
 387         ${pulseview_HEADERS_MOC}
 388         ${pulseview_FORMS_HEADERS}
 389         ${pulseview_RESOURCES_RCC}
 390 )
 391 endif()
 392
 393 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 394
 395 if(WIN32)
 396         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 397         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 398 endif()
 399
 400 #===============================================================================
 401 #= Installation
 402 #-------------------------------------------------------------------------------
 403
 404 # Install the executable.
 405 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 406
 407 # Install the manpage.
 408 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 409
 410 #===============================================================================
 411 #= Packaging (handled by CPack)
 412 #-------------------------------------------------------------------------------
 413
 414 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 415 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 416 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 417 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 418 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 419 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 420 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 421         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 422 set(CPACK_SOURCE_GENERATOR "TGZ")
 423
 424 include(CPack)
 425
 426 #===============================================================================
 427 #= Tests
 428 #-------------------------------------------------------------------------------
 429
 430 if(ENABLE_TESTS)
 431         add_subdirectory(test)
 432         enable_testing()
 433         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 434 endif()