CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27 include(cotire)
  28
  29 project(pulseview)
  30
  31 #===============================================================================
  32 #= User Options
  33 #-------------------------------------------------------------------------------
  34
  35 option(DISABLE_WERROR "Build without -Werror" FALSE)
  36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  39
  40 if(WIN32)
  41         # On Windows/MinGW we need to statically link to libraries.
  42         # This option is user configurable, but enable it by default on win32.
  43         set(STATIC_PKGDEPS_LIBS TRUE)
  44
  45         # For boost-thread we need two additional settings on win32:
  46         set(Boost_USE_STATIC_LIBS on)
  47         add_definitions(-DBOOST_THREAD_USE_LIB)
  48
  49         # Windsws does not support UNIX signals
  50         set(ENABLE_SIGNALS FALSE)
  51 endif()
  52
  53 #===============================================================================
  54 #= Dependencies
  55 #-------------------------------------------------------------------------------
  56
  57 list(APPEND PKGDEPS
  58         libsigrok>=0.2.0
  59         libsigrokdecode>=0.2.0
  60 )
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  66 find_package(Qt4 REQUIRED)
  67
  68 # Find the platform's thread library (needed for boost-thread).
  69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  70 find_package(Threads)
  71
  72 if(WIN32)
  73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  74 # The library is named libboost_thread_win32* (not libboost_thread*).
  75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  76 else()
  77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  78 endif()
  79
  80 #===============================================================================
  81 #= Config Header
  82 #-------------------------------------------------------------------------------
  83
  84 set(PV_TITLE PulseView)
  85 set(PV_DESCRIPTION "A GUI for sigrok")
  86
  87 set(PV_VERSION_MAJOR 0)
  88 set(PV_VERSION_MINOR 1)
  89 set(PV_VERSION_MICRO 0)
  90 set(PV_VERSION_STRING
  91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  92 )
  93
  94 configure_file (
  95         ${PROJECT_SOURCE_DIR}/config.h.in
  96         ${PROJECT_BINARY_DIR}/config.h
  97 )
  98
  99 #===============================================================================
 100 #= Sources
 101 #-------------------------------------------------------------------------------
 102
 103 set(pulseview_SOURCES
 104         main.cpp
 105         pv/devicemanager.cpp
 106         pv/mainwindow.cpp
 107         pv/sigsession.cpp
 108         pv/data/analog.cpp
 109         pv/data/analogsnapshot.cpp
 110         pv/data/decoder.cpp
 111         pv/data/logic.cpp
 112         pv/data/logicsnapshot.cpp
 113         pv/data/signaldata.cpp
 114         pv/data/snapshot.cpp
 115         pv/dialogs/about.cpp
 116         pv/dialogs/connect.cpp
 117         pv/dialogs/decoder.cpp
 118         pv/dialogs/deviceoptions.cpp
 119         pv/prop/bool.cpp
 120         pv/prop/double.cpp
 121         pv/prop/enum.cpp
 122         pv/prop/int.cpp
 123         pv/prop/property.cpp
 124         pv/prop/binding/binding.cpp
 125         pv/prop/binding/deviceoptions.cpp
 126         pv/toolbars/contextbar.cpp
 127         pv/toolbars/samplingbar.cpp
 128         pv/view/analogsignal.cpp
 129         pv/view/cursor.cpp
 130         pv/view/cursorpair.cpp
 131         pv/view/decodesignal.cpp
 132         pv/view/header.cpp
 133         pv/view/marginwidget.cpp
 134         pv/view/logicsignal.cpp
 135         pv/view/ruler.cpp
 136         pv/view/selectableitem.cpp
 137         pv/view/signal.cpp
 138         pv/view/timemarker.cpp
 139         pv/view/trace.cpp
 140         pv/view/view.cpp
 141         pv/view/viewport.cpp
 142         pv/view/decode/annotation.cpp
 143 )
 144
 145 # This list includes only QObject derrived class headers
 146 set(pulseview_HEADERS
 147         pv/mainwindow.h
 148         pv/sigsession.h
 149         pv/dialogs/about.h
 150         pv/dialogs/connect.h
 151         pv/dialogs/deviceoptions.h
 152         pv/toolbars/contextbar.h
 153         pv/toolbars/samplingbar.h
 154         pv/view/cursor.h
 155         pv/view/header.h
 156         pv/view/logicsignal.h
 157         pv/view/marginwidget.h
 158         pv/view/ruler.h
 159         pv/view/selectableitem.h
 160         pv/view/signal.h
 161         pv/view/timemarker.h
 162         pv/view/trace.h
 163         pv/view/view.h
 164         pv/view/viewport.h
 165 )
 166
 167 set(pulseview_FORMS
 168         pv/dialogs/about.ui
 169 )
 170
 171 set(pulseview_RESOURCES
 172         pulseview.qrc
 173 )
 174
 175 if(ENABLE_SIGNALS)
 176         list(APPEND pulseview_SOURCES signalhandler.cpp)
 177         list(APPEND pulseview_HEADERS signalhandler.h)
 178 endif()
 179
 180 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 181 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 182 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 183
 184 include(${QT_USE_FILE})
 185
 186 #===============================================================================
 187 #= Global Definitions
 188 #-------------------------------------------------------------------------------
 189
 190 add_definitions(${QT_DEFINITIONS})
 191 add_definitions(-Wall -Wextra)
 192
 193 if(NOT DISABLE_WERROR)
 194         add_definitions(-Werror)
 195 endif()
 196
 197 #===============================================================================
 198 #= Global Include Directories
 199 #-------------------------------------------------------------------------------
 200
 201 include_directories(
 202         ${CMAKE_CURRENT_BINARY_DIR}
 203         ${CMAKE_CURRENT_SOURCE_DIR}
 204         ${Boost_INCLUDE_DIRS}
 205 )
 206
 207 if(STATIC_PKGDEPS_LIBS)
 208         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 209 else()
 210         include_directories(${PKGDEPS_INCLUDE_DIRS})
 211 endif()
 212
 213 #===============================================================================
 214 #= Linker Configuration
 215 #-------------------------------------------------------------------------------
 216
 217 link_directories(${Boost_LIBRARY_DIRS})
 218
 219 set(PULSEVIEW_LINK_LIBS
 220         ${Boost_LIBRARIES}
 221         ${CMAKE_THREAD_LIBS_INIT}
 222         ${QT_LIBRARIES}
 223 )
 224
 225 if(STATIC_PKGDEPS_LIBS)
 226         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 227         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 228 else()
 229         link_directories(${PKGDEPS_LIBRARY_DIRS})
 230         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 231 endif()
 232
 233 add_executable(${PROJECT_NAME}
 234         ${pulseview_SOURCES}
 235         ${pulseview_HEADERS_MOC}
 236         ${pulseview_FORMS_HEADERS}
 237         ${pulseview_RESOURCES_RCC}
 238 )
 239
 240 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 241 cotire(${PROJECT_NAME})
 242
 243 if(WIN32)
 244 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 245 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 246 endif()
 247
 248 #===============================================================================
 249 #= Installation
 250 #-------------------------------------------------------------------------------
 251
 252 # Install the executable.
 253 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 254
 255 # Install the manpage.
 256 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 257
 258 #===============================================================================
 259 #= Packaging (handled by CPack)
 260 #-------------------------------------------------------------------------------
 261
 262 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 263 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 264 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 265 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 266 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 267 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 268 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 269         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 270 set(CPACK_SOURCE_GENERATOR "TGZ")
 271
 272 include(CPack)
 273
 274 #===============================================================================
 275 #= Tests
 276 #-------------------------------------------------------------------------------
 277
 278 if(ENABLE_TESTS)
 279         add_subdirectory(test)
 280         enable_testing()
 281         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 282 endif(ENABLE_TESTS)