CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_TESTS "Enable unit tests" FALSE)
  32 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  33
  34 if(WIN32)
  35         # On Windows/MinGW we need to statically link to libraries.
  36         # This option is user configurable, but enable it by default on win32.
  37         set(STATIC_PKGDEPS_LIBS TRUE)
  38
  39         # For boost-thread we need two additional settings on win32:
  40         set(Boost_USE_STATIC_LIBS on)
  41         add_definitions(-DBOOST_THREAD_USE_LIB)
  42 endif()
  43
  44 #===============================================================================
  45 #= Dependencies
  46 #-------------------------------------------------------------------------------
  47
  48 find_package(PkgConfig)
  49 pkg_check_modules(PKGDEPS REQUIRED
  50         libsigrokdecode>=0.1.0
  51         libsigrok>=0.2.0
  52 )
  53
  54 find_package(Qt4 REQUIRED)
  55
  56 if(WIN32)
  57 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  58 # The library is named libboost_thread_win32* (not libboost_thread*).
  59 find_package(Boost 1.42 COMPONENTS system thread_win32)
  60 else()
  61 find_package(Boost 1.42 COMPONENTS system thread)
  62 endif()
  63
  64 #===============================================================================
  65 #= Config Header
  66 #-------------------------------------------------------------------------------
  67
  68 set(PV_TITLE PulseView)
  69 set(PV_DESCRIPTION "A GUI for sigrok")
  70
  71 set(PV_VERSION_MAJOR 0)
  72 set(PV_VERSION_MINOR 1)
  73 set(PV_VERSION_MICRO 0)
  74 set(PV_VERSION_STRING
  75         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  76 )
  77
  78 configure_file (
  79         ${PROJECT_SOURCE_DIR}/config.h.in
  80         ${PROJECT_BINARY_DIR}/config.h
  81 )
  82
  83 #===============================================================================
  84 #= Sources
  85 #-------------------------------------------------------------------------------
  86
  87 set(pulseview_SOURCES
  88         main.cpp
  89         pv/mainwindow.cpp
  90         pv/samplingbar.cpp
  91         pv/sigsession.cpp
  92         pv/data/analog.cpp
  93         pv/data/analogsnapshot.cpp
  94         pv/data/logic.cpp
  95         pv/data/logicsnapshot.cpp
  96         pv/data/signaldata.cpp
  97         pv/data/snapshot.cpp
  98         pv/dialogs/about.cpp
  99         pv/dialogs/hwcap.cpp
 100         pv/prop/enum.cpp
 101         pv/prop/property.cpp
 102         pv/prop/binding/binding.cpp
 103         pv/prop/binding/hwcap.cpp
 104         pv/view/analogsignal.cpp
 105         pv/view/cursor.cpp
 106         pv/view/header.cpp
 107         pv/view/logicsignal.cpp
 108         pv/view/ruler.cpp
 109         pv/view/signal.cpp
 110         pv/view/timemarker.cpp
 111         pv/view/view.cpp
 112         pv/view/viewport.cpp
 113 )
 114
 115 set(pulseview_HEADERS
 116         pv/mainwindow.h
 117         pv/samplingbar.h
 118         pv/sigsession.h
 119         pv/dialogs/about.h
 120         pv/view/cursor.h
 121         pv/view/header.h
 122         pv/view/ruler.h
 123         pv/view/timemarker.h
 124         pv/view/view.h
 125         pv/view/viewport.h
 126 )
 127
 128 set(pulseview_FORMS
 129         pv/dialogs/about.ui
 130 )
 131
 132 set(pulseview_RESOURCES
 133         pulseview.qrc
 134 )
 135
 136 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 137 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 138 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 139
 140 include(${QT_USE_FILE})
 141
 142 #===============================================================================
 143 #= Global Definitions
 144 #-------------------------------------------------------------------------------
 145
 146 add_definitions(${QT_DEFINITIONS})
 147 add_definitions(-Wextra)
 148
 149 if(NOT DISABLE_WERROR)
 150         add_definitions(-Werror)
 151 endif()
 152
 153 #===============================================================================
 154 #= Global Include Directories
 155 #-------------------------------------------------------------------------------
 156
 157 include_directories(
 158         ${CMAKE_CURRENT_BINARY_DIR}
 159         ${CMAKE_CURRENT_SOURCE_DIR}
 160         ${Boost_INCLUDE_DIRS}
 161 )
 162
 163 if(STATIC_PKGDEPS_LIBS)
 164         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 165 else()
 166         include_directories(${PKGDEPS_INCLUDE_DIRS})
 167 endif()
 168
 169 #===============================================================================
 170 #= Linker Configuration
 171 #-------------------------------------------------------------------------------
 172
 173 link_directories(${Boost_LIBRARY_DIRS})
 174
 175 set(PULSEVIEW_LINK_LIBS
 176         ${Boost_LIBRARIES}
 177         ${QT_LIBRARIES}
 178 )
 179
 180 if(STATIC_PKGDEPS_LIBS)
 181         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 182         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 183 else()
 184         link_directories(${PKGDEPS_LIBRARY_DIRS})
 185         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 186 endif()
 187
 188 add_executable(${PROJECT_NAME}
 189         ${pulseview_SOURCES}
 190         ${pulseview_HEADERS_MOC}
 191         ${pulseview_FORMS_HEADERS}
 192         ${pulseview_RESOURCES_RCC}
 193 )
 194
 195 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 196
 197 #===============================================================================
 198 #= Installation
 199 #-------------------------------------------------------------------------------
 200
 201 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 202
 203 #===============================================================================
 204 #= Packaging (handled by CPack)
 205 #-------------------------------------------------------------------------------
 206
 207 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 208 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 209 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 210 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 211 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 212 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 213 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 214         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 215 set(CPACK_SOURCE_GENERATOR "TGZ")
 216
 217 include(CPack)
 218
 219 #===============================================================================
 220 #= Tests
 221 #-------------------------------------------------------------------------------
 222
 223 if(ENABLE_TESTS)
 224         add_subdirectory(test)
 225         enable_testing()
 226         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 227 endif(ENABLE_TESTS)