Added decoder stack item deletion
[pulseview.git] / CMakeLists.txt
1
2 ## This file is part of the PulseView project.
3 ##
4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
6 ##
7 ## This program is free software: you can redistribute it and/or modify
8 ## it under the terms of the GNU General Public License as published by
9 ## the Free Software Foundation, either version 2 of the License, or
10 ## (at your option) any later version.
11 ##
12 ## This program is distributed in the hope that it will be useful,
13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 ## GNU General Public License for more details.
16 ##
17 ## You should have received a copy of the GNU General Public License
18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
19 ##
20
21 cmake_minimum_required(VERSION 2.8.6)
22
23 include(FindPkgConfig)
24 include(GNUInstallDirs)
25
26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
27 include(cotire)
28
29 project(pulseview)
30
31 #===============================================================================
32 #= User Options
33 #-------------------------------------------------------------------------------
34
35 option(DISABLE_WERROR "Build without -Werror" FALSE)
36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
37 option(ENABLE_TESTS "Enable unit tests" FALSE)
38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
39
40 if(WIN32)
41         # On Windows/MinGW we need to statically link to libraries.
42         # This option is user configurable, but enable it by default on win32.
43         set(STATIC_PKGDEPS_LIBS TRUE)
44
45         # For boost-thread we need two additional settings on win32:
46         set(Boost_USE_STATIC_LIBS on)
47         add_definitions(-DBOOST_THREAD_USE_LIB)
48
49         # Windsws does not support UNIX signals
50         set(ENABLE_SIGNALS FALSE)
51 endif()
52
53 #===============================================================================
54 #= Dependencies
55 #-------------------------------------------------------------------------------
56
57 list(APPEND PKGDEPS
58         libsigrok>=0.2.0
59         libsigrokdecode>=0.2.0
60 )
61
62 find_package(PkgConfig)
63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
64
65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
66 find_package(Qt4 REQUIRED)
67
68 # Find the platform's thread library (needed for boost-thread).
69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
70 find_package(Threads)
71
72 if(WIN32)
73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
74 # The library is named libboost_thread_win32* (not libboost_thread*).
75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
76 else()
77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
78 endif()
79
80 #===============================================================================
81 #= Config Header
82 #-------------------------------------------------------------------------------
83
84 set(PV_TITLE PulseView)
85 set(PV_DESCRIPTION "A GUI for sigrok")
86
87 set(PV_VERSION_MAJOR 0)
88 set(PV_VERSION_MINOR 1)
89 set(PV_VERSION_MICRO 0)
90 set(PV_VERSION_STRING
91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
92 )
93
94 configure_file (
95         ${PROJECT_SOURCE_DIR}/config.h.in
96         ${PROJECT_BINARY_DIR}/config.h
97 )
98
99 #===============================================================================
100 #= Sources
101 #-------------------------------------------------------------------------------
102
103 set(pulseview_SOURCES
104         main.cpp
105         pv/devicemanager.cpp
106         pv/mainwindow.cpp
107         pv/sigsession.cpp
108         pv/data/analog.cpp
109         pv/data/analogsnapshot.cpp
110         pv/data/decoderstack.cpp
111         pv/data/logic.cpp
112         pv/data/logicsnapshot.cpp
113         pv/data/signaldata.cpp
114         pv/data/snapshot.cpp
115         pv/data/decode/decoder.cpp
116         pv/dialogs/about.cpp
117         pv/dialogs/connect.cpp
118         pv/popups/deviceoptions.cpp
119         pv/popups/probes.cpp
120         pv/prop/bool.cpp
121         pv/prop/double.cpp
122         pv/prop/enum.cpp
123         pv/prop/int.cpp
124         pv/prop/property.cpp
125         pv/prop/string.cpp
126         pv/prop/binding/binding.cpp
127         pv/prop/binding/decoderoptions.cpp
128         pv/prop/binding/deviceoptions.cpp
129         pv/toolbars/samplingbar.cpp
130         pv/view/analogsignal.cpp
131         pv/view/cursor.cpp
132         pv/view/cursorpair.cpp
133         pv/view/decodetrace.cpp
134         pv/view/header.cpp
135         pv/view/marginwidget.cpp
136         pv/view/logicsignal.cpp
137         pv/view/ruler.cpp
138         pv/view/selectableitem.cpp
139         pv/view/signal.cpp
140         pv/view/timemarker.cpp
141         pv/view/trace.cpp
142         pv/view/tracepalette.cpp
143         pv/view/view.cpp
144         pv/view/viewport.cpp
145         pv/view/decode/annotation.cpp
146         pv/widgets/colourbutton.cpp
147         pv/widgets/colourpopup.cpp
148         pv/widgets/decodergroupbox.cpp
149         pv/widgets/decodermenu.cpp
150         pv/widgets/popup.cpp
151         pv/widgets/popuptoolbutton.cpp
152         pv/widgets/wellarray.cpp
153 )
154
155 # This list includes only QObject derrived class headers
156 set(pulseview_HEADERS
157         pv/mainwindow.h
158         pv/sigsession.h
159         pv/data/decoderstack.h
160         pv/dialogs/about.h
161         pv/dialogs/connect.h
162         pv/popups/deviceoptions.h
163         pv/popups/probes.h
164         pv/prop/bool.h
165         pv/prop/double.h
166         pv/prop/enum.h
167         pv/prop/int.h
168         pv/prop/property.h
169         pv/prop/string.h
170         pv/toolbars/samplingbar.h
171         pv/view/cursor.h
172         pv/view/decodetrace.h
173         pv/view/header.h
174         pv/view/logicsignal.h
175         pv/view/marginwidget.h
176         pv/view/ruler.h
177         pv/view/selectableitem.h
178         pv/view/signal.h
179         pv/view/timemarker.h
180         pv/view/trace.h
181         pv/view/view.h
182         pv/view/viewport.h
183         pv/widgets/colourbutton.h
184         pv/widgets/colourpopup.h
185         pv/widgets/decodergroupbox.h
186         pv/widgets/decodermenu.h
187         pv/widgets/popup.h
188         pv/widgets/popuptoolbutton.h
189         pv/widgets/wellarray.h
190 )
191
192 set(pulseview_FORMS
193         pv/dialogs/about.ui
194 )
195
196 set(pulseview_RESOURCES
197         pulseview.qrc
198 )
199
200 if(ENABLE_SIGNALS)
201         list(APPEND pulseview_SOURCES signalhandler.cpp)
202         list(APPEND pulseview_HEADERS signalhandler.h)
203 endif()
204
205 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
206 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
207 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
208
209 include(${QT_USE_FILE})
210
211 #===============================================================================
212 #= Global Definitions
213 #-------------------------------------------------------------------------------
214
215 add_definitions(${QT_DEFINITIONS})
216 add_definitions(-Wall -Wextra)
217
218 if(NOT DISABLE_WERROR)
219         add_definitions(-Werror)
220 endif()
221
222 #===============================================================================
223 #= Global Include Directories
224 #-------------------------------------------------------------------------------
225
226 include_directories(
227         ${CMAKE_CURRENT_BINARY_DIR}
228         ${CMAKE_CURRENT_SOURCE_DIR}
229         ${Boost_INCLUDE_DIRS}
230 )
231
232 if(STATIC_PKGDEPS_LIBS)
233         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
234 else()
235         include_directories(${PKGDEPS_INCLUDE_DIRS})
236 endif()
237
238 #===============================================================================
239 #= Linker Configuration
240 #-------------------------------------------------------------------------------
241
242 link_directories(${Boost_LIBRARY_DIRS})
243
244 set(PULSEVIEW_LINK_LIBS
245         ${Boost_LIBRARIES}
246         ${CMAKE_THREAD_LIBS_INIT}
247         ${QT_LIBRARIES}
248 )
249
250 if(STATIC_PKGDEPS_LIBS)
251         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
252         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
253 else()
254         link_directories(${PKGDEPS_LIBRARY_DIRS})
255         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
256 endif()
257
258 add_executable(${PROJECT_NAME}
259         ${pulseview_SOURCES}
260         ${pulseview_HEADERS_MOC}
261         ${pulseview_FORMS_HEADERS}
262         ${pulseview_RESOURCES_RCC}
263 )
264
265 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
266 cotire(${PROJECT_NAME})
267
268 if(WIN32)
269 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
270 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
271 endif()
272
273 #===============================================================================
274 #= Installation
275 #-------------------------------------------------------------------------------
276
277 # Install the executable.
278 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
279
280 # Install the manpage.
281 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
282
283 #===============================================================================
284 #= Packaging (handled by CPack)
285 #-------------------------------------------------------------------------------
286
287 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
288 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
289 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
290 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
291 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
292 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
293 set(CPACK_SOURCE_PACKAGE_FILE_NAME
294         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
295 set(CPACK_SOURCE_GENERATOR "TGZ")
296
297 include(CPack)
298
299 #===============================================================================
300 #= Tests
301 #-------------------------------------------------------------------------------
302
303 if(ENABLE_TESTS)
304         add_subdirectory(test)
305         enable_testing()
306         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
307 endif(ENABLE_TESTS)