CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokxx>=0.3.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 2)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_STRING
 129         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 130 )
 131
 132 configure_file (
 133         ${PROJECT_SOURCE_DIR}/config.h.in
 134         ${PROJECT_BINARY_DIR}/config.h
 135 )
 136
 137 #===============================================================================
 138 #= Sources
 139 #-------------------------------------------------------------------------------
 140
 141 set(pulseview_SOURCES
 142         main.cpp
 143         pv/application.cpp
 144         pv/devicemanager.cpp
 145         pv/mainwindow.cpp
 146         pv/session.cpp
 147         pv/storesession.cpp
 148         pv/util.cpp
 149         pv/data/analog.cpp
 150         pv/data/analogsnapshot.cpp
 151         pv/data/logic.cpp
 152         pv/data/logicsnapshot.cpp
 153         pv/data/signaldata.cpp
 154         pv/data/snapshot.cpp
 155         pv/dialogs/about.cpp
 156         pv/dialogs/connect.cpp
 157         pv/dialogs/storeprogress.cpp
 158         pv/popups/deviceoptions.cpp
 159         pv/popups/channels.cpp
 160         pv/prop/bool.cpp
 161         pv/prop/double.cpp
 162         pv/prop/enum.cpp
 163         pv/prop/int.cpp
 164         pv/prop/property.cpp
 165         pv/prop/string.cpp
 166         pv/prop/binding/binding.cpp
 167         pv/prop/binding/deviceoptions.cpp
 168         pv/toolbars/samplingbar.cpp
 169         pv/view/analogsignal.cpp
 170         pv/view/cursor.cpp
 171         pv/view/cursorheader.cpp
 172         pv/view/cursorpair.cpp
 173         pv/view/header.cpp
 174         pv/view/marginwidget.cpp
 175         pv/view/logicsignal.cpp
 176         pv/view/rowitem.cpp
 177         pv/view/rowitemowner.cpp
 178         pv/view/rowitempaintparams.cpp
 179         pv/view/ruler.cpp
 180         pv/view/selectableitem.cpp
 181         pv/view/signal.cpp
 182         pv/view/timemarker.cpp
 183         pv/view/trace.cpp
 184         pv/view/tracegroup.cpp
 185         pv/view/tracepalette.cpp
 186         pv/view/view.cpp
 187         pv/view/viewport.cpp
 188         pv/widgets/colourbutton.cpp
 189         pv/widgets/colourpopup.cpp
 190         pv/widgets/popup.cpp
 191         pv/widgets/popuptoolbutton.cpp
 192         pv/widgets/sweeptimingwidget.cpp
 193         pv/widgets/wellarray.cpp
 194 )
 195
 196 # This list includes only QObject derived class headers.
 197 set(pulseview_HEADERS
 198         pv/mainwindow.hpp
 199         pv/session.hpp
 200         pv/storesession.hpp
 201         pv/dialogs/about.hpp
 202         pv/dialogs/connect.hpp
 203         pv/dialogs/storeprogress.hpp
 204         pv/popups/channels.hpp
 205         pv/popups/deviceoptions.hpp
 206         pv/prop/bool.hpp
 207         pv/prop/double.hpp
 208         pv/prop/enum.hpp
 209         pv/prop/int.hpp
 210         pv/prop/property.hpp
 211         pv/prop/string.hpp
 212         pv/prop/binding/deviceoptions.hpp
 213         pv/toolbars/samplingbar.hpp
 214         pv/view/cursor.hpp
 215         pv/view/cursorheader.hpp
 216         pv/view/header.hpp
 217         pv/view/logicsignal.hpp
 218         pv/view/marginwidget.hpp
 219         pv/view/rowitem.hpp
 220         pv/view/ruler.hpp
 221         pv/view/selectableitem.hpp
 222         pv/view/signal.hpp
 223         pv/view/timemarker.hpp
 224         pv/view/trace.hpp
 225         pv/view/tracegroup.hpp
 226         pv/view/view.hpp
 227         pv/view/viewport.hpp
 228         pv/widgets/colourbutton.hpp
 229         pv/widgets/colourpopup.hpp
 230         pv/widgets/popup.hpp
 231         pv/widgets/popuptoolbutton.hpp
 232         pv/widgets/sweeptimingwidget.hpp
 233         pv/widgets/wellarray.hpp
 234 )
 235
 236 set(pulseview_FORMS
 237         pv/dialogs/about.ui
 238 )
 239
 240 set(pulseview_RESOURCES
 241         pulseview.qrc
 242 )
 243
 244 if(ENABLE_SIGNALS)
 245         list(APPEND pulseview_SOURCES signalhandler.cpp)
 246         list(APPEND pulseview_HEADERS signalhandler.hpp)
 247 endif()
 248
 249 if(ENABLE_DECODE)
 250         list(APPEND pulseview_SOURCES
 251                 pv/data/decoderstack.cpp
 252                 pv/data/decode/annotation.cpp
 253                 pv/data/decode/decoder.cpp
 254                 pv/data/decode/row.cpp
 255                 pv/data/decode/rowdata.cpp
 256                 pv/prop/binding/decoderoptions.cpp
 257                 pv/view/decodetrace.cpp
 258                 pv/widgets/decodergroupbox.cpp
 259                 pv/widgets/decodermenu.cpp
 260         )
 261
 262         list(APPEND pulseview_HEADERS
 263                 pv/data/decoderstack.hpp
 264                 pv/view/decodetrace.hpp
 265                 pv/widgets/decodergroupbox.hpp
 266                 pv/widgets/decodermenu.hpp
 267         )
 268 endif()
 269
 270 if(WIN32)
 271         # Use the sigrok icon for the pulseview.exe executable.
 272         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 273         enable_language(RC)
 274         list(APPEND pulseview_SOURCES pulseviewico.rc)
 275 endif()
 276
 277 if(ANDROID)
 278         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 279 endif()
 280
 281 if(Qt5Core_FOUND)
 282         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 283         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 284         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 285 else()
 286         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 287         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 288         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 289         include(${QT_USE_FILE})
 290 endif()
 291
 292 #===============================================================================
 293 #= Global Definitions
 294 #-------------------------------------------------------------------------------
 295
 296 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 297 add_definitions(-D__STDC_LIMIT_MACROS)
 298 add_definitions(-Wall -Wextra)
 299 add_definitions(-std=c++11)
 300
 301 if(ENABLE_DECODE)
 302         add_definitions(-DENABLE_DECODE)
 303 endif()
 304
 305 if(NOT DISABLE_WERROR)
 306         add_definitions(-Werror)
 307 endif()
 308
 309 if(ENABLE_SIGNALS)
 310         add_definitions(-DENABLE_SIGNALS)
 311 endif()
 312
 313 #===============================================================================
 314 #= Global Include Directories
 315 #-------------------------------------------------------------------------------
 316
 317 include_directories(
 318         ${CMAKE_CURRENT_BINARY_DIR}
 319         ${CMAKE_CURRENT_SOURCE_DIR}
 320         ${Boost_INCLUDE_DIRS}
 321         ${QT_INCLUDE_DIRS}
 322 )
 323
 324 if(STATIC_PKGDEPS_LIBS)
 325         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 326 else()
 327         include_directories(${PKGDEPS_INCLUDE_DIRS})
 328 endif()
 329
 330 #===============================================================================
 331 #= Linker Configuration
 332 #-------------------------------------------------------------------------------
 333
 334 link_directories(${Boost_LIBRARY_DIRS})
 335
 336 set(PULSEVIEW_LINK_LIBS
 337         ${Boost_LIBRARIES}
 338         ${QT_LIBRARIES}
 339         ${CMAKE_THREAD_LIBS_INIT}
 340 )
 341
 342 if(STATIC_PKGDEPS_LIBS)
 343         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 344         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 345 if(WIN32)
 346         # Workaround for a MinGW linking issue.
 347         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 348 endif()
 349 else()
 350         link_directories(${PKGDEPS_LIBRARY_DIRS})
 351         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 352 endif()
 353
 354 if(WIN32)
 355         # On Windows we need to statically link the libqsvg imageformat
 356         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 357         add_definitions(-DQT_STATICPLUGIN)
 358         link_directories("${QT_PLUGINS_DIR}/imageformats")
 359         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 360         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 361 endif()
 362
 363 if(ANDROID)
 364         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 365 endif()
 366
 367 if(ANDROID)
 368 add_library(${PROJECT_NAME} SHARED
 369         ${pulseview_SOURCES}
 370         ${pulseview_HEADERS_MOC}
 371         ${pulseview_FORMS_HEADERS}
 372         ${pulseview_RESOURCES_RCC}
 373 )
 374 else()
 375 add_executable(${PROJECT_NAME}
 376         ${pulseview_SOURCES}
 377         ${pulseview_HEADERS_MOC}
 378         ${pulseview_FORMS_HEADERS}
 379         ${pulseview_RESOURCES_RCC}
 380 )
 381 endif()
 382
 383 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 384
 385 if(WIN32)
 386         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 387         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 388 endif()
 389
 390 #===============================================================================
 391 #= Installation
 392 #-------------------------------------------------------------------------------
 393
 394 # Install the executable.
 395 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 396
 397 # Install the manpage.
 398 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 399
 400 #===============================================================================
 401 #= Packaging (handled by CPack)
 402 #-------------------------------------------------------------------------------
 403
 404 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 405 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 406 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 407 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 408 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 409 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 410 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 411         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 412 set(CPACK_SOURCE_GENERATOR "TGZ")
 413
 414 include(CPack)
 415
 416 #===============================================================================
 417 #= Tests
 418 #-------------------------------------------------------------------------------
 419
 420 if(ENABLE_TESTS)
 421         add_subdirectory(test)
 422         enable_testing()
 423         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 424 endif()