CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27 include(cotire)
  28
  29 project(pulseview)
  30
  31 #===============================================================================
  32 #= User Options
  33 #-------------------------------------------------------------------------------
  34
  35 option(DISABLE_WERROR "Build without -Werror" FALSE)
  36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  39
  40 if(WIN32)
  41         # On Windows/MinGW we need to statically link to libraries.
  42         # This option is user configurable, but enable it by default on win32.
  43         set(STATIC_PKGDEPS_LIBS TRUE)
  44
  45         # For boost-thread we need two additional settings on win32:
  46         set(Boost_USE_STATIC_LIBS on)
  47         add_definitions(-DBOOST_THREAD_USE_LIB)
  48
  49         # Windsws does not support UNIX signals
  50         set(ENABLE_SIGNALS FALSE)
  51 endif()
  52
  53 #===============================================================================
  54 #= Dependencies
  55 #-------------------------------------------------------------------------------
  56
  57 list(APPEND PKGDEPS
  58         libsigrok>=0.2.0
  59         libsigrokdecode>=0.2.0
  60 )
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  66 find_package(Qt4 REQUIRED)
  67
  68 # Find the platform's thread library (needed for boost-thread).
  69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  70 find_package(Threads)
  71
  72 if(WIN32)
  73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  74 # The library is named libboost_thread_win32* (not libboost_thread*).
  75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  76 else()
  77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  78 endif()
  79
  80 #===============================================================================
  81 #= Config Header
  82 #-------------------------------------------------------------------------------
  83
  84 set(PV_TITLE PulseView)
  85 set(PV_DESCRIPTION "A GUI for sigrok")
  86
  87 set(PV_VERSION_MAJOR 0)
  88 set(PV_VERSION_MINOR 1)
  89 set(PV_VERSION_MICRO 0)
  90 set(PV_VERSION_STRING
  91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  92 )
  93
  94 configure_file (
  95         ${PROJECT_SOURCE_DIR}/config.h.in
  96         ${PROJECT_BINARY_DIR}/config.h
  97 )
  98
  99 #===============================================================================
 100 #= Sources
 101 #-------------------------------------------------------------------------------
 102
 103 set(pulseview_SOURCES
 104         main.cpp
 105         pv/devicemanager.cpp
 106         pv/mainwindow.cpp
 107         pv/sigsession.cpp
 108         pv/data/analog.cpp
 109         pv/data/analogsnapshot.cpp
 110         pv/data/decoder.cpp
 111         pv/data/logic.cpp
 112         pv/data/logicsnapshot.cpp
 113         pv/data/signaldata.cpp
 114         pv/data/snapshot.cpp
 115         pv/dialogs/about.cpp
 116         pv/dialogs/connect.cpp
 117         pv/dialogs/decoder.cpp
 118         pv/popups/deviceoptions.cpp
 119         pv/popups/probes.cpp
 120         pv/prop/bool.cpp
 121         pv/prop/double.cpp
 122         pv/prop/enum.cpp
 123         pv/prop/int.cpp
 124         pv/prop/property.cpp
 125         pv/prop/string.cpp
 126         pv/prop/binding/binding.cpp
 127         pv/prop/binding/decoderoptions.cpp
 128         pv/prop/binding/deviceoptions.cpp
 129         pv/toolbars/samplingbar.cpp
 130         pv/view/analogsignal.cpp
 131         pv/view/cursor.cpp
 132         pv/view/cursorpair.cpp
 133         pv/view/decodesignal.cpp
 134         pv/view/header.cpp
 135         pv/view/marginwidget.cpp
 136         pv/view/logicsignal.cpp
 137         pv/view/ruler.cpp
 138         pv/view/selectableitem.cpp
 139         pv/view/signal.cpp
 140         pv/view/timemarker.cpp
 141         pv/view/trace.cpp
 142         pv/view/tracepalette.cpp
 143         pv/view/view.cpp
 144         pv/view/viewport.cpp
 145         pv/view/decode/annotation.cpp
 146         pv/widgets/colourbutton.cpp
 147         pv/widgets/colourpopup.cpp
 148         pv/widgets/popup.cpp
 149         pv/widgets/popuptoolbutton.cpp
 150         pv/widgets/wellarray.cpp
 151 )
 152
 153 # This list includes only QObject derrived class headers
 154 set(pulseview_HEADERS
 155         pv/mainwindow.h
 156         pv/sigsession.h
 157         pv/data/decoder.h
 158         pv/dialogs/about.h
 159         pv/dialogs/connect.h
 160         pv/popups/deviceoptions.h
 161         pv/popups/probes.h
 162         pv/prop/bool.h
 163         pv/prop/double.h
 164         pv/prop/enum.h
 165         pv/prop/int.h
 166         pv/prop/property.h
 167         pv/prop/string.h
 168         pv/toolbars/samplingbar.h
 169         pv/view/cursor.h
 170         pv/view/decodesignal.h
 171         pv/view/header.h
 172         pv/view/logicsignal.h
 173         pv/view/marginwidget.h
 174         pv/view/ruler.h
 175         pv/view/selectableitem.h
 176         pv/view/signal.h
 177         pv/view/timemarker.h
 178         pv/view/trace.h
 179         pv/view/view.h
 180         pv/view/viewport.h
 181         pv/widgets/colourbutton.h
 182         pv/widgets/colourpopup.h
 183         pv/widgets/popuptoolbutton.h
 184         pv/widgets/wellarray.h
 185 )
 186
 187 set(pulseview_FORMS
 188         pv/dialogs/about.ui
 189 )
 190
 191 set(pulseview_RESOURCES
 192         pulseview.qrc
 193 )
 194
 195 if(ENABLE_SIGNALS)
 196         list(APPEND pulseview_SOURCES signalhandler.cpp)
 197         list(APPEND pulseview_HEADERS signalhandler.h)
 198 endif()
 199
 200 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 201 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 202 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 203
 204 include(${QT_USE_FILE})
 205
 206 #===============================================================================
 207 #= Global Definitions
 208 #-------------------------------------------------------------------------------
 209
 210 add_definitions(${QT_DEFINITIONS})
 211 add_definitions(-Wall -Wextra)
 212
 213 if(NOT DISABLE_WERROR)
 214         add_definitions(-Werror)
 215 endif()
 216
 217 #===============================================================================
 218 #= Global Include Directories
 219 #-------------------------------------------------------------------------------
 220
 221 include_directories(
 222         ${CMAKE_CURRENT_BINARY_DIR}
 223         ${CMAKE_CURRENT_SOURCE_DIR}
 224         ${Boost_INCLUDE_DIRS}
 225 )
 226
 227 if(STATIC_PKGDEPS_LIBS)
 228         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 229 else()
 230         include_directories(${PKGDEPS_INCLUDE_DIRS})
 231 endif()
 232
 233 #===============================================================================
 234 #= Linker Configuration
 235 #-------------------------------------------------------------------------------
 236
 237 link_directories(${Boost_LIBRARY_DIRS})
 238
 239 set(PULSEVIEW_LINK_LIBS
 240         ${Boost_LIBRARIES}
 241         ${CMAKE_THREAD_LIBS_INIT}
 242         ${QT_LIBRARIES}
 243 )
 244
 245 if(STATIC_PKGDEPS_LIBS)
 246         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 247         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 248 else()
 249         link_directories(${PKGDEPS_LIBRARY_DIRS})
 250         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 251 endif()
 252
 253 add_executable(${PROJECT_NAME}
 254         ${pulseview_SOURCES}
 255         ${pulseview_HEADERS_MOC}
 256         ${pulseview_FORMS_HEADERS}
 257         ${pulseview_RESOURCES_RCC}
 258 )
 259
 260 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 261 cotire(${PROJECT_NAME})
 262
 263 if(WIN32)
 264 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 265 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 266 endif()
 267
 268 #===============================================================================
 269 #= Installation
 270 #-------------------------------------------------------------------------------
 271
 272 # Install the executable.
 273 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 274
 275 # Install the manpage.
 276 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 277
 278 #===============================================================================
 279 #= Packaging (handled by CPack)
 280 #-------------------------------------------------------------------------------
 281
 282 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 283 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 284 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 285 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 286 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 287 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 288 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 289         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 290 set(CPACK_SOURCE_GENERATOR "TGZ")
 291
 292 include(CPack)
 293
 294 #===============================================================================
 295 #= Tests
 296 #-------------------------------------------------------------------------------
 297
 298 if(ENABLE_TESTS)
 299         add_subdirectory(test)
 300         enable_testing()
 301         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 302 endif(ENABLE_TESTS)