CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" FALSE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 #===============================================================================
  55 #= Dependencies
  56 #-------------------------------------------------------------------------------
  57
  58 list(APPEND PKGDEPS libsigrok>=0.2.0)
  59
  60 if(ENABLE_DECODE)
  61         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  62 endif()
  63
  64 find_package(PkgConfig)
  65 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  66
  67 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  68 find_package(Qt4 REQUIRED)
  69
  70 # Find the platform's thread library (needed for boost-thread).
  71 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  72 find_package(Threads)
  73
  74 if(WIN32)
  75         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  76         # The library is named libboost_thread_win32* (not libboost_thread*).
  77         find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  78 else()
  79         find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  80 endif()
  81
  82 #===============================================================================
  83 #= Config Header
  84 #-------------------------------------------------------------------------------
  85
  86 set(PV_TITLE PulseView)
  87 set(PV_DESCRIPTION "A GUI for sigrok")
  88
  89 set(PV_VERSION_MAJOR 0)
  90 set(PV_VERSION_MINOR 1)
  91 set(PV_VERSION_MICRO 0)
  92 set(PV_VERSION_STRING
  93         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  94 )
  95
  96 configure_file (
  97         ${PROJECT_SOURCE_DIR}/config.h.in
  98         ${PROJECT_BINARY_DIR}/config.h
  99 )
 100
 101 #===============================================================================
 102 #= Sources
 103 #-------------------------------------------------------------------------------
 104
 105 set(pulseview_SOURCES
 106         main.cpp
 107         pv/devicemanager.cpp
 108         pv/mainwindow.cpp
 109         pv/sigsession.cpp
 110         pv/storesession.cpp
 111         pv/data/analog.cpp
 112         pv/data/analogsnapshot.cpp
 113         pv/data/logic.cpp
 114         pv/data/logicsnapshot.cpp
 115         pv/data/signaldata.cpp
 116         pv/data/snapshot.cpp
 117         pv/dialogs/about.cpp
 118         pv/dialogs/connect.cpp
 119         pv/dialogs/storeprogress.cpp
 120         pv/popups/deviceoptions.cpp
 121         pv/popups/probes.cpp
 122         pv/prop/bool.cpp
 123         pv/prop/double.cpp
 124         pv/prop/enum.cpp
 125         pv/prop/int.cpp
 126         pv/prop/property.cpp
 127         pv/prop/string.cpp
 128         pv/prop/binding/binding.cpp
 129         pv/prop/binding/deviceoptions.cpp
 130         pv/toolbars/samplingbar.cpp
 131         pv/view/analogsignal.cpp
 132         pv/view/cursor.cpp
 133         pv/view/cursorpair.cpp
 134         pv/view/header.cpp
 135         pv/view/marginwidget.cpp
 136         pv/view/logicsignal.cpp
 137         pv/view/ruler.cpp
 138         pv/view/selectableitem.cpp
 139         pv/view/signal.cpp
 140         pv/view/timemarker.cpp
 141         pv/view/trace.cpp
 142         pv/view/tracepalette.cpp
 143         pv/view/view.cpp
 144         pv/view/viewport.cpp
 145         pv/widgets/colourbutton.cpp
 146         pv/widgets/colourpopup.cpp
 147         pv/widgets/popup.cpp
 148         pv/widgets/popuptoolbutton.cpp
 149         pv/widgets/sweeptimingwidget.cpp
 150         pv/widgets/wellarray.cpp
 151 )
 152
 153 # This list includes only QObject derived class headers.
 154 set(pulseview_HEADERS
 155         pv/mainwindow.h
 156         pv/sigsession.h
 157         pv/storesession.h
 158         pv/dialogs/about.h
 159         pv/dialogs/connect.h
 160         pv/dialogs/storeprogress.h
 161         pv/popups/probes.h
 162         pv/popups/deviceoptions.h
 163         pv/prop/bool.h
 164         pv/prop/double.h
 165         pv/prop/enum.h
 166         pv/prop/int.h
 167         pv/prop/property.h
 168         pv/prop/string.h
 169         pv/toolbars/samplingbar.h
 170         pv/view/cursor.h
 171         pv/view/header.h
 172         pv/view/logicsignal.h
 173         pv/view/marginwidget.h
 174         pv/view/ruler.h
 175         pv/view/selectableitem.h
 176         pv/view/signal.h
 177         pv/view/timemarker.h
 178         pv/view/trace.h
 179         pv/view/view.h
 180         pv/view/viewport.h
 181         pv/widgets/colourbutton.h
 182         pv/widgets/colourpopup.h
 183         pv/widgets/popup.h
 184         pv/widgets/popuptoolbutton.h
 185         pv/widgets/sweeptimingwidget.h
 186         pv/widgets/wellarray.h
 187 )
 188
 189 set(pulseview_FORMS
 190         pv/dialogs/about.ui
 191 )
 192
 193 set(pulseview_RESOURCES
 194         pulseview.qrc
 195 )
 196
 197 if(ENABLE_SIGNALS)
 198         list(APPEND pulseview_SOURCES signalhandler.cpp)
 199         list(APPEND pulseview_HEADERS signalhandler.h)
 200 endif()
 201
 202 if(ENABLE_DECODE)
 203         list(APPEND pulseview_SOURCES
 204                 pv/data/decoderstack.cpp
 205                 pv/data/decode/annotation.cpp
 206                 pv/data/decode/decoder.cpp
 207                 pv/prop/binding/decoderoptions.cpp
 208                 pv/view/decodetrace.cpp
 209                 pv/widgets/decodergroupbox.cpp
 210                 pv/widgets/decodermenu.cpp
 211         )
 212
 213         list(APPEND pulseview_HEADERS
 214                 pv/data/decoderstack.h
 215                 pv/view/decodetrace.h
 216                 pv/widgets/decodergroupbox.h
 217                 pv/widgets/decodermenu.h
 218         )
 219 endif()
 220
 221 if(WIN32)
 222         # Use the sigrok icon for the pulseview.exe executable.
 223         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 224         enable_language(RC)
 225         list(APPEND pulseview_SOURCES pulseviewico.rc)
 226 endif()
 227
 228 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 229 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 230 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 231
 232 include(${QT_USE_FILE})
 233
 234 #===============================================================================
 235 #= Global Definitions
 236 #-------------------------------------------------------------------------------
 237
 238 add_definitions(${QT_DEFINITIONS})
 239 add_definitions(-D__STDC_LIMIT_MACROS)
 240 add_definitions(-Wall -Wextra)
 241
 242 if(ENABLE_DECODE)
 243         add_definitions(-DENABLE_DECODE)
 244 endif()
 245
 246 if(NOT DISABLE_WERROR)
 247         add_definitions(-Werror)
 248 endif()
 249
 250 #===============================================================================
 251 #= Global Include Directories
 252 #-------------------------------------------------------------------------------
 253
 254 include_directories(
 255         ${CMAKE_CURRENT_BINARY_DIR}
 256         ${CMAKE_CURRENT_SOURCE_DIR}
 257         ${Boost_INCLUDE_DIRS}
 258 )
 259
 260 if(STATIC_PKGDEPS_LIBS)
 261         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 262 else()
 263         include_directories(${PKGDEPS_INCLUDE_DIRS})
 264 endif()
 265
 266 #===============================================================================
 267 #= Linker Configuration
 268 #-------------------------------------------------------------------------------
 269
 270 link_directories(${Boost_LIBRARY_DIRS})
 271
 272 set(PULSEVIEW_LINK_LIBS
 273         ${Boost_LIBRARIES}
 274         ${CMAKE_THREAD_LIBS_INIT}
 275         ${QT_LIBRARIES}
 276 )
 277
 278 if(STATIC_PKGDEPS_LIBS)
 279         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 280         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 281 else()
 282         link_directories(${PKGDEPS_LIBRARY_DIRS})
 283         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 284 endif()
 285
 286 if(WIN32)
 287         # On Windows we need to statically link the libqsvg imageformat
 288         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 289         add_definitions(-DQT_STATICPLUGIN)
 290         link_directories("${QT_PLUGINS_DIR}/imageformats")
 291         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 292         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 293 endif()
 294
 295 add_executable(${PROJECT_NAME}
 296         ${pulseview_SOURCES}
 297         ${pulseview_HEADERS_MOC}
 298         ${pulseview_FORMS_HEADERS}
 299         ${pulseview_RESOURCES_RCC}
 300 )
 301
 302 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 303
 304 if(WIN32)
 305         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 306         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 307 endif()
 308
 309 if(ENABLE_COTIRE)
 310         include(cotire)
 311         cotire(${PROJECT_NAME})
 312 endif()
 313
 314 #===============================================================================
 315 #= Installation
 316 #-------------------------------------------------------------------------------
 317
 318 # Install the executable.
 319 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 320
 321 # Install the manpage.
 322 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 323
 324 #===============================================================================
 325 #= Packaging (handled by CPack)
 326 #-------------------------------------------------------------------------------
 327
 328 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 329 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 330 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 331 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 332 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 333 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 334 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 335         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 336 set(CPACK_SOURCE_GENERATOR "TGZ")
 337
 338 include(CPack)
 339
 340 #===============================================================================
 341 #= Tests
 342 #-------------------------------------------------------------------------------
 343
 344 if(ENABLE_TESTS)
 345         add_subdirectory(test)
 346         enable_testing()
 347         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 348 endif()