Rename colour* to color*
[pulseview.git] / CMakeLists.txt
1 ##
2 ## This file is part of the PulseView project.
3 ##
4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
6 ##
7 ## This program is free software: you can redistribute it and/or modify
8 ## it under the terms of the GNU General Public License as published by
9 ## the Free Software Foundation, either version 2 of the License, or
10 ## (at your option) any later version.
11 ##
12 ## This program is distributed in the hope that it will be useful,
13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 ## GNU General Public License for more details.
16 ##
17 ## You should have received a copy of the GNU General Public License
18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
19 ##
20
21 cmake_minimum_required(VERSION 2.8.12)
22
23 include(GNUInstallDirs)
24
25 project(pulseview)
26
27 # Let AUTOMOC and AUTOUIC process GENERATED files.
28 if(POLICY CMP0071)
29         cmake_policy(SET CMP0071 NEW)
30 endif()
31
32 # Only interpret if() arguments as variables or keywords when unquoted.
33 if(POLICY CMP0054)
34         cmake_policy(SET CMP0054 NEW)
35 endif()
36
37 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
38
39 #===============================================================================
40 #= User Options
41 #-------------------------------------------------------------------------------
42
43 option(DISABLE_WERROR "Build without -Werror" FALSE)
44 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
45 option(ENABLE_STACKTRACE "Enable stack trace when crashing" FALSE)
46 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
47 option(ENABLE_TESTS "Enable unit tests" TRUE)
48 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
49
50 if(WIN32)
51         # On Windows/MinGW we need to statically link to libraries.
52         # This option is user configurable, but enable it by default on win32.
53         set(STATIC_PKGDEPS_LIBS TRUE)
54
55         # Windows does not support UNIX signals.
56         set(ENABLE_SIGNALS FALSE)
57 endif()
58
59 if(NOT CMAKE_BUILD_TYPE)
60         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
61         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
62         FORCE)
63 endif()
64
65 #===============================================================================
66 #= Dependencies
67 #-------------------------------------------------------------------------------
68
69 list(APPEND PKGDEPS glib-2.0>=2.28.0)
70 list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
71
72 list(APPEND PKGDEPS libsigrokcxx>=0.6.0)
73
74 if(ENABLE_DECODE)
75         list(APPEND PKGDEPS libsigrokdecode>=0.6.0)
76 endif()
77
78 if(ANDROID)
79         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
80 endif()
81
82 find_package(PkgConfig)
83 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
84
85 set(CMAKE_AUTOMOC TRUE)
86
87 find_package(Qt5 COMPONENTS Core Gui Widgets Svg REQUIRED)
88
89 if(WIN32)
90         # MXE workaround: Use pkg-config to find Qt5 libs.
91         # https://github.com/mxe/mxe/issues/1642
92         # Not required (and doesn't work) on MSYS2.
93         if(NOT DEFINED ENV{MSYSTEM})
94                 pkg_check_modules(QT5ALL REQUIRED Qt5Widgets Qt5Gui Qt5Svg)
95         endif()
96 endif()
97
98 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
99
100 set(BOOSTCOMPS filesystem serialization system)
101 if(ENABLE_TESTS)
102         list(APPEND BOOSTCOMPS unit_test_framework)
103 endif()
104
105 if(ENABLE_STACKTRACE)
106         find_package(Boost 1.65.1 COMPONENTS ${BOOSTCOMPS} REQUIRED)
107 else()
108         find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
109 endif()
110
111 # Find the platform's thread library (needed for C++11 threads).
112 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
113 find_package(Threads REQUIRED)
114
115 # Check for explicit link against libatomic
116 #
117 # Depending on the toolchain, linking a program using atomic functions may need
118 # "-latomic" explicitly passed to the linker
119 #
120 # This check first tests if atomics are available in the C-library, if not and
121 # libatomic exists, then it runs the same test with -latomic added to the
122 # linker flags.
123
124 # Helper for checking for atomics
125 function(check_working_cxx_atomics varname additional_lib)
126   include(CheckCXXSourceCompiles)
127   include(CMakePushCheckState)
128   cmake_push_check_state()
129   set(CMAKE_REQUIRED_FLAGS "-std=c++11")
130   set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
131   set(CMAKE_REQUIRED_QUIET 1)
132   CHECK_CXX_SOURCE_COMPILES("
133 #include <atomic>
134 std::atomic<int> x;
135 int main() {
136   return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
137 }
138 " ${varname})
139   cmake_pop_check_state()
140 endfunction(check_working_cxx_atomics)
141
142 # First check if atomics work without the library.
143 # If not, check if the library exists, and atomics work with it.
144 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
145 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
146   message(STATUS "Atomics provided by the C-library - yes")
147 else()
148   message(STATUS "Atomics provided by the C-library - no")
149   find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
150   if(LIBATOMIC_LIBRARY)
151     check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
152     if (HAVE_CXX_ATOMICS_WITH_LIB)
153       message(STATUS "Atomics provided by libatomic - yes")
154     else()
155       message(STATUS "Atomics provided by libatomic - no")
156       message(FATAL_ERROR "Compiler must support std::atomic!")
157     endif()
158   else()
159     message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
160   endif()
161 endif()
162
163 #===============================================================================
164 #= System Introspection
165 #-------------------------------------------------------------------------------
166
167 include(memaccess)
168 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
169
170 #===============================================================================
171 #= Config Header
172 #-------------------------------------------------------------------------------
173
174 set(PV_TITLE PulseView)
175 set(PV_VERSION_STRING "0.5.0")
176
177 set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
178
179 include(GetGitRevisionDescription)
180
181 # Append the revision hash unless we are exactly on a tagged release.
182 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
183 if(NOT PV_TAG_VERSION_STRING)
184         get_git_head_revision(PV_REVSPEC PV_HASH)
185         if(PV_HASH)
186                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
187                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
188         endif()
189 endif()
190
191 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
192         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
193         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
194         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
195         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
196 endif()
197
198 message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
199
200 configure_file (
201         ${PROJECT_SOURCE_DIR}/config.h.in
202         ${PROJECT_BINARY_DIR}/config.h
203 )
204
205 #===============================================================================
206 #= Sources
207 #-------------------------------------------------------------------------------
208
209 set(pulseview_SOURCES
210         main.cpp
211         pv/application.cpp
212         pv/devicemanager.cpp
213         pv/globalsettings.cpp
214         pv/logging.cpp
215         pv/mainwindow.cpp
216         pv/session.cpp
217         pv/storesession.cpp
218         pv/util.cpp
219         pv/binding/binding.cpp
220         pv/binding/inputoutput.cpp
221         pv/binding/device.cpp
222         pv/data/analog.cpp
223         pv/data/analogsegment.cpp
224         pv/data/logic.cpp
225         pv/data/logicsegment.cpp
226         pv/data/signalbase.cpp
227         pv/data/signaldata.cpp
228         pv/data/segment.cpp
229         pv/devices/device.cpp
230         pv/devices/file.cpp
231         pv/devices/hardwaredevice.cpp
232         pv/devices/inputfile.cpp
233         pv/devices/sessionfile.cpp
234         pv/dialogs/connect.cpp
235         pv/dialogs/inputoutputoptions.cpp
236         pv/dialogs/settings.cpp
237         pv/dialogs/storeprogress.cpp
238         pv/popups/deviceoptions.cpp
239         pv/popups/channels.cpp
240         pv/prop/bool.cpp
241         pv/prop/double.cpp
242         pv/prop/enum.cpp
243         pv/prop/int.cpp
244         pv/prop/property.cpp
245         pv/prop/string.cpp
246         pv/toolbars/mainbar.cpp
247         pv/views/trace/analogsignal.cpp
248         pv/views/trace/cursor.cpp
249         pv/views/trace/cursorpair.cpp
250         pv/views/trace/flag.cpp
251         pv/views/trace/header.cpp
252         pv/views/trace/marginwidget.cpp
253         pv/views/trace/logicsignal.cpp
254         pv/views/trace/rowitem.cpp
255         pv/views/trace/ruler.cpp
256         pv/views/trace/signal.cpp
257         pv/views/trace/timeitem.cpp
258         pv/views/trace/timemarker.cpp
259         pv/views/trace/trace.cpp
260         pv/views/trace/tracegroup.cpp
261         pv/views/trace/tracepalette.cpp
262         pv/views/trace/tracetreeitem.cpp
263         pv/views/trace/tracetreeitemowner.cpp
264         pv/views/trace/triggermarker.cpp
265         pv/views/trace/view.cpp
266         pv/views/trace/viewitem.cpp
267         pv/views/trace/viewitemowner.cpp
268         pv/views/trace/viewitempaintparams.cpp
269         pv/views/trace/viewport.cpp
270         pv/views/trace/viewwidget.cpp
271         pv/views/viewbase.cpp
272         pv/views/trace/standardbar.cpp
273         pv/widgets/colorbutton.cpp
274         pv/widgets/colorpopup.cpp
275         pv/widgets/devicetoolbutton.cpp
276         pv/widgets/exportmenu.cpp
277         pv/widgets/importmenu.cpp
278         pv/widgets/popup.cpp
279         pv/widgets/popuptoolbutton.cpp
280         pv/widgets/sweeptimingwidget.cpp
281         pv/widgets/timestampspinbox.cpp
282         pv/widgets/wellarray.cpp
283 )
284
285 # This list includes only QObject derived class headers.
286 set(pulseview_HEADERS
287         pv/logging.hpp
288         pv/globalsettings.hpp
289         pv/mainwindow.hpp
290         pv/session.hpp
291     &nb