CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.4.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.4.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 3)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_SUFFIX -git)
 129 set(PV_VERSION_STRING
 130         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}${PV_VERSION_SUFFIX}
 131 )
 132
 133 configure_file (
 134         ${PROJECT_SOURCE_DIR}/config.h.in
 135         ${PROJECT_BINARY_DIR}/config.h
 136 )
 137
 138 #===============================================================================
 139 #= Sources
 140 #-------------------------------------------------------------------------------
 141
 142 set(pulseview_SOURCES
 143         main.cpp
 144         pv/application.cpp
 145         pv/devicemanager.cpp
 146         pv/mainwindow.cpp
 147         pv/session.cpp
 148         pv/storesession.cpp
 149         pv/util.cpp
 150         pv/binding/binding.cpp
 151         pv/binding/inputoutput.cpp
 152         pv/binding/device.cpp
 153         pv/data/analog.cpp
 154         pv/data/analogsegment.cpp
 155         pv/data/logic.cpp
 156         pv/data/logicsegment.cpp
 157         pv/data/signaldata.cpp
 158         pv/data/segment.cpp
 159         pv/devices/device.cpp
 160         pv/devices/file.cpp
 161         pv/devices/hardwaredevice.cpp
 162         pv/devices/inputfile.cpp
 163         pv/devices/sessionfile.cpp
 164         pv/dialogs/about.cpp
 165         pv/dialogs/connect.cpp
 166         pv/dialogs/inputoutputoptions.cpp
 167         pv/dialogs/storeprogress.cpp
 168         pv/popups/deviceoptions.cpp
 169         pv/popups/channels.cpp
 170         pv/prop/bool.cpp
 171         pv/prop/double.cpp
 172         pv/prop/enum.cpp
 173         pv/prop/int.cpp
 174         pv/prop/property.cpp
 175         pv/prop/string.cpp
 176         pv/toolbars/mainbar.cpp
 177         pv/view/analogsignal.cpp
 178         pv/view/cursor.cpp
 179         pv/view/cursorpair.cpp
 180         pv/view/flag.cpp
 181         pv/view/header.cpp
 182         pv/view/marginwidget.cpp
 183         pv/view/logicsignal.cpp
 184         pv/view/rowitem.cpp
 185         pv/view/rowitemowner.cpp
 186         pv/view/ruler.cpp
 187         pv/view/signal.cpp
 188         pv/view/timeitem.cpp
 189         pv/view/timemarker.cpp
 190         pv/view/trace.cpp
 191         pv/view/tracegroup.cpp
 192         pv/view/tracepalette.cpp
 193         pv/view/view.cpp
 194         pv/view/viewitem.cpp
 195         pv/view/viewitempaintparams.cpp
 196         pv/view/viewport.cpp
 197         pv/view/viewwidget.cpp
 198         pv/widgets/colourbutton.cpp
 199         pv/widgets/colourpopup.cpp
 200         pv/widgets/devicetoolbutton.cpp
 201         pv/widgets/exportmenu.cpp
 202         pv/widgets/hidingmenubar.cpp
 203         pv/widgets/importmenu.cpp
 204         pv/widgets/popup.cpp
 205         pv/widgets/popuptoolbutton.cpp
 206         pv/widgets/sweeptimingwidget.cpp
 207         pv/widgets/wellarray.cpp
 208 )
 209
 210 # This list includes only QObject derived class headers.
 211 set(pulseview_HEADERS
 212         pv/mainwindow.hpp
 213         pv/session.hpp
 214         pv/storesession.hpp
 215         pv/binding/device.hpp
 216         pv/dialogs/about.hpp
 217         pv/dialogs/connect.hpp
 218         pv/dialogs/inputoutputoptions.hpp
 219         pv/dialogs/storeprogress.hpp
 220         pv/popups/channels.hpp
 221         pv/popups/deviceoptions.hpp
 222         pv/prop/bool.hpp
 223         pv/prop/double.hpp
 224         pv/prop/enum.hpp
 225         pv/prop/int.hpp
 226         pv/prop/property.hpp
 227         pv/prop/string.hpp
 228         pv/toolbars/mainbar.hpp
 229         pv/view/cursor.hpp
 230         pv/view/flag.hpp
 231         pv/view/header.hpp
 232         pv/view/logicsignal.hpp
 233         pv/view/marginwidget.hpp
 234         pv/view/rowitem.hpp
 235         pv/view/ruler.hpp
 236         pv/view/signal.hpp
 237         pv/view/timeitem.hpp
 238         pv/view/timemarker.hpp
 239         pv/view/trace.hpp
 240         pv/view/tracegroup.hpp
 241         pv/view/view.hpp
 242         pv/view/viewitem.hpp
 243         pv/view/viewport.hpp
 244         pv/view/viewwidget.hpp
 245         pv/widgets/colourbutton.hpp
 246         pv/widgets/colourpopup.hpp
 247         pv/widgets/devicetoolbutton.hpp
 248         pv/widgets/exportmenu.hpp
 249         pv/widgets/hidingmenubar.hpp
 250         pv/widgets/importmenu.hpp
 251         pv/widgets/popup.hpp
 252         pv/widgets/popuptoolbutton.hpp
 253         pv/widgets/sweeptimingwidget.hpp
 254         pv/widgets/wellarray.hpp
 255 )
 256
 257 set(pulseview_FORMS
 258         pv/dialogs/about.ui
 259 )
 260
 261 set(pulseview_RESOURCES
 262         pulseview.qrc
 263 )
 264
 265 if(ENABLE_SIGNALS)
 266         list(APPEND pulseview_SOURCES signalhandler.cpp)
 267         list(APPEND pulseview_HEADERS signalhandler.hpp)
 268 endif()
 269
 270 if(ENABLE_DECODE)
 271         list(APPEND pulseview_SOURCES
 272                 pv/binding/decoder.cpp
 273                 pv/data/decoderstack.cpp
 274                 pv/data/decode/annotation.cpp
 275                 pv/data/decode/decoder.cpp
 276                 pv/data/decode/row.cpp
 277                 pv/data/decode/rowdata.cpp
 278                 pv/view/decodetrace.cpp
 279                 pv/widgets/decodergroupbox.cpp
 280                 pv/widgets/decodermenu.cpp
 281         )
 282
 283         list(APPEND pulseview_HEADERS
 284                 pv/data/decoderstack.hpp
 285                 pv/view/decodetrace.hpp
 286                 pv/widgets/decodergroupbox.hpp
 287                 pv/widgets/decodermenu.hpp
 288         )
 289 endif()
 290
 291 if(WIN32)
 292         # Use the sigrok icon for the pulseview.exe executable.
 293         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 294         enable_language(RC)
 295         list(APPEND pulseview_SOURCES pulseviewico.rc)
 296 endif()
 297
 298 if(ANDROID)
 299         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 300 endif()
 301
 302 if(Qt5Core_FOUND)
 303         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 304         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 305         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 306 else()
 307         # Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
 308         # https://bugreports.qt.io/browse/QTBUG-22829
 309         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
 310                 OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
 311         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 312         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 313         include(${QT_USE_FILE})
 314 endif()
 315
 316 #===============================================================================
 317 #= Global Definitions
 318 #-------------------------------------------------------------------------------
 319
 320 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 321 add_definitions(-D__STDC_LIMIT_MACROS)
 322 add_definitions(-Wall -Wextra)
 323 add_definitions(-std=c++11)
 324
 325 if(ENABLE_DECODE)
 326         add_definitions(-DENABLE_DECODE)
 327 endif()
 328
 329 if(NOT DISABLE_WERROR)
 330         add_definitions(-Werror)
 331 endif()
 332
 333 if(ENABLE_SIGNALS)
 334         add_definitions(-DENABLE_SIGNALS)
 335 endif()
 336
 337 #===============================================================================
 338 #= Global Include Directories
 339 #-------------------------------------------------------------------------------
 340
 341 include_directories(
 342         ${CMAKE_CURRENT_BINARY_DIR}
 343         ${CMAKE_CURRENT_SOURCE_DIR}
 344         ${Boost_INCLUDE_DIRS}
 345         ${QT_INCLUDE_DIRS}
 346 )
 347
 348 if(STATIC_PKGDEPS_LIBS)
 349         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 350 else()
 351         include_directories(${PKGDEPS_INCLUDE_DIRS})
 352 endif()
 353
 354 #===============================================================================
 355 #= Linker Configuration
 356 #-------------------------------------------------------------------------------
 357
 358 link_directories(${Boost_LIBRARY_DIRS})
 359
 360 set(PULSEVIEW_LINK_LIBS
 361         ${Boost_LIBRARIES}
 362         ${QT_LIBRARIES}
 363         ${CMAKE_THREAD_LIBS_INIT}
 364 )
 365
 366 if(STATIC_PKGDEPS_LIBS)
 367         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 368         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 369 if(WIN32)
 370         # Workaround for a MinGW linking issue.
 371         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 372 endif()
 373 else()
 374         link_directories(${PKGDEPS_LIBRARY_DIRS})
 375         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 376 endif()
 377
 378 if(WIN32)
 379         # On Windows we need to statically link the libqsvg imageformat
 380         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 381         add_definitions(-DQT_STATICPLUGIN)
 382         link_directories("${QT_PLUGINS_DIR}/imageformats")
 383         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 384         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 385 endif()
 386
 387 if(ANDROID)
 388         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 389 endif()
 390
 391 if(ANDROID)
 392 add_library(${PROJECT_NAME} SHARED
 393         ${pulseview_SOURCES}
 394         ${pulseview_HEADERS_MOC}
 395         ${pulseview_FORMS_HEADERS}
 396         ${pulseview_RESOURCES_RCC}
 397 )
 398 else()
 399 add_executable(${PROJECT_NAME}
 400         ${pulseview_SOURCES}
 401         ${pulseview_HEADERS_MOC}
 402         ${pulseview_FORMS_HEADERS}
 403         ${pulseview_RESOURCES_RCC}
 404 )
 405 endif()
 406
 407 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 408
 409 if(WIN32)
 410         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 411         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 412 endif()
 413
 414 #===============================================================================
 415 #= Installation
 416 #-------------------------------------------------------------------------------
 417
 418 # Install the executable.
 419 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 420
 421 # Install the manpage.
 422 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 423
 424 #===============================================================================
 425 #= Packaging (handled by CPack)
 426 #-------------------------------------------------------------------------------
 427
 428 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 429 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 430 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 431 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 432 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 433 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 434 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 435         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}${PV_VERSION_SUFFIX}")
 436 set(CPACK_SOURCE_GENERATOR "TGZ")
 437
 438 include(CPack)
 439
 440 #===============================================================================
 441 #= Tests
 442 #-------------------------------------------------------------------------------
 443
 444 if(ENABLE_TESTS)
 445         add_subdirectory(test)
 446         enable_testing()
 447         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 448 endif()