CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  41
  42 if(WIN32)
  43         # On Windows/MinGW we need to statically link to libraries.
  44         # This option is user configurable, but enable it by default on win32.
  45         set(STATIC_PKGDEPS_LIBS TRUE)
  46
  47         # Windows does not support UNIX signals.
  48         set(ENABLE_SIGNALS FALSE)
  49 endif()
  50
  51 if(NOT CMAKE_BUILD_TYPE)
  52   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  53       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  54       FORCE)
  55 endif()
  56
  57 #===============================================================================
  58 #= Dependencies
  59 #-------------------------------------------------------------------------------
  60
  61 list(APPEND PKGDEPS libsigrokxx>=0.3.0)
  62
  63 if(ENABLE_DECODE)
  64         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  65 endif()
  66
  67 if(ANDROID)
  68         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  69 endif()
  70
  71 find_package(PkgConfig)
  72 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  73
  74 if(FORCE_QT4)
  75         set(Qt5Core_FOUND FALSE)
  76 else()
  77         find_package(Qt5Core QUIET)
  78 endif()
  79
  80 if(Qt5Core_FOUND)
  81         message("-- Using Qt5")
  82         find_package(Qt5Widgets REQUIRED)
  83         find_package(Qt5Gui REQUIRED)
  84         find_package(Qt5Svg REQUIRED)
  85         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  86         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  87         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  88         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  89 else()
  90         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  91         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  92 endif()
  93
  94 find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
  95
  96 # Find the platform's thread library (needed for C++11 threads).
  97 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  98 find_package(Threads REQUIRED)
  99
 100 #===============================================================================
 101 #= System Introspection
 102 #-------------------------------------------------------------------------------
 103
 104 include(memaccess)
 105 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 106
 107 #===============================================================================
 108 #= Config Header
 109 #-------------------------------------------------------------------------------
 110
 111 set(PV_TITLE PulseView)
 112 set(PV_DESCRIPTION "A GUI for sigrok")
 113
 114 set(PV_VERSION_MAJOR 0)
 115 set(PV_VERSION_MINOR 2)
 116 set(PV_VERSION_MICRO 0)
 117 set(PV_VERSION_STRING
 118         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 119 )
 120
 121 configure_file (
 122         ${PROJECT_SOURCE_DIR}/config.h.in
 123         ${PROJECT_BINARY_DIR}/config.h
 124 )
 125
 126 #===============================================================================
 127 #= Sources
 128 #-------------------------------------------------------------------------------
 129
 130 set(pulseview_SOURCES
 131         main.cpp
 132         pv/application.cpp
 133         pv/devicemanager.cpp
 134         pv/mainwindow.cpp
 135         pv/sigsession.cpp
 136         pv/storesession.cpp
 137         pv/util.cpp
 138         pv/data/analog.cpp
 139         pv/data/analogsnapshot.cpp
 140         pv/data/logic.cpp
 141         pv/data/logicsnapshot.cpp
 142         pv/data/signaldata.cpp
 143         pv/data/snapshot.cpp
 144         pv/dialogs/about.cpp
 145         pv/dialogs/connect.cpp
 146         pv/dialogs/storeprogress.cpp
 147         pv/popups/deviceoptions.cpp
 148         pv/popups/channels.cpp
 149         pv/prop/bool.cpp
 150         pv/prop/double.cpp
 151         pv/prop/enum.cpp
 152         pv/prop/int.cpp
 153         pv/prop/property.cpp
 154         pv/prop/string.cpp
 155         pv/prop/binding/binding.cpp
 156         pv/prop/binding/deviceoptions.cpp
 157         pv/toolbars/samplingbar.cpp
 158         pv/view/analogsignal.cpp
 159         pv/view/cursor.cpp
 160         pv/view/cursorheader.cpp
 161         pv/view/cursorpair.cpp
 162         pv/view/header.cpp
 163         pv/view/marginwidget.cpp
 164         pv/view/logicsignal.cpp
 165         pv/view/rowitem.cpp
 166         pv/view/rowitemowner.cpp
 167         pv/view/ruler.cpp
 168         pv/view/selectableitem.cpp
 169         pv/view/signal.cpp
 170         pv/view/timemarker.cpp
 171         pv/view/trace.cpp
 172         pv/view/tracegroup.cpp
 173         pv/view/tracepalette.cpp
 174         pv/view/view.cpp
 175         pv/view/viewport.cpp
 176         pv/widgets/colourbutton.cpp
 177         pv/widgets/colourpopup.cpp
 178         pv/widgets/popup.cpp
 179         pv/widgets/popuptoolbutton.cpp
 180         pv/widgets/sweeptimingwidget.cpp
 181         pv/widgets/wellarray.cpp
 182 )
 183
 184 # This list includes only QObject derived class headers.
 185 set(pulseview_HEADERS
 186         pv/mainwindow.h
 187         pv/sigsession.h
 188         pv/storesession.h
 189         pv/dialogs/about.h
 190         pv/dialogs/connect.h
 191         pv/dialogs/storeprogress.h
 192         pv/popups/channels.h
 193         pv/popups/deviceoptions.h
 194         pv/prop/bool.h
 195         pv/prop/double.h
 196         pv/prop/enum.h
 197         pv/prop/int.h
 198         pv/prop/property.h
 199         pv/prop/string.h
 200         pv/prop/binding/deviceoptions.h
 201         pv/toolbars/samplingbar.h
 202         pv/view/cursor.h
 203         pv/view/cursorheader.h
 204         pv/view/header.h
 205         pv/view/logicsignal.h
 206         pv/view/marginwidget.h
 207         pv/view/ruler.h
 208         pv/view/selectableitem.h
 209         pv/view/signal.h
 210         pv/view/timemarker.h
 211         pv/view/trace.h
 212         pv/view/tracegroup.h
 213         pv/view/view.h
 214         pv/view/viewport.h
 215         pv/widgets/colourbutton.h
 216         pv/widgets/colourpopup.h
 217         pv/widgets/popup.h
 218         pv/widgets/popuptoolbutton.h
 219         pv/widgets/sweeptimingwidget.h
 220         pv/widgets/wellarray.h
 221 )
 222
 223 set(pulseview_FORMS
 224         pv/dialogs/about.ui
 225 )
 226
 227 set(pulseview_RESOURCES
 228         pulseview.qrc
 229 )
 230
 231 if(ENABLE_SIGNALS)
 232         list(APPEND pulseview_SOURCES signalhandler.cpp)
 233         list(APPEND pulseview_HEADERS signalhandler.h)
 234 endif()
 235
 236 if(ENABLE_DECODE)
 237         list(APPEND pulseview_SOURCES
 238                 pv/data/decoderstack.cpp
 239                 pv/data/decode/annotation.cpp
 240                 pv/data/decode/decoder.cpp
 241                 pv/data/decode/row.cpp
 242                 pv/data/decode/rowdata.cpp
 243                 pv/prop/binding/decoderoptions.cpp
 244                 pv/view/decodetrace.cpp
 245                 pv/widgets/decodergroupbox.cpp
 246                 pv/widgets/decodermenu.cpp
 247         )
 248
 249         list(APPEND pulseview_HEADERS
 250                 pv/data/decoderstack.h
 251                 pv/view/decodetrace.h
 252                 pv/widgets/decodergroupbox.h
 253                 pv/widgets/decodermenu.h
 254         )
 255 endif()
 256
 257 if(WIN32)
 258         # Use the sigrok icon for the pulseview.exe executable.
 259         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 260         enable_language(RC)
 261         list(APPEND pulseview_SOURCES pulseviewico.rc)
 262 endif()
 263
 264 if(ANDROID)
 265         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 266 endif()
 267
 268 if(Qt5Core_FOUND)
 269         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 270         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 271         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 272 else()
 273         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 274         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 275         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 276         include(${QT_USE_FILE})
 277 endif()
 278
 279 #===============================================================================
 280 #= Global Definitions
 281 #-------------------------------------------------------------------------------
 282
 283 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 284 add_definitions(-D__STDC_LIMIT_MACROS)
 285 add_definitions(-Wall -Wextra)
 286 add_definitions(-std=c++11)
 287
 288 if(ENABLE_DECODE)
 289         add_definitions(-DENABLE_DECODE)
 290 endif()
 291
 292 if(NOT DISABLE_WERROR)
 293         add_definitions(-Werror)
 294 endif()
 295
 296 if(ENABLE_SIGNALS)
 297         add_definitions(-DENABLE_SIGNALS)
 298 endif()
 299
 300 #===============================================================================
 301 #= Global Include Directories
 302 #-------------------------------------------------------------------------------
 303
 304 include_directories(
 305         ${CMAKE_CURRENT_BINARY_DIR}
 306         ${CMAKE_CURRENT_SOURCE_DIR}
 307         ${Boost_INCLUDE_DIRS}
 308         ${QT_INCLUDE_DIRS}
 309 )
 310
 311 if(STATIC_PKGDEPS_LIBS)
 312         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 313 else()
 314         include_directories(${PKGDEPS_INCLUDE_DIRS})
 315 endif()
 316
 317 #===============================================================================
 318 #= Linker Configuration
 319 #-------------------------------------------------------------------------------
 320
 321 link_directories(${Boost_LIBRARY_DIRS})
 322
 323 set(PULSEVIEW_LINK_LIBS
 324         ${Boost_LIBRARIES}
 325         ${QT_LIBRARIES}
 326         ${CMAKE_THREAD_LIBS_INIT}
 327 )
 328
 329 if(STATIC_PKGDEPS_LIBS)
 330         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 331         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 332 if(WIN32)
 333         # Workaround for a MinGW linking issue.
 334         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 335 endif()
 336 else()
 337         link_directories(${PKGDEPS_LIBRARY_DIRS})
 338         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 339 endif()
 340
 341 if(WIN32)
 342         # On Windows we need to statically link the libqsvg imageformat
 343         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 344         add_definitions(-DQT_STATICPLUGIN)
 345         link_directories("${QT_PLUGINS_DIR}/imageformats")
 346         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 347         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 348 endif()
 349
 350 if(ANDROID)
 351         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 352 endif()
 353
 354 if(ANDROID)
 355 add_library(${PROJECT_NAME} SHARED
 356         ${pulseview_SOURCES}
 357         ${pulseview_HEADERS_MOC}
 358         ${pulseview_FORMS_HEADERS}
 359         ${pulseview_RESOURCES_RCC}
 360 )
 361 else()
 362 add_executable(${PROJECT_NAME}
 363         ${pulseview_SOURCES}
 364         ${pulseview_HEADERS_MOC}
 365         ${pulseview_FORMS_HEADERS}
 366         ${pulseview_RESOURCES_RCC}
 367 )
 368 endif()
 369
 370 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 371
 372 if(WIN32)
 373         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 374         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 375 endif()
 376
 377 if(ENABLE_COTIRE)
 378         include(cotire)
 379         cotire(${PROJECT_NAME})
 380 endif()
 381
 382 #===============================================================================
 383 #= Installation
 384 #-------------------------------------------------------------------------------
 385
 386 # Install the executable.
 387 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 388
 389 # Install the manpage.
 390 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 391
 392 #===============================================================================
 393 #= Packaging (handled by CPack)
 394 #-------------------------------------------------------------------------------
 395
 396 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 397 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 398 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 399 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 400 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 401 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 402 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 403         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 404 set(CPACK_SOURCE_GENERATOR "TGZ")
 405
 406 include(CPack)
 407
 408 #===============================================================================
 409 #= Tests
 410 #-------------------------------------------------------------------------------
 411
 412 if(ENABLE_TESTS)
 413         add_subdirectory(test)
 414         enable_testing()
 415         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 416 endif()