CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  41
  42 if(WIN32)
  43         # On Windows/MinGW we need to statically link to libraries.
  44         # This option is user configurable, but enable it by default on win32.
  45         set(STATIC_PKGDEPS_LIBS TRUE)
  46
  47         # Windows does not support UNIX signals.
  48         set(ENABLE_SIGNALS FALSE)
  49 endif()
  50
  51 if(NOT CMAKE_BUILD_TYPE)
  52   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  53       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  54       FORCE)
  55 endif()
  56
  57 #===============================================================================
  58 #= Dependencies
  59 #-------------------------------------------------------------------------------
  60
  61 list(APPEND PKGDEPS libsigrok>=0.3.0)
  62
  63 if(ENABLE_DECODE)
  64         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  65 endif()
  66
  67 if(ANDROID)
  68         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  69 endif()
  70
  71 find_package(PkgConfig)
  72 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  73
  74 if(FORCE_QT4)
  75         set(Qt5Core_FOUND FALSE)
  76 else()
  77         find_package(Qt5Core QUIET)
  78 endif()
  79
  80 if(Qt5Core_FOUND)
  81         message("-- Using Qt5")
  82         find_package(Qt5Widgets REQUIRED)
  83         find_package(Qt5Gui REQUIRED)
  84         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  85         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  86         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets)
  87         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  88 else()
  89         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  90         find_package(Qt4 REQUIRED)
  91 endif()
  92
  93 find_package(Boost 1.42 COMPONENTS filesystem system REQUIRED)
  94
  95 #===============================================================================
  96 #= System Introspection
  97 #-------------------------------------------------------------------------------
  98
  99 include(memaccess)
 100 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 101
 102 #===============================================================================
 103 #= Config Header
 104 #-------------------------------------------------------------------------------
 105
 106 set(PV_TITLE PulseView)
 107 set(PV_DESCRIPTION "A GUI for sigrok")
 108
 109 set(PV_VERSION_MAJOR 0)
 110 set(PV_VERSION_MINOR 2)
 111 set(PV_VERSION_MICRO 0)
 112 set(PV_VERSION_STRING
 113         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 114 )
 115
 116 configure_file (
 117         ${PROJECT_SOURCE_DIR}/config.h.in
 118         ${PROJECT_BINARY_DIR}/config.h
 119 )
 120
 121 #===============================================================================
 122 #= Sources
 123 #-------------------------------------------------------------------------------
 124
 125 set(pulseview_SOURCES
 126         main.cpp
 127         pv/devicemanager.cpp
 128         pv/mainwindow.cpp
 129         pv/sigsession.cpp
 130         pv/storesession.cpp
 131         pv/util.cpp
 132         pv/data/analog.cpp
 133         pv/data/analogsnapshot.cpp
 134         pv/data/logic.cpp
 135         pv/data/logicsnapshot.cpp
 136         pv/data/signaldata.cpp
 137         pv/data/snapshot.cpp
 138         pv/device/device.cpp
 139         pv/device/file.cpp
 140         pv/device/devinst.cpp
 141         pv/device/inputfile.cpp
 142         pv/device/sessionfile.cpp
 143         pv/dialogs/about.cpp
 144         pv/dialogs/connect.cpp
 145         pv/dialogs/storeprogress.cpp
 146         pv/popups/deviceoptions.cpp
 147         pv/popups/probes.cpp
 148         pv/prop/bool.cpp
 149         pv/prop/double.cpp
 150         pv/prop/enum.cpp
 151         pv/prop/int.cpp
 152         pv/prop/property.cpp
 153         pv/prop/string.cpp
 154         pv/prop/binding/binding.cpp
 155         pv/prop/binding/deviceoptions.cpp
 156         pv/toolbars/samplingbar.cpp
 157         pv/view/analogsignal.cpp
 158         pv/view/cursor.cpp
 159         pv/view/cursorheader.cpp
 160         pv/view/cursorpair.cpp
 161         pv/view/header.cpp
 162         pv/view/marginwidget.cpp
 163         pv/view/logicsignal.cpp
 164         pv/view/ruler.cpp
 165         pv/view/selectableitem.cpp
 166         pv/view/signal.cpp
 167         pv/view/timemarker.cpp
 168         pv/view/trace.cpp
 169         pv/view/tracepalette.cpp
 170         pv/view/view.cpp
 171         pv/view/viewport.cpp
 172         pv/widgets/colourbutton.cpp
 173         pv/widgets/colourpopup.cpp
 174         pv/widgets/popup.cpp
 175         pv/widgets/popuptoolbutton.cpp
 176         pv/widgets/sweeptimingwidget.cpp
 177         pv/widgets/wellarray.cpp
 178 )
 179
 180 # This list includes only QObject derived class headers.
 181 set(pulseview_HEADERS
 182         pv/mainwindow.h
 183         pv/sigsession.h
 184         pv/storesession.h
 185         pv/device/devinst.h
 186         pv/dialogs/about.h
 187         pv/dialogs/connect.h
 188         pv/dialogs/storeprogress.h
 189         pv/popups/probes.h
 190         pv/popups/deviceoptions.h
 191         pv/prop/bool.h
 192         pv/prop/double.h
 193         pv/prop/enum.h
 194         pv/prop/int.h
 195         pv/prop/property.h
 196         pv/prop/string.h
 197         pv/toolbars/samplingbar.h
 198         pv/view/cursor.h
 199         pv/view/cursorheader.h
 200         pv/view/header.h
 201         pv/view/logicsignal.h
 202         pv/view/marginwidget.h
 203         pv/view/ruler.h
 204         pv/view/selectableitem.h
 205         pv/view/signal.h
 206         pv/view/timemarker.h
 207         pv/view/trace.h
 208         pv/view/view.h
 209         pv/view/viewport.h
 210         pv/widgets/colourbutton.h
 211         pv/widgets/colourpopup.h
 212         pv/widgets/popup.h
 213         pv/widgets/popuptoolbutton.h
 214         pv/widgets/sweeptimingwidget.h
 215         pv/widgets/wellarray.h
 216 )
 217
 218 set(pulseview_FORMS
 219         pv/dialogs/about.ui
 220 )
 221
 222 set(pulseview_RESOURCES
 223         pulseview.qrc
 224 )
 225
 226 if(ENABLE_SIGNALS)
 227         list(APPEND pulseview_SOURCES signalhandler.cpp)
 228         list(APPEND pulseview_HEADERS signalhandler.h)
 229 endif()
 230
 231 if(ENABLE_DECODE)
 232         list(APPEND pulseview_SOURCES
 233                 pv/data/decoderstack.cpp
 234                 pv/data/decode/annotation.cpp
 235                 pv/data/decode/decoder.cpp
 236                 pv/data/decode/row.cpp
 237                 pv/data/decode/rowdata.cpp
 238                 pv/prop/binding/decoderoptions.cpp
 239                 pv/view/decodetrace.cpp
 240                 pv/widgets/decodergroupbox.cpp
 241                 pv/widgets/decodermenu.cpp
 242         )
 243
 244         list(APPEND pulseview_HEADERS
 245                 pv/data/decoderstack.h
 246                 pv/view/decodetrace.h
 247                 pv/widgets/decodergroupbox.h
 248                 pv/widgets/decodermenu.h
 249         )
 250 endif()
 251
 252 if(WIN32)
 253         # Use the sigrok icon for the pulseview.exe executable.
 254         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 255         enable_language(RC)
 256         list(APPEND pulseview_SOURCES pulseviewico.rc)
 257 endif()
 258
 259 if(ANDROID)
 260         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 261 endif()
 262
 263 if(Qt5Core_FOUND)
 264         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 265         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 266         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 267 else()
 268         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 269         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 270         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 271         include(${QT_USE_FILE})
 272 endif()
 273
 274 #===============================================================================
 275 #= Global Definitions
 276 #-------------------------------------------------------------------------------
 277
 278 add_definitions(${QT_DEFINITIONS})
 279 add_definitions(-D__STDC_LIMIT_MACROS)
 280 add_definitions(-Wall -Wextra)
 281 add_definitions(-std=c++11)
 282
 283 if(ENABLE_DECODE)
 284         add_definitions(-DENABLE_DECODE)
 285 endif()
 286
 287 if(NOT DISABLE_WERROR)
 288         add_definitions(-Werror)
 289 endif()
 290
 291 if(ENABLE_SIGNALS)
 292         add_definitions(-DENABLE_SIGNALS)
 293 endif()
 294
 295 #===============================================================================
 296 #= Global Include Directories
 297 #-------------------------------------------------------------------------------
 298
 299 include_directories(
 300         ${CMAKE_CURRENT_BINARY_DIR}
 301         ${CMAKE_CURRENT_SOURCE_DIR}
 302         ${Boost_INCLUDE_DIRS}
 303         ${QT_INCLUDE_DIRS}
 304 )
 305
 306 if(STATIC_PKGDEPS_LIBS)
 307         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 308 else()
 309         include_directories(${PKGDEPS_INCLUDE_DIRS})
 310 endif()
 311
 312 #===============================================================================
 313 #= Linker Configuration
 314 #-------------------------------------------------------------------------------
 315
 316 link_directories(${Boost_LIBRARY_DIRS})
 317
 318 set(PULSEVIEW_LINK_LIBS
 319         ${Boost_LIBRARIES}
 320         ${QT_LIBRARIES}
 321 )
 322
 323 if(STATIC_PKGDEPS_LIBS)
 324         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 325         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 326 if(WIN32)
 327         # Workaround for a MinGW linking issue.
 328         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 329 endif()
 330 else()
 331         link_directories(${PKGDEPS_LIBRARY_DIRS})
 332         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 333 endif()
 334
 335 if(WIN32)
 336         # On Windows we need to statically link the libqsvg imageformat
 337         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 338         add_definitions(-DQT_STATICPLUGIN)
 339         link_directories("${QT_PLUGINS_DIR}/imageformats")
 340         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 341         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 342 endif()
 343
 344 if(ANDROID)
 345         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 346 endif()
 347
 348 if(ANDROID)
 349 add_library(${PROJECT_NAME} SHARED
 350         ${pulseview_SOURCES}
 351         ${pulseview_HEADERS_MOC}
 352         ${pulseview_FORMS_HEADERS}
 353         ${pulseview_RESOURCES_RCC}
 354 )
 355 else()
 356 add_executable(${PROJECT_NAME}
 357         ${pulseview_SOURCES}
 358         ${pulseview_HEADERS_MOC}
 359         ${pulseview_FORMS_HEADERS}
 360         ${pulseview_RESOURCES_RCC}
 361 )
 362 endif()
 363
 364 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 365
 366 if(WIN32)
 367         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 368         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 369 endif()
 370
 371 if(ENABLE_COTIRE)
 372         include(cotire)
 373         cotire(${PROJECT_NAME})
 374 endif()
 375
 376 #===============================================================================
 377 #= Installation
 378 #-------------------------------------------------------------------------------
 379
 380 # Install the executable.
 381 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 382
 383 # Install the manpage.
 384 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 385
 386 #===============================================================================
 387 #= Packaging (handled by CPack)
 388 #-------------------------------------------------------------------------------
 389
 390 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 391 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 392 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 393 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 394 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 395 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 396 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 397         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 398 set(CPACK_SOURCE_GENERATOR "TGZ")
 399
 400 include(CPack)
 401
 402 #===============================================================================
 403 #= Tests
 404 #-------------------------------------------------------------------------------
 405
 406 if(ENABLE_TESTS)
 407         add_subdirectory(test)
 408         enable_testing()
 409         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 410 endif()