CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.3.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 2)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_STRING
 129         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 130 )
 131
 132 configure_file (
 133         ${PROJECT_SOURCE_DIR}/config.h.in
 134         ${PROJECT_BINARY_DIR}/config.h
 135 )
 136
 137 #===============================================================================
 138 #= Sources
 139 #-------------------------------------------------------------------------------
 140
 141 set(pulseview_SOURCES
 142         main.cpp
 143         pv/application.cpp
 144         pv/devicemanager.cpp
 145         pv/mainwindow.cpp
 146         pv/session.cpp
 147         pv/storesession.cpp
 148         pv/util.cpp
 149         pv/binding/binding.cpp
 150         pv/binding/inputoutput.cpp
 151         pv/binding/device.cpp
 152         pv/data/analog.cpp
 153         pv/data/analogsegment.cpp
 154         pv/data/logic.cpp
 155         pv/data/logicsegment.cpp
 156         pv/data/signaldata.cpp
 157         pv/data/segment.cpp
 158         pv/devices/device.cpp
 159         pv/devices/file.cpp
 160         pv/devices/hardwaredevice.cpp
 161         pv/devices/inputfile.cpp
 162         pv/devices/sessionfile.cpp
 163         pv/dialogs/about.cpp
 164         pv/dialogs/connect.cpp
 165         pv/dialogs/inputoutputoptions.cpp
 166         pv/dialogs/storeprogress.cpp
 167         pv/popups/deviceoptions.cpp
 168         pv/popups/channels.cpp
 169         pv/prop/bool.cpp
 170         pv/prop/double.cpp
 171         pv/prop/enum.cpp
 172         pv/prop/int.cpp
 173         pv/prop/property.cpp
 174         pv/prop/string.cpp
 175         pv/toolbars/mainbar.cpp
 176         pv/view/analogsignal.cpp
 177         pv/view/cursor.cpp
 178         pv/view/cursorpair.cpp
 179         pv/view/flag.cpp
 180         pv/view/header.cpp
 181         pv/view/marginwidget.cpp
 182         pv/view/logicsignal.cpp
 183         pv/view/rowitem.cpp
 184         pv/view/rowitemowner.cpp
 185         pv/view/ruler.cpp
 186         pv/view/signal.cpp
 187         pv/view/timeitem.cpp
 188         pv/view/timemarker.cpp
 189         pv/view/trace.cpp
 190         pv/view/tracegroup.cpp
 191         pv/view/tracepalette.cpp
 192         pv/view/view.cpp
 193         pv/view/viewitem.cpp
 194         pv/view/viewitempaintparams.cpp
 195         pv/view/viewport.cpp
 196         pv/view/viewwidget.cpp
 197         pv/widgets/colourbutton.cpp
 198         pv/widgets/colourpopup.cpp
 199         pv/widgets/devicetoolbutton.cpp
 200         pv/widgets/exportmenu.cpp
 201         pv/widgets/hidingmenubar.cpp
 202         pv/widgets/importmenu.cpp
 203         pv/widgets/popup.cpp
 204         pv/widgets/popuptoolbutton.cpp
 205         pv/widgets/sweeptimingwidget.cpp
 206         pv/widgets/wellarray.cpp
 207 )
 208
 209 # This list includes only QObject derived class headers.
 210 set(pulseview_HEADERS
 211         pv/mainwindow.hpp
 212         pv/session.hpp
 213         pv/storesession.hpp
 214         pv/binding/device.hpp
 215         pv/dialogs/about.hpp
 216         pv/dialogs/connect.hpp
 217         pv/dialogs/inputoutputoptions.hpp
 218         pv/dialogs/storeprogress.hpp
 219         pv/popups/channels.hpp
 220         pv/popups/deviceoptions.hpp
 221         pv/prop/bool.hpp
 222         pv/prop/double.hpp
 223         pv/prop/enum.hpp
 224         pv/prop/int.hpp
 225         pv/prop/property.hpp
 226         pv/prop/string.hpp
 227         pv/toolbars/mainbar.hpp
 228         pv/view/cursor.hpp
 229         pv/view/flag.hpp
 230         pv/view/header.hpp
 231         pv/view/logicsignal.hpp
 232         pv/view/marginwidget.hpp
 233         pv/view/rowitem.hpp
 234         pv/view/ruler.hpp
 235         pv/view/signal.hpp
 236         pv/view/timeitem.hpp
 237         pv/view/timemarker.hpp
 238         pv/view/trace.hpp
 239         pv/view/tracegroup.hpp
 240         pv/view/view.hpp
 241         pv/view/viewitem.hpp
 242         pv/view/viewport.hpp
 243         pv/view/viewwidget.hpp
 244         pv/widgets/colourbutton.hpp
 245         pv/widgets/colourpopup.hpp
 246         pv/widgets/devicetoolbutton.hpp
 247         pv/widgets/exportmenu.hpp
 248         pv/widgets/hidingmenubar.hpp
 249         pv/widgets/importmenu.hpp
 250         pv/widgets/popup.hpp
 251         pv/widgets/popuptoolbutton.hpp
 252         pv/widgets/sweeptimingwidget.hpp
 253         pv/widgets/wellarray.hpp
 254 )
 255
 256 set(pulseview_FORMS
 257         pv/dialogs/about.ui
 258 )
 259
 260 set(pulseview_RESOURCES
 261         pulseview.qrc
 262 )
 263
 264 if(ENABLE_SIGNALS)
 265         list(APPEND pulseview_SOURCES signalhandler.cpp)
 266         list(APPEND pulseview_HEADERS signalhandler.hpp)
 267 endif()
 268
 269 if(ENABLE_DECODE)
 270         list(APPEND pulseview_SOURCES
 271                 pv/binding/decoder.cpp
 272                 pv/data/decoderstack.cpp
 273                 pv/data/decode/annotation.cpp
 274                 pv/data/decode/decoder.cpp
 275                 pv/data/decode/row.cpp
 276                 pv/data/decode/rowdata.cpp
 277                 pv/view/decodetrace.cpp
 278                 pv/widgets/decodergroupbox.cpp
 279                 pv/widgets/decodermenu.cpp
 280         )
 281
 282         list(APPEND pulseview_HEADERS
 283                 pv/data/decoderstack.hpp
 284                 pv/view/decodetrace.hpp
 285                 pv/widgets/decodergroupbox.hpp
 286                 pv/widgets/decodermenu.hpp
 287         )
 288 endif()
 289
 290 if(WIN32)
 291         # Use the sigrok icon for the pulseview.exe executable.
 292         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 293         enable_language(RC)
 294         list(APPEND pulseview_SOURCES pulseviewico.rc)
 295 endif()
 296
 297 if(ANDROID)
 298         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 299 endif()
 300
 301 if(Qt5Core_FOUND)
 302         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 303         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 304         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 305 else()
 306         # Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
 307         # https://bugreports.qt.io/browse/QTBUG-22829
 308         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
 309                 OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
 310         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 311         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 312         include(${QT_USE_FILE})
 313 endif()
 314
 315 #===============================================================================
 316 #= Global Definitions
 317 #-------------------------------------------------------------------------------
 318
 319 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 320 add_definitions(-D__STDC_LIMIT_MACROS)
 321 add_definitions(-Wall -Wextra)
 322 add_definitions(-std=c++11)
 323
 324 if(ENABLE_DECODE)
 325         add_definitions(-DENABLE_DECODE)
 326 endif()
 327
 328 if(NOT DISABLE_WERROR)
 329         add_definitions(-Werror)
 330 endif()
 331
 332 if(ENABLE_SIGNALS)
 333         add_definitions(-DENABLE_SIGNALS)
 334 endif()
 335
 336 #===============================================================================
 337 #= Global Include Directories
 338 #-------------------------------------------------------------------------------
 339
 340 include_directories(
 341         ${CMAKE_CURRENT_BINARY_DIR}
 342         ${CMAKE_CURRENT_SOURCE_DIR}
 343         ${Boost_INCLUDE_DIRS}
 344         ${QT_INCLUDE_DIRS}
 345 )
 346
 347 if(STATIC_PKGDEPS_LIBS)
 348         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 349 else()
 350         include_directories(${PKGDEPS_INCLUDE_DIRS})
 351 endif()
 352
 353 #===============================================================================
 354 #= Linker Configuration
 355 #-------------------------------------------------------------------------------
 356
 357 link_directories(${Boost_LIBRARY_DIRS})
 358
 359 set(PULSEVIEW_LINK_LIBS
 360         ${Boost_LIBRARIES}
 361         ${QT_LIBRARIES}
 362         ${CMAKE_THREAD_LIBS_INIT}
 363 )
 364
 365 if(STATIC_PKGDEPS_LIBS)
 366         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 367         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 368 if(WIN32)
 369         # Workaround for a MinGW linking issue.
 370         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 371 endif()
 372 else()
 373         link_directories(${PKGDEPS_LIBRARY_DIRS})
 374         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 375 endif()
 376
 377 if(WIN32)
 378         # On Windows we need to statically link the libqsvg imageformat
 379         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 380         add_definitions(-DQT_STATICPLUGIN)
 381         link_directories("${QT_PLUGINS_DIR}/imageformats")
 382         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 383         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 384 endif()
 385
 386 if(ANDROID)
 387         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 388 endif()
 389
 390 if(ANDROID)
 391 add_library(${PROJECT_NAME} SHARED
 392         ${pulseview_SOURCES}
 393         ${pulseview_HEADERS_MOC}
 394         ${pulseview_FORMS_HEADERS}
 395         ${pulseview_RESOURCES_RCC}
 396 )
 397 else()
 398 add_executable(${PROJECT_NAME}
 399         ${pulseview_SOURCES}
 400         ${pulseview_HEADERS_MOC}
 401         ${pulseview_FORMS_HEADERS}
 402         ${pulseview_RESOURCES_RCC}
 403 )
 404 endif()
 405
 406 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 407
 408 if(WIN32)
 409         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 410         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 411 endif()
 412
 413 #===============================================================================
 414 #= Installation
 415 #-------------------------------------------------------------------------------
 416
 417 # Install the executable.
 418 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 419
 420 # Install the manpage.
 421 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 422
 423 #===============================================================================
 424 #= Packaging (handled by CPack)
 425 #-------------------------------------------------------------------------------
 426
 427 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 428 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 429 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 430 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 431 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 432 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 433 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 434         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 435 set(CPACK_SOURCE_GENERATOR "TGZ")
 436
 437 include(CPack)
 438
 439 #===============================================================================
 440 #= Tests
 441 #-------------------------------------------------------------------------------
 442
 443 if(ENABLE_TESTS)
 444         add_subdirectory(test)
 445         enable_testing()
 446         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 447 endif()