CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27 include(cotire)
  28
  29 project(pulseview)
  30
  31 #===============================================================================
  32 #= User Options
  33 #-------------------------------------------------------------------------------
  34
  35 option(DISABLE_WERROR "Build without -Werror" FALSE)
  36 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  37 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS on)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windsws does not support UNIX signals
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 #===============================================================================
  55 #= Dependencies
  56 #-------------------------------------------------------------------------------
  57
  58 list(APPEND PKGDEPS
  59         libsigrok>=0.2.0
  60 )
  61
  62 if(ENABLE_SIGROKDECODE)
  63         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  64 endif()
  65
  66 find_package(PkgConfig)
  67 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  68
  69 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  70 find_package(Qt4 REQUIRED)
  71
  72 # Find the platform's thread library (needed for boost-thread).
  73 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  74 find_package(Threads)
  75
  76 if(WIN32)
  77 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  78 # The library is named libboost_thread_win32* (not libboost_thread*).
  79 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  80 else()
  81 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  82 endif()
  83
  84 #===============================================================================
  85 #= Config Header
  86 #-------------------------------------------------------------------------------
  87
  88 set(PV_TITLE PulseView)
  89 set(PV_DESCRIPTION "A GUI for sigrok")
  90
  91 set(PV_VERSION_MAJOR 0)
  92 set(PV_VERSION_MINOR 1)
  93 set(PV_VERSION_MICRO 0)
  94 set(PV_VERSION_STRING
  95         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  96 )
  97
  98 configure_file (
  99         ${PROJECT_SOURCE_DIR}/config.h.in
 100         ${PROJECT_BINARY_DIR}/config.h
 101 )
 102
 103 #===============================================================================
 104 #= Sources
 105 #-------------------------------------------------------------------------------
 106
 107 set(pulseview_SOURCES
 108         main.cpp
 109         pv/devicemanager.cpp
 110         pv/mainwindow.cpp
 111         pv/sigsession.cpp
 112         pv/data/analog.cpp
 113         pv/data/analogsnapshot.cpp
 114         pv/data/logic.cpp
 115         pv/data/logicsnapshot.cpp
 116         pv/data/signaldata.cpp
 117         pv/data/snapshot.cpp
 118         pv/dialogs/about.cpp
 119         pv/dialogs/connect.cpp
 120         pv/dialogs/deviceoptions.cpp
 121         pv/prop/bool.cpp
 122         pv/prop/double.cpp
 123         pv/prop/enum.cpp
 124         pv/prop/int.cpp
 125         pv/prop/property.cpp
 126         pv/prop/binding/binding.cpp
 127         pv/prop/binding/deviceoptions.cpp
 128         pv/toolbars/contextbar.cpp
 129         pv/toolbars/samplingbar.cpp
 130         pv/view/analogsignal.cpp
 131         pv/view/cursor.cpp
 132         pv/view/cursorpair.cpp
 133         pv/view/header.cpp
 134         pv/view/marginwidget.cpp
 135         pv/view/logicsignal.cpp
 136         pv/view/ruler.cpp
 137         pv/view/selectableitem.cpp
 138         pv/view/signal.cpp
 139         pv/view/timemarker.cpp
 140         pv/view/trace.cpp
 141         pv/view/view.cpp
 142         pv/view/viewport.cpp
 143 )
 144
 145 # This list includes only QObject derrived class headers
 146 set(pulseview_HEADERS
 147         pv/mainwindow.h
 148         pv/sigsession.h
 149         pv/dialogs/about.h
 150         pv/dialogs/connect.h
 151         pv/dialogs/deviceoptions.h
 152         pv/toolbars/contextbar.h
 153         pv/toolbars/samplingbar.h
 154         pv/view/cursor.h
 155         pv/view/header.h
 156         pv/view/logicsignal.h
 157         pv/view/marginwidget.h
 158         pv/view/ruler.h
 159         pv/view/selectableitem.h
 160         pv/view/signal.h
 161         pv/view/timemarker.h
 162         pv/view/trace.h
 163         pv/view/view.h
 164         pv/view/viewport.h
 165 )
 166
 167 set(pulseview_FORMS
 168         pv/dialogs/about.ui
 169 )
 170
 171 set(pulseview_RESOURCES
 172         pulseview.qrc
 173 )
 174
 175 if(ENABLE_SIGNALS)
 176         list(APPEND pulseview_SOURCES signalhandler.cpp)
 177         list(APPEND pulseview_HEADERS signalhandler.h)
 178 endif()
 179
 180 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 181 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 182 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 183
 184 include(${QT_USE_FILE})
 185
 186 #===============================================================================
 187 #= Global Definitions
 188 #-------------------------------------------------------------------------------
 189
 190 add_definitions(${QT_DEFINITIONS})
 191 add_definitions(-Wall -Wextra)
 192
 193 if(ENABLE_SIGROKDECODE)
 194         add_definitions(-DENABLE_SIGROKDECODE)
 195 endif()
 196
 197 if(NOT DISABLE_WERROR)
 198         add_definitions(-Werror)
 199 endif()
 200
 201 #===============================================================================
 202 #= Global Include Directories
 203 #-------------------------------------------------------------------------------
 204
 205 include_directories(
 206         ${CMAKE_CURRENT_BINARY_DIR}
 207         ${CMAKE_CURRENT_SOURCE_DIR}
 208         ${Boost_INCLUDE_DIRS}
 209 )
 210
 211 if(STATIC_PKGDEPS_LIBS)
 212         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 213 else()
 214         include_directories(${PKGDEPS_INCLUDE_DIRS})
 215 endif()
 216
 217 #===============================================================================
 218 #= Linker Configuration
 219 #-------------------------------------------------------------------------------
 220
 221 link_directories(${Boost_LIBRARY_DIRS})
 222
 223 set(PULSEVIEW_LINK_LIBS
 224         ${Boost_LIBRARIES}
 225         ${CMAKE_THREAD_LIBS_INIT}
 226         ${QT_LIBRARIES}
 227 )
 228
 229 if(STATIC_PKGDEPS_LIBS)
 230         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 231         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 232 else()
 233         link_directories(${PKGDEPS_LIBRARY_DIRS})
 234         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 235 endif()
 236
 237 add_executable(${PROJECT_NAME}
 238         ${pulseview_SOURCES}
 239         ${pulseview_HEADERS_MOC}
 240         ${pulseview_FORMS_HEADERS}
 241         ${pulseview_RESOURCES_RCC}
 242 )
 243
 244 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 245 cotire(${PROJECT_NAME})
 246
 247 if(WIN32)
 248 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 249 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 250 endif()
 251
 252 #===============================================================================
 253 #= Installation
 254 #-------------------------------------------------------------------------------
 255
 256 # Install the executable.
 257 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 258
 259 # Install the manpage.
 260 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 261
 262 #===============================================================================
 263 #= Packaging (handled by CPack)
 264 #-------------------------------------------------------------------------------
 265
 266 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 267 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 268 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 269 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 270 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 271 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 272 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 273         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 274 set(CPACK_SOURCE_GENERATOR "TGZ")
 275
 276 include(CPack)
 277
 278 #===============================================================================
 279 #= Tests
 280 #-------------------------------------------------------------------------------
 281
 282 if(ENABLE_TESTS)
 283         add_subdirectory(test)
 284         enable_testing()
 285         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 286 endif(ENABLE_TESTS)