X-Git-Url: https://sigrok.org/gitweb/?p=libsigrokdecode.git;a=blobdiff_plain;f=configure.ac;h=772b984ed6b8cdcda9c496e5443b4fb10c3780e3;hp=abc2a37dacafd85e26dc8fcb9ad00aaa927b7450;hb=a27981c145cd9a3709673339dc455f3a0d5c3745;hpb=0631e33dc11b621914af0e76a1864567557ebdc4;ds=sidebyside

diff --git a/configure.ac b/configure.ac
index abc2a37..772b984 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,5 +1,5 @@
 ##
-## This file is part of the sigrok project.
+## This file is part of the libsigrokdecode project.
 ##
 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
 ##
@@ -21,186 +21,155 @@
 AC_PREREQ([2.63])
 
 # libsigrokdecode package version number (NOT the same as shared lib version!).
-m4_define([srd_package_version_major], [0])
-m4_define([srd_package_version_minor], [1])
-m4_define([srd_package_version_micro], [0])
-m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
-
-AC_INIT([libsigrokdecode], [srd_package_version],
+AC_INIT([libsigrokdecode], [0.6.0],
 	[sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
 	[http://www.sigrok.org])
-AC_CONFIG_HEADER([config.h])
-AC_CONFIG_MACRO_DIR([autostuff])
+AC_CONFIG_MACRO_DIR([m4])
 AC_CONFIG_AUX_DIR([autostuff])
+AC_CONFIG_HEADERS([config.h version.h])
 
 # We require at least automake 1.11 (needed for 'silent rules').
-AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
-m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news color-tests])
+AM_SILENT_RULES([yes])
 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
 
-AH_TOP([#ifndef SRD_CONFIG_H
-#define SRD_CONFIG_H    /* To stop multiple inclusions. */])
-AH_BOTTOM([#endif /* SRD_CONFIG_H */])
-
-CFLAGS="-g -Wall -Wextra"
+AC_CANONICAL_HOST
 
 # Checks for programs.
-AC_PROG_CXX
 AC_PROG_CC
-AC_PROG_CPP
 AC_PROG_INSTALL
 AC_PROG_LN_S
 
+# Required for per-target flags or subdir-objects with C sources.
+AM_PROG_CC_C_O
+
+# Set the standard the C library headers should conform to.
+AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
+#ifndef _POSIX_C_SOURCE
+# define _POSIX_C_SOURCE 200112L
+#endif])
+
+# Get compiler versions.
+SR_PROG_VERSION([$CC], [srd_cc_version])
+
 # Initialize libtool.
 LT_INIT
 
-# Initialize pkg-config.
-# We require at least 0.22, as "Requires.private" behaviour changed there.
-PKG_PROG_PKG_CONFIG([0.22])
+# Set up the libsigrokdecode version defines.
+SR_PKG_VERSION_SET([SRD_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
 
 # Library version for libsigrokdecode (NOT the same as the package version).
 # Carefully read the libtool docs before updating these numbers!
 # The algorithm for determining which number to change (and how) is nontrivial!
 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
-SRD_LIB_VERSION_CURRENT=0
-SRD_LIB_VERSION_REVISION=0
-SRD_LIB_VERSION_AGE=0
-SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
-SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
-AC_SUBST(SRD_LIB_VERSION_CURRENT)
-AC_SUBST(SRD_LIB_VERSION_REVISION)
-AC_SUBST(SRD_LIB_VERSION_AGE)
-AC_SUBST(SRD_LIB_VERSION)
-AC_SUBST(SRD_LIB_LDFLAGS)
-
-# Checks for libraries.
-
-# libglib-2.0 is always needed.
-# Note: glib-2.0 is part of the libsigrokdecode API
-# (hard pkg-config requirement).
-AM_PATH_GLIB_2_0([2.28.0],
-        [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
-
-# Python support. We require at least Python >= 3.0.
-AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
-AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.2-config python3.1-config python3.0-config])
-CPPFLAGS_PYTHON=""
-LDFLAGS_PYTHON=""
-case "$build" in
-*mingw*)
-	# We currently hardcode the paths to the Python 3.2 default install
-	# location as there's no 'python-config' script on Windows, it seems.
-	AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
-	CPPFLAGS_PYTHON="-I/c/Python32/include"
-	LDFLAGS_PYTHON="-L/c/Python32/libs -lpython32"
-	;;
-*)
-	# We know that Linux has 'python3-config'.
-	# On Darwin, Macports has python3.x-config, fink has python3-config.
-	# Mac OS X (Snow Leopard) ships with 'python-config' per default, but
-	# that's Python 2.x, so not useful for us.
-	# Everything else is untested, we just hope 'PYTHON3_CONFIG' works.
-	if test -n "$PYTHON3_CONFIG"; then
-		CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
-		LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
-	else
-		AC_MSG_ERROR([python3-config not found])
-	fi
-	;;
-esac
-AC_SUBST(CPPFLAGS_PYTHON)
-AC_SUBST(LDFLAGS_PYTHON)
-
-# Checks for header files.
-# These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
-# AC_CHECK_HEADERS([])
-
-# Checks for typedefs, structures, and compiler characteristics.
-AC_C_INLINE
-AC_TYPE_INT8_T
-AC_TYPE_INT16_T
-AC_TYPE_INT32_T
-AC_TYPE_INT64_T
-AC_TYPE_UINT8_T
-AC_TYPE_UINT16_T
-AC_TYPE_UINT32_T
-AC_TYPE_UINT64_T
-AC_TYPE_SIZE_T
-
-# Checks for library functions.
-AC_CHECK_FUNCS([memset strtoull])
-
-AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
-AC_SUBST(MAKEFLAGS, '--no-print-directory')
-AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
-
-SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
-SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
-SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
-SRD_PACKAGE_VERSION=srd_package_version
-
-AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
-AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
-AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
-AC_SUBST(SRD_PACKAGE_VERSION)
-
-AC_CONFIG_FILES([Makefile
-		 sigrokdecode.h
-		 libsigrokdecode.pc
-		 decoders/Makefile
-		 decoders/dcf77/Makefile
-		 decoders/edid/Makefile
-		 decoders/i2c/Makefile
-		 decoders/i2cdemux/Makefile
-		 decoders/i2cfilter/Makefile
-		 decoders/i2s/Makefile
-		 decoders/jtag/Makefile
-		 decoders/jtag_stm32/Makefile
-		 decoders/lm75/Makefile
-		 decoders/lpc/Makefile
-		 decoders/mlx90614/Makefile
-		 decoders/mx25lxx05d/Makefile
-		 decoders/mxc6225xu/Makefile
-		 decoders/nunchuk/Makefile
-		 decoders/pan1321/Makefile
-		 decoders/rtc8564/Makefile
-		 decoders/spi/Makefile
-		 decoders/transitioncounter/Makefile
-		 decoders/uart/Makefile
-		 decoders/uart_dump/Makefile
-		 decoders/usb/Makefile
-		 decoders/usb_signalling/Makefile
-		 decoders/usb_protocol/Makefile
-		 decoders/onewire/Makefile
-		])
+# Format: current:revision:age.
+SR_LIB_VERSION_SET([SRD_LIB_VERSION], [4:0:0])
 
-AC_OUTPUT
+AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
+
+# Initialize pkg-config.
+# We require at least 0.22, as "Requires.private" behaviour changed there.
+PKG_PROG_PKG_CONFIG
+
+############################
+##  Package dependencies  ##
+############################
+
+# Initialize pkg-config.
+# We require at least 0.22, as "Requires.private" behaviour changed there.
+PKG_PROG_PKG_CONFIG([0.22])
+
+# Collect the pkg-config module names of all dependencies in SRD_PKGLIBS.
+# These are used to derive the compiler flags and for the "Requires.private"
+# field in the generated libsigrokdecode.pc file.
+SRD_PKGLIBS=
+SRD_PKGLIBS_TESTS=
 
-echo
-echo "libsigrokdecode configuration summary:"
-echo
-echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
-echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
-echo "  - Prefix: $prefix"
-echo
-echo "Detected libraries:"
-echo
-
-# Note: This only works for libs with pkg-config integration.
-for lib in "glib-2.0"; do
-        if `$PKG_CONFIG --exists $lib`; then
-                ver=`$PKG_CONFIG --modversion $lib`
-                answer="yes ($ver)"
-        else
-                answer="no"
-        fi
-        echo "  - $lib: $answer"
-done
-
-echo
-echo "Detected Python:"
-echo
-echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
-echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
-echo
+# Keep track of all checked modules so we can list them at the end.
+SR_PKG_CHECK_SUMMARY([srd_pkglibs_summary])
+
+# Python 3 is always needed.
+SR_PKG_CHECK([python3], [SRD_PKGLIBS],
+	[python3 >= 3.2], [python-3.7 >= 3.7], [python-3.6 >= 3.6], [python-3.5 >= 3.5], [python-3.4 >= 3.4], [python-3.3 >= 3.3], [python-3.2 >= 3.2])
+AS_IF([test "x$sr_have_python3" = xno],
+	[AC_MSG_ERROR([Cannot find Python 3 development headers.])])
+
+# We also need to find the name of the python3 executable (for 'make install').
+# Some OSes call this python3, some call it python3.2, etc. etc.
+AC_ARG_VAR([PYTHON3], [Python 3 interpreter])
+AC_CHECK_PROGS([PYTHON3], [python3.7 python3.6 python3.5 python3.4 python3.3 python3.2 python3])
+AS_IF([test "x$PYTHON3" = x],
+	[AC_MSG_ERROR([Cannot find Python 3 interpreter.])])
+
+######################
+##  Feature checks  ##
+######################
+
+# Keep track of all checked modules so we can list them at the end.
+SR_PKG_CHECK_SUMMARY([srd_pkglibs_opt_summary])
+
+# The Check unit testing framework is optional. Disable if not found.
+SR_PKG_CHECK([check], [SRD_PKGLIBS_TESTS], [check >= 0.9.4])
+AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
+
+# Enable the C99 standard if possible, and enforce the use
+# of SRD_API to explicitly mark all public API functions.
+SRD_EXTRA_CFLAGS=
+SR_CHECK_COMPILE_FLAGS([SRD_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
+SR_CHECK_COMPILE_FLAGS([SRD_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
+
+# Select suitable compiler warning flags.
+SR_ARG_ENABLE_WARNINGS([SRD_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes -Wshadow -Wformat=2 -Wno-format-nonliteral -Wfloat-equal])
+
+# Link against libm, this is required (among other things) by Python.
+SRD_EXTRA_LIBS=
+SR_SEARCH_LIBS([SRD_EXTRA_LIBS], [pow], [m])
+
+AC_SYS_LARGEFILE
+
+AC_C_BIGENDIAN
+
+##############################
+##  Finalize configuration  ##
+##############################
+
+AC_SUBST([SRD_PKGLIBS])
+
+# Retrieve the compile and link flags for all modules combined.
+# Also, bail out at this point if any module dependency is not met.
+PKG_CHECK_MODULES([LIBSIGROKDECODE], [glib-2.0 >= 2.34 $SRD_PKGLIBS])
+PKG_CHECK_MODULES([TESTS], [$SRD_PKGLIBS_TESTS glib-2.0 $SRD_PKGLIBS])
+
+srd_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
+
+AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
+        [The canonical host libsigrokdecode will run on.])
+
+AC_CONFIG_FILES([Makefile libsigrokdecode.pc])
+
+AC_OUTPUT
 
+cat >&AS_MESSAGE_FD <<_EOF
+
+libsigrokdecode configuration summary:
+ - Package version................. $SRD_PACKAGE_VERSION
+ - Library ABI version............. $SRD_LIB_VERSION
+ - Prefix.......................... $prefix
+ - Building on..................... $build
+ - Building for.................... $host
+ - Building shared / static........ $enable_shared / $enable_static
+
+Compile configuration:
+ - C compiler...................... $CC
+ - C compiler version.............. $srd_cc_version
+ - C compiler flags................ $CFLAGS
+ - Additional C compiler flags..... $SRD_EXTRA_CFLAGS
+ - C compiler warnings............. $SRD_WFLAGS
+ - Linker flags.................... $LDFLAGS
+
+Detected libraries (required):
+ - glib-2.0 >= 2.34................ $srd_glib_version
+$srd_pkglibs_summary
+Detected libraries (optional):
+$srd_pkglibs_opt_summary
+_EOF