configure.ac

   1 ##
   2 ## This file is part of the libsigrokdecode project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([srd_package_version_major], [0])
  25 m4_define([srd_package_version_minor], [2])
  26 m4_define([srd_package_version_micro], [0])
  27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
  28
  29 AC_INIT([libsigrokdecode], [srd_package_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SRD_CONFIG_H
  42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SRD_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Initialize libtool.
  56 LT_INIT
  57
  58 # Initialize pkg-config.
  59 # We require at least 0.22, as "Requires.private" behaviour changed there.
  60 PKG_PROG_PKG_CONFIG([0.22])
  61
  62 # Library version for libsigrokdecode (NOT the same as the package version).
  63 # Carefully read the libtool docs before updating these numbers!
  64 # The algorithm for determining which number to change (and how) is nontrivial!
  65 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  66 SRD_LIB_VERSION_CURRENT=1
  67 SRD_LIB_VERSION_REVISION=0
  68 SRD_LIB_VERSION_AGE=0
  69 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
  70 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
  71 AC_SUBST(SRD_LIB_VERSION_CURRENT)
  72 AC_SUBST(SRD_LIB_VERSION_REVISION)
  73 AC_SUBST(SRD_LIB_VERSION_AGE)
  74 AC_SUBST(SRD_LIB_VERSION)
  75 AC_SUBST(SRD_LIB_LDFLAGS)
  76
  77 # Checks for libraries.
  78
  79 # libglib-2.0 is always needed.
  80 # Note: glib-2.0 is part of the libsigrokdecode API
  81 # (hard pkg-config requirement).
  82 AM_PATH_GLIB_2_0([2.24.0],
  83         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  84
  85 # Python support. We require at least Python >= 3.0.
  86 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
  87 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.3-config python-config-3.3 python3.2-config python-config-3.2 python3.1-config python-config-3.1 python3.0-config python-config-3.0])
  88 CPPFLAGS_PYTHON=""
  89 LDFLAGS_PYTHON=""
  90 case "$build" in
  91 *mingw*)
  92         # We currently hardcode the paths to the Python 3.2 default install
  93         # location as there's no 'python-config' script on Windows, it seems.
  94         # Note: We add both the /c/ and c:/ syntax (needed for cmake).
  95         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
  96         CPPFLAGS_PYTHON="-I/c/Python32/include -Ic:/Python32/include"
  97         LDFLAGS_PYTHON="-L/c/Python32/libs -Lc:/Python32/libs -lpython32"
  98         ;;
  99 *)
 100         # We know that Linux has 'python3-config'.
 101         # On Darwin, Macports has python3.x-config, fink has python3-config.
 102         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
 103         # that's Python 2.x, so not useful for us.
 104         # Everything else is untested, we just hope some $PYTHON3_CONFIG
 105         # (i.e., any of the tools we check for above) is available.
 106         if test -n "$PYTHON3_CONFIG"; then
 107                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
 108                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
 109         else
 110                 AC_MSG_ERROR([python3-config not found])
 111         fi
 112         ;;
 113 esac
 114 AC_SUBST(CPPFLAGS_PYTHON)
 115 AC_SUBST(LDFLAGS_PYTHON)
 116
 117 # Checks for header files.
 118 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 119 # AC_CHECK_HEADERS([])
 120
 121 # Checks for typedefs, structures, and compiler characteristics.
 122 AC_C_INLINE
 123 AC_TYPE_INT8_T
 124 AC_TYPE_INT16_T
 125 AC_TYPE_INT32_T
 126 AC_TYPE_INT64_T
 127 AC_TYPE_UINT8_T
 128 AC_TYPE_UINT16_T
 129 AC_TYPE_UINT32_T
 130 AC_TYPE_UINT64_T
 131 AC_TYPE_SIZE_T
 132
 133 # Checks for library functions.
 134 AC_CHECK_FUNCS([memset strtoull])
 135
 136 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 137 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 138 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 139
 140 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
 141 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
 142 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
 143 SRD_PACKAGE_VERSION=srd_package_version
 144
 145 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
 146 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
 147 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
 148 AC_SUBST(SRD_PACKAGE_VERSION)
 149
 150 AC_CONFIG_FILES([Makefile
 151                  libsigrokdecode.h
 152                  libsigrokdecode.pc
 153                  contrib/Makefile
 154                  decoders/Makefile
 155                  decoders/avr_isp/Makefile
 156                  decoders/can/Makefile
 157                  decoders/dcf77/Makefile
 158                  decoders/ds1307/Makefile
 159                  decoders/edid/Makefile
 160                  decoders/i2c/Makefile
 161                  decoders/i2cdemux/Makefile
 162                  decoders/i2cfilter/Makefile
 163                  decoders/i2s/Makefile
 164                  decoders/jtag/Makefile
 165                  decoders/jtag_stm32/Makefile
 166                  decoders/lm75/Makefile
 167                  decoders/lpc/Makefile
 168                  decoders/maxim_ds28ea00/Makefile
 169                  decoders/mlx90614/Makefile
 170                  decoders/mx25lxx05d/Makefile
 171                  decoders/mxc6225xu/Makefile
 172                  decoders/nunchuk/Makefile
 173                  decoders/onewire_link/Makefile
 174                  decoders/onewire_network/Makefile
 175                  decoders/pan1321/Makefile
 176                  decoders/rtc8564/Makefile
 177                  decoders/sdcard_spi/Makefile
 178                  decoders/spi/Makefile
 179                  decoders/tlc5620/Makefile
 180                  decoders/transitioncounter/Makefile
 181                  decoders/uart/Makefile
 182                  decoders/uart_dump/Makefile
 183                  decoders/usb_protocol/Makefile
 184                  decoders/usb_signalling/Makefile
 185                 ])
 186
 187 AC_OUTPUT
 188
 189 echo
 190 echo "libsigrokdecode configuration summary:"
 191 echo
 192 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
 193 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
 194 echo "  - Prefix: $prefix"
 195 echo "  - Building on: $build"
 196 echo "  - Building for: $host"
 197 echo
 198 echo "Detected libraries:"
 199 echo
 200
 201 # Note: This only works for libs with pkg-config integration.
 202 for lib in "glib-2.0 >= 2.24.0"; do
 203         if `$PKG_CONFIG --exists $lib`; then
 204                 ver=`$PKG_CONFIG --modversion $lib`
 205                 answer="yes ($ver)"
 206         else
 207                 answer="no"
 208         fi
 209         echo "  - $lib: $answer"
 210 done
 211
 212 echo
 213 echo "Detected Python:"
 214 echo
 215 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
 216 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
 217 echo
 218