configure.ac: Check for all known Python3 pkg-config names.
[libsigrokdecode.git] / configure.ac
1 ##
2 ## This file is part of the libsigrokdecode project.
3 ##
4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
5 ##
6 ## This program is free software: you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation, either version 3 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 # We require at least autoconf 2.63 (AC_INIT format changed there).
21 AC_PREREQ([2.63])
22
23 # libsigrokdecode package version number (NOT the same as shared lib version!).
24 m4_define([srd_package_version_major], [0])
25 m4_define([srd_package_version_minor], [2])
26 m4_define([srd_package_version_micro], [0])
27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
28
29 AC_INIT([libsigrokdecode], [srd_package_version],
30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
31         [http://www.sigrok.org])
32 AC_CONFIG_HEADER([config.h])
33 AC_CONFIG_MACRO_DIR([autostuff])
34 AC_CONFIG_AUX_DIR([autostuff])
35
36 # We require at least automake 1.11 (needed for 'silent rules').
37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
40
41 AH_TOP([#ifndef SRD_CONFIG_H
42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
44
45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
46 # and enforce use of SRD_API to explicitly mark all public API functions.
47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
48
49 # Checks for programs.
50 AC_PROG_CC
51 AC_PROG_CPP
52 AC_PROG_INSTALL
53 AC_PROG_LN_S
54
55 # Required for per-target flags or subdir-objects with C sources.
56 AM_PROG_CC_C_O
57
58 # Initialize libtool.
59 LT_INIT
60
61 # Initialize pkg-config.
62 # We require at least 0.22, as "Requires.private" behaviour changed there.
63 PKG_PROG_PKG_CONFIG([0.22])
64
65 # Library version for libsigrokdecode (NOT the same as the package version).
66 # Carefully read the libtool docs before updating these numbers!
67 # The algorithm for determining which number to change (and how) is nontrivial!
68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
69 SRD_LIB_VERSION_CURRENT=1
70 SRD_LIB_VERSION_REVISION=0
71 SRD_LIB_VERSION_AGE=0
72 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
73 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
74 AC_SUBST(SRD_LIB_VERSION_CURRENT)
75 AC_SUBST(SRD_LIB_VERSION_REVISION)
76 AC_SUBST(SRD_LIB_VERSION_AGE)
77 AC_SUBST(SRD_LIB_VERSION)
78 AC_SUBST(SRD_LIB_LDFLAGS)
79
80 # assume we can build tests/runtc unless proven otherwise
81 build_runtc="yes"
82
83 # Checks for libraries.
84
85 # libglib-2.0 is always needed.
86 # Note: glib-2.0 is part of the libsigrokdecode API
87 # (hard pkg-config requirement).
88 AM_PATH_GLIB_2_0([2.24.0],
89         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
90
91 # Python 3 is always needed.
92 # Note: We need to try a few different variants, since some systems have a
93 # python3.pc file, others have a python-3.3.pc file, and so on.
94 # See also: http://sigrok.org/wiki/Libsigrokdecode/Python
95 CPPFLAGS_PYTHON=""
96 LDFLAGS_PYTHON=""
97 PKG_CHECK_MODULES([python3], [python3 >= 3.0],
98         [CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python3_CFLAGS";
99         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python3_LIBS"],
100 [PKG_CHECK_MODULES([python33], [python-3.3 >= 3.0],
101         [CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python33_CFLAGS";
102         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python33_LIBS"],
103 [PKG_CHECK_MODULES([python32], [python-3.2 >= 3.0],
104         [CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python32_CFLAGS";
105         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python32_LIBS"],
106 [PKG_CHECK_MODULES([python31], [python-3.1 >= 3.0],
107         [CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python31_CFLAGS";
108         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python31_LIBS"],
109 [PKG_CHECK_MODULES([python30], [python-3.0 >= 3.0],
110         [CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python30_CFLAGS";
111         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python30_LIBS"],
112 )])])])])
113 case "$build" in
114 *mingw*)
115         # We currently hardcode the paths to the Python 3.2 default install
116         # location as there's no 'python-config' script on Windows, it seems.
117         # Note: We add both the /c/ and c:/ syntax (needed for cmake).
118         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
119         CPPFLAGS_PYTHON="-I/c/Python32/include -Ic:/Python32/include"
120         LDFLAGS_PYTHON="-L/c/Python32/libs -Lc:/Python32/libs -lpython32"
121         ;;
122 esac
123 AC_SUBST(CPPFLAGS_PYTHON)
124 AC_SUBST(LDFLAGS_PYTHON)
125
126 # Link against libm, this is required (among other things) by Python.
127 AC_SEARCH_LIBS([pow], [m])
128
129 # The Check unit testing framework is optional. Disable if not found.
130 PKG_CHECK_MODULES([check], [check >= 0.9.4],
131         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
132         LIBS="$LIBS $check_LIBS"], [have_check="no"])
133 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
134
135 # libsigrok is optional (only used for the protocol decoder test framework).
136 # Disable if not found.
137 PKG_CHECK_MODULES([libsigrok], [libsigrok >= 0.2.0],
138         [LIBSIGROK_CFLAGS="$libsigrok_CFLAGS"; LIBSIGROK_LIBS="$libsigrok_LIBS"],
139         [build_runtc="no"])
140 AC_SUBST([LIBSIGROK_CFLAGS])
141 AC_SUBST([LIBSIGROK_LIBS])
142
143 # Checks for header files.
144 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
145 AC_CHECK_HEADER([sys/resource.h], [], [build_runtc="no"])
146
147 # Checks for typedefs, structures, and compiler characteristics.
148 AC_C_INLINE
149 AC_TYPE_INT8_T
150 AC_TYPE_INT16_T
151 AC_TYPE_INT32_T
152 AC_TYPE_INT64_T
153 AC_TYPE_UINT8_T
154 AC_TYPE_UINT16_T
155 AC_TYPE_UINT32_T
156 AC_TYPE_UINT64_T
157 AC_TYPE_SIZE_T
158
159 # Checks for library functions.
160 AC_CHECK_FUNCS([memset strtoull])
161
162 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
163 AC_SUBST(MAKEFLAGS, '--no-print-directory')
164 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
165
166 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
167 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
168 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
169 SRD_PACKAGE_VERSION=srd_package_version
170
171 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
172 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
173 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
174 AC_SUBST(SRD_PACKAGE_VERSION)
175
176 AM_CONDITIONAL(BUILD_RUNTC, test x"$build_runtc" = "xyes")
177
178 AC_CONFIG_FILES([Makefile
179                  version.h
180                  libsigrokdecode.pc
181                  contrib/Makefile
182                  tests/Makefile
183                 ])
184
185 AC_OUTPUT
186
187 echo
188 echo "libsigrokdecode configuration summary:"
189 echo
190 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
191 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
192 echo "  - Prefix: $prefix"
193 echo "  - Building on: $build"
194 echo "  - Building for: $host"
195 echo "  - Building protocol decoder test framework: $build_runtc"
196 echo
197 echo "Detected libraries:"
198 echo
199
200 # Note: This only works for libs with pkg-config integration.
201 for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4" "libsigrok >= 0.2.0"; do
202         if `$PKG_CONFIG --exists $lib`; then
203                 ver=`$PKG_CONFIG --modversion $lib`
204                 answer="yes ($ver)"
205         else
206                 answer="no"
207         fi
208         echo "  - $lib: $answer"
209 done
210
211 echo
212 echo "Detected Python:"
213 echo
214 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
215 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
216 echo
217