configure.ac

   1 ##
   2 ## This file is part of the libsigrokdecode project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([srd_package_version_major], [0])
  25 m4_define([srd_package_version_minor], [2])
  26 m4_define([srd_package_version_micro], [0])
  27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
  28
  29 AC_INIT([libsigrokdecode], [srd_package_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SRD_CONFIG_H
  42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SRD_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrokdecode (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SRD_LIB_VERSION_CURRENT=1
  70 SRD_LIB_VERSION_REVISION=0
  71 SRD_LIB_VERSION_AGE=0
  72 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
  73 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
  74 AC_SUBST(SRD_LIB_VERSION_CURRENT)
  75 AC_SUBST(SRD_LIB_VERSION_REVISION)
  76 AC_SUBST(SRD_LIB_VERSION_AGE)
  77 AC_SUBST(SRD_LIB_VERSION)
  78 AC_SUBST(SRD_LIB_LDFLAGS)
  79
  80 # assume we can build tests/runtc unless proven otherwise
  81 build_runtc="yes"
  82
  83 # Checks for libraries.
  84
  85 # libglib-2.0 is always needed.
  86 # Note: glib-2.0 is part of the libsigrokdecode API
  87 # (hard pkg-config requirement).
  88 AM_PATH_GLIB_2_0([2.24.0],
  89         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  90
  91 # Python support. We require at least Python >= 3.0.
  92 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
  93 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.3-config python-config-3.3 python3.2-config python-config-3.2 python3.1-config python-config-3.1 python3.0-config python-config-3.0])
  94 CPPFLAGS_PYTHON=""
  95 LDFLAGS_PYTHON=""
  96 case "$build" in
  97 *mingw*)
  98         # We currently hardcode the paths to the Python 3.2 default install
  99         # location as there's no 'python-config' script on Windows, it seems.
 100         # Note: We add both the /c/ and c:/ syntax (needed for cmake).
 101         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
 102         CPPFLAGS_PYTHON="-I/c/Python32/include -Ic:/Python32/include"
 103         LDFLAGS_PYTHON="-L/c/Python32/libs -Lc:/Python32/libs -lpython32"
 104         ;;
 105 *)
 106         # We know that Linux has 'python3-config'.
 107         # On Darwin, Macports has python3.x-config, fink has python3-config.
 108         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
 109         # that's Python 2.x, so not useful for us.
 110         # Everything else is untested, we just hope some $PYTHON3_CONFIG
 111         # (i.e., any of the tools we check for above) is available.
 112         if test -n "$PYTHON3_CONFIG"; then
 113                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
 114                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
 115         else
 116                 AC_MSG_ERROR([python3-config not found])
 117         fi
 118         ;;
 119 esac
 120 AC_SUBST(CPPFLAGS_PYTHON)
 121 AC_SUBST(LDFLAGS_PYTHON)
 122
 123 # The Check unit testing framework is optional. Disable if not found.
 124 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 125         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
 126         LIBS="$LIBS $check_LIBS"], [have_check="no"])
 127 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 128
 129 # Protocol decoder test framework
 130 PKG_CHECK_MODULES([libsigrok], [libsigrok >= 0.2.0],
 131         [LIBSIGROK_CFLAGS="$libsigrok_CFLAGS"; LIBSIGROK_LIBS="$libsigrok_LIBS"],
 132         [build_runtc="no"])
 133 AC_SUBST([LIBSIGROK_CFLAGS])
 134 AC_SUBST([LIBSIGROK_LIBS])
 135
 136 # Checks for header files.
 137 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 138 AC_CHECK_HEADER([sys/resource.h], [], [build_runtc="no"])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AC_C_INLINE
 142 AC_TYPE_INT8_T
 143 AC_TYPE_INT16_T
 144 AC_TYPE_INT32_T
 145 AC_TYPE_INT64_T
 146 AC_TYPE_UINT8_T
 147 AC_TYPE_UINT16_T
 148 AC_TYPE_UINT32_T
 149 AC_TYPE_UINT64_T
 150 AC_TYPE_SIZE_T
 151
 152 # Checks for library functions.
 153 AC_CHECK_FUNCS([memset strtoull])
 154
 155 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 156 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 157 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 158
 159 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
 160 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
 161 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
 162 SRD_PACKAGE_VERSION=srd_package_version
 163
 164 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
 165 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
 166 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
 167 AC_SUBST(SRD_PACKAGE_VERSION)
 168
 169 AM_CONDITIONAL(BUILD_RUNTC, test x"$build_runtc" = "xyes")
 170
 171 AC_CONFIG_FILES([Makefile
 172                  version.h
 173                  libsigrokdecode.pc
 174                  contrib/Makefile
 175                  tests/Makefile
 176                 ])
 177
 178 AC_OUTPUT
 179
 180 echo
 181 echo "libsigrokdecode configuration summary:"
 182 echo
 183 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
 184 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
 185 echo "  - Prefix: $prefix"
 186 echo "  - Building on: $build"
 187 echo "  - Building for: $host"
 188 echo "  - Building protocol decoder test framework: $build_runtc"
 189 echo
 190 echo "Detected libraries:"
 191 echo
 192
 193 # Note: This only works for libs with pkg-config integration.
 194 for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4" "libsigrok >= 0.2.0"; do
 195         if `$PKG_CONFIG --exists $lib`; then
 196                 ver=`$PKG_CONFIG --modversion $lib`
 197                 answer="yes ($ver)"
 198         else
 199                 answer="no"
 200         fi
 201         echo "  - $lib: $answer"
 202 done
 203
 204 echo
 205 echo "Detected Python:"
 206 echo
 207 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
 208 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
 209 echo
 210