configure.ac

   1 ##
   2 ## This file is part of the libsigrokdecode project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 AC_INIT([libsigrokdecode], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  26         [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SRD_CONFIG_H
  37 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 AC_PROG_LN_S
  44
  45 # Required for per-target flags or subdir-objects with C sources.
  46 AM_PROG_CC_C_O
  47
  48 # Initialize libtool.
  49 LT_INIT
  50
  51 # Set up the libsigrokdecode version defines.
  52 SR_PKG_VERSION_SET([SRD_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  53
  54 # Library version for libsigrokdecode (NOT the same as the package version).
  55 # Carefully read the libtool docs before updating these numbers!
  56 # The algorithm for determining which number to change (and how) is nontrivial!
  57 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  58 SR_LIB_VERSION_SET([SRD_LIB_VERSION], [2:0:0])
  59
  60 ############################
  61 ##  Package dependencies  ##
  62 ############################
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Collect the pkg-config module names of all dependencies in SRD_PKGLIBS.
  69 # These are used to derive the compiler flags and for the "Requires.private"
  70 # field in the generated libsigrokdecode.pc file.
  71 SRD_PKGLIBS=
  72 SRD_PKGLIBS_TESTS=
  73
  74 # Keep track of all checked modules so we can list them at the end.
  75 SR_PKG_CHECK_SUMMARY([srd_pkglibs_summary])
  76
  77 # Python 3 is always needed.
  78 SR_PKG_CHECK([python3], [SRD_PKGLIBS],
  79         [python3 >= 3.2], [python-3.4 >= 3.4], [python-3.3 >= 3.3], [python-3.2 >= 3.2])
  80 AS_IF([test "x$sr_have_python3" = xno],
  81         [AC_MSG_ERROR([Cannot find Python 3 development headers.])])
  82
  83 # We also need to find the name of the python3 executable (for 'make install').
  84 # Some OSes call this python3, some call it python3.2, etc. etc.
  85 AC_ARG_VAR([PYTHON3], [Python 3 interpreter])
  86 AC_CHECK_PROGS([PYTHON3], [python3.4 python3.3 python3.2 python3])
  87 AS_IF([test "x$PYTHON3" = x],
  88         [AC_MSG_ERROR([Cannot find Python 3 interpreter.])])
  89
  90 ######################
  91 ##  Feature checks  ##
  92 ######################
  93
  94 # Keep track of all checked modules so we can list them at the end.
  95 SR_PKG_CHECK_SUMMARY([srd_pkglibs_opt_summary])
  96
  97 # The Check unit testing framework is optional. Disable if not found.
  98 SR_PKG_CHECK([check], [SRD_PKGLIBS_TESTS], [check >= 0.9.4])
  99 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 100
 101 # Enable the C99 standard if possible, and enforce the use
 102 # of SRD_API to explicitly mark all public API functions.
 103 SRD_EXTRA_CFLAGS=
 104 SR_CHECK_COMPILE_FLAGS([SRD_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 105 SR_CHECK_COMPILE_FLAGS([SRD_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 106
 107 # Select suitable compiler warning flags.
 108 SR_ARG_ENABLE_WARNINGS([SRD_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 109
 110 # Link against libm, this is required (among other things) by Python.
 111 SRD_EXTRA_LIBS=
 112 SR_SEARCH_LIBS([SRD_EXTRA_LIBS], [pow], [m])
 113
 114 ##############################
 115 ##  Finalize configuration  ##
 116 ##############################
 117
 118 AC_SUBST([SRD_PKGLIBS])
 119
 120 # Retrieve the compile and link flags for all modules combined.
 121 # Also, bail out at this point if any module dependency is not met.
 122 PKG_CHECK_MODULES([LIBSIGROKDECODE], [glib-2.0 >= 2.24.0 $SRD_PKGLIBS])
 123 PKG_CHECK_MODULES([TESTS], [$SRD_PKGLIBS_TESTS glib-2.0 $SRD_PKGLIBS])
 124
 125 srd_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 126
 127 AC_CONFIG_FILES([Makefile libsigrokdecode.pc])
 128
 129 AC_OUTPUT
 130
 131 cat >&AS_MESSAGE_FD <<_EOF
 132
 133 libsigrokdecode configuration summary:
 134  - Package version................. $SRD_PACKAGE_VERSION
 135  - Library ABI version............. $SRD_LIB_VERSION
 136  - Prefix.......................... $prefix
 137  - Building on..................... $build
 138  - Building for.................... $host
 139  - Additional C compiler flags..... $SRD_EXTRA_CFLAGS
 140  - C compiler warnings............. $SRD_WFLAGS
 141
 142 Detected libraries (required):
 143  - glib-2.0 >= 2.24.0.............. $srd_glib_version
 144 $srd_pkglibs_summary
 145 Detected libraries (optional):
 146 $srd_pkglibs_opt_summary
 147 _EOF