ca387107f8e4e0668ea7ce7f12a59d72e6d89348
[libsigrokdecode.git] / configure.ac
1 ##
2 ## This file is part of the libsigrokdecode project.
3 ##
4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
5 ##
6 ## This program is free software: you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation, either version 3 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 # We require at least autoconf 2.63 (AC_INIT format changed there).
21 AC_PREREQ([2.63])
22
23 # libsigrokdecode package version number (NOT the same as shared lib version!).
24 m4_define([srd_package_version_major], [0])
25 m4_define([srd_package_version_minor], [2])
26 m4_define([srd_package_version_micro], [0])
27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
28
29 AC_INIT([libsigrokdecode], [srd_package_version],
30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
31         [http://www.sigrok.org])
32 AC_CONFIG_HEADER([config.h])
33 AC_CONFIG_MACRO_DIR([autostuff])
34 AC_CONFIG_AUX_DIR([autostuff])
35
36 # We require at least automake 1.11 (needed for 'silent rules').
37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
40
41 AH_TOP([#ifndef SRD_CONFIG_H
42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
44
45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
46 # and enforce use of SRD_API to explicitly mark all public API functions.
47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
48
49 # Checks for programs.
50 AC_PROG_CC
51 AC_PROG_CPP
52 AC_PROG_INSTALL
53 AC_PROG_LN_S
54
55 # Required for per-target flags or subdir-objects with C sources.
56 AM_PROG_CC_C_O
57
58 # Initialize libtool.
59 LT_INIT
60
61 # Initialize pkg-config.
62 # We require at least 0.22, as "Requires.private" behaviour changed there.
63 PKG_PROG_PKG_CONFIG([0.22])
64
65 # Library version for libsigrokdecode (NOT the same as the package version).
66 # Carefully read the libtool docs before updating these numbers!
67 # The algorithm for determining which number to change (and how) is nontrivial!
68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
69 SRD_LIB_VERSION_CURRENT=1
70 SRD_LIB_VERSION_REVISION=0
71 SRD_LIB_VERSION_AGE=0
72 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
73 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
74 AC_SUBST(SRD_LIB_VERSION_CURRENT)
75 AC_SUBST(SRD_LIB_VERSION_REVISION)
76 AC_SUBST(SRD_LIB_VERSION_AGE)
77 AC_SUBST(SRD_LIB_VERSION)
78 AC_SUBST(SRD_LIB_LDFLAGS)
79
80 # Checks for libraries.
81
82 # libglib-2.0 is always needed.
83 # Note: glib-2.0 is part of the libsigrokdecode API
84 # (hard pkg-config requirement).
85 AM_PATH_GLIB_2_0([2.24.0],
86         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
87
88 # Python support. We require at least Python >= 3.0.
89 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
90 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.3-config python-config-3.3 python3.2-config python-config-3.2 python3.1-config python-config-3.1 python3.0-config python-config-3.0])
91 CPPFLAGS_PYTHON=""
92 LDFLAGS_PYTHON=""
93 case "$build" in
94 *mingw*)
95         # We currently hardcode the paths to the Python 3.2 default install
96         # location as there's no 'python-config' script on Windows, it seems.
97         # Note: We add both the /c/ and c:/ syntax (needed for cmake).
98         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
99         CPPFLAGS_PYTHON="-I/c/Python32/include -Ic:/Python32/include"
100         LDFLAGS_PYTHON="-L/c/Python32/libs -Lc:/Python32/libs -lpython32"
101         ;;
102 *)
103         # We know that Linux has 'python3-config'.
104         # On Darwin, Macports has python3.x-config, fink has python3-config.
105         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
106         # that's Python 2.x, so not useful for us.
107         # Everything else is untested, we just hope some $PYTHON3_CONFIG
108         # (i.e., any of the tools we check for above) is available.
109         if test -n "$PYTHON3_CONFIG"; then
110                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
111                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
112         else
113                 AC_MSG_ERROR([python3-config not found])
114         fi
115         ;;
116 esac
117 AC_SUBST(CPPFLAGS_PYTHON)
118 AC_SUBST(LDFLAGS_PYTHON)
119
120 # The Check unit testing framework is optional. Disable if not found.
121 PKG_CHECK_MODULES([check], [check >= 0.9.4],
122         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
123         LIBS="$LIBS $check_LIBS"], [have_check="no"])
124 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
125
126 # Checks for header files.
127 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
128 # AC_CHECK_HEADERS([])
129
130 # Checks for typedefs, structures, and compiler characteristics.
131 AC_C_INLINE
132 AC_TYPE_INT8_T
133 AC_TYPE_INT16_T
134 AC_TYPE_INT32_T
135 AC_TYPE_INT64_T
136 AC_TYPE_UINT8_T
137 AC_TYPE_UINT16_T
138 AC_TYPE_UINT32_T
139 AC_TYPE_UINT64_T
140 AC_TYPE_SIZE_T
141
142 # Checks for library functions.
143 AC_CHECK_FUNCS([memset strtoull])
144
145 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
146 AC_SUBST(MAKEFLAGS, '--no-print-directory')
147 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
148
149 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
150 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
151 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
152 SRD_PACKAGE_VERSION=srd_package_version
153
154 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
155 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
156 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
157 AC_SUBST(SRD_PACKAGE_VERSION)
158
159 AC_CONFIG_FILES([Makefile
160                  version.h
161                  libsigrokdecode.pc
162                  contrib/Makefile
163                  tests/Makefile
164                 ])
165
166 AC_OUTPUT
167
168 echo
169 echo "libsigrokdecode configuration summary:"
170 echo
171 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
172 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
173 echo "  - Prefix: $prefix"
174 echo "  - Building on: $build"
175 echo "  - Building for: $host"
176 echo
177 echo "Detected libraries:"
178 echo
179
180 # Note: This only works for libs with pkg-config integration.
181 for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4"; do
182         if `$PKG_CONFIG --exists $lib`; then
183                 ver=`$PKG_CONFIG --modversion $lib`
184                 answer="yes ($ver)"
185         else
186                 answer="no"
187         fi
188         echo "  - $lib: $answer"
189 done
190
191 echo
192 echo "Detected Python:"
193 echo
194 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
195 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
196 echo
197