configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 AC_PREREQ([2.61])
  21
  22 # libsigrokdecode package version number (NOT the same as shared lib version!).
  23 m4_define([libsigrokdecode_major_version], [0])
  24 m4_define([libsigrokdecode_minor_version], [2])
  25 m4_define([libsigrokdecode_micro_version], [0])
  26 m4_define([libsigrokdecode_version],
  27           [libsigrokdecode_major_version.libsigrokdecode_minor_version.libsigrokdecode_micro_version])
  28
  29 AC_INIT([libsigrokdecode], [libsigrokdecode_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 AM_INIT_AUTOMAKE([-Wall -Werror foreign std-options])
  37 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  38
  39 AH_TOP([#ifndef LIBSIGROKDECODE_CONFIG_H
  40 #define LIBSIGROKDECODE_CONFIG_H    /* To stop multiple inclusions. */])
  41 AH_BOTTOM([#endif /* LIBSIGROKDECODE_CONFIG_H */])
  42
  43 CFLAGS="-g -Wall -Wextra"
  44
  45 # Checks for programs.
  46 AC_PROG_CXX
  47 AC_PROG_CC
  48 AC_PROG_CPP
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51
  52 # Initialize libtool.
  53 LT_INIT
  54
  55 # Initialize pkg-config.
  56 # We require at least 0.22, as "Requires.private" behaviour changed there.
  57 PKG_PROG_PKG_CONFIG([0.22])
  58
  59 # Library version for libsigrokdecode (NOT the same as the package version).
  60 # Carefully read the libtool docs before updating these numbers!
  61 # The algorithm for determining which number to change (and how) is nontrivial!
  62 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  63 LIBSIGROKDECODE_LT_CURRENT=0
  64 LIBSIGROKDECODE_LT_REVISION=0
  65 LIBSIGROKDECODE_LT_AGE=0
  66 LIBSIGROKDECODE_LT_VERSION="$LIBSIGROKDECODE_LT_CURRENT:$LIBSIGROKDECODE_LT_REVISION:$LIBSIGROKDECODE_LT_AGE"
  67 LIBSIGROKDECODE_LT_LDFLAGS="-version-info $LIBSIGROKDECODE_LT_VERSION"
  68 AC_SUBST(LIBSIGROKDECODE_LT_LDFLAGS)
  69
  70 # Checks for libraries.
  71
  72 # libglib-2.0 is always needed.
  73 # Note: glib-2.0 is part of the libsigrokdecode API
  74 # (hard pkg-config requirement).
  75 AM_PATH_GLIB_2_0([2.22.0],
  76         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  77
  78 # Python support. We require at least Python >= 3.0.
  79 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
  80 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.2-config python3.1-config python3.0-config])
  81 CPPFLAGS_PYTHON=""
  82 LDFLAGS_PYTHON=""
  83 case "$build" in
  84 *mingw*)
  85         # We currently hardcode the paths to the Python 3.2 default install
  86         # location as there's no 'python-config' script on Windows, it seems.
  87         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
  88         CPPFLAGS_PYTHON="-I/c/Python32/include"
  89         LDFLAGS_PYTHON="-L/c/Python32/libs -lpython32"
  90         ;;
  91 *)
  92         # We know that Linux has 'python3-config'.
  93         # On Darwin, Macports has python3.x-config, fink has python3-config.
  94         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
  95         # that's Python 2.x, so not useful for us.
  96         # Everything else is untested, we just hope 'PYTHON3_CONFIG' works.
  97         if test -n "$PYTHON3_CONFIG"; then
  98                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
  99                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
 100         else
 101                 AC_MSG_ERROR([python3-config not found])
 102         fi
 103         ;;
 104 esac
 105 AC_SUBST(CPPFLAGS_PYTHON)
 106 AC_SUBST(LDFLAGS_PYTHON)
 107
 108 # Checks for header files.
 109 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 110 # AC_CHECK_HEADERS([])
 111
 112 # Checks for typedefs, structures, and compiler characteristics.
 113 AC_C_INLINE
 114 AC_TYPE_INT8_T
 115 AC_TYPE_INT16_T
 116 AC_TYPE_INT32_T
 117 AC_TYPE_INT64_T
 118 AC_TYPE_UINT8_T
 119 AC_TYPE_UINT16_T
 120 AC_TYPE_UINT32_T
 121 AC_TYPE_UINT64_T
 122 AC_TYPE_SIZE_T
 123
 124 # Checks for library functions.
 125 AC_CHECK_FUNCS([memset strtoull])
 126
 127 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 128 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 129 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 130
 131 LIBSIGROKDECODE_MAJOR_VERSION=libsigrokdecode_major_version
 132 LIBSIGROKDECODE_MINOR_VERSION=libsigrokdecode_minor_version
 133 LIBSIGROKDECODE_MICRO_VERSION=libsigrokdecode_micro_version
 134 LIBSIGROKDECODE_VERSION=libsigrokdecode_version
 135
 136 AC_SUBST(LIBSIGROKDECODE_MAJOR_VERSION)
 137 AC_SUBST(LIBSIGROKDECODE_MINOR_VERSION)
 138 AC_SUBST(LIBSIGROKDECODE_MICRO_VERSION)
 139 AC_SUBST(LIBSIGROKDECODE_VERSION)
 140
 141 AC_DEFINE(LIBSIGROKDECODE_MAJOR_VERSION, [libsigrokdecode_major_version],
 142           [Define to the libsigrokdecode major package version])
 143 AC_DEFINE(LIBSIGROKDECODE_MINOR_VERSION, [libsigrokdecode_minor_version],
 144           [Define to the libsigrokdecode minor package version])
 145 AC_DEFINE(LIBSIGROKDECODE_MICRO_VERSION, [libsigrokdecode_micro_version],
 146           [Define to the libsigrokdecode micro package version])
 147 AC_DEFINE(LIBSIGROKDECODE_VERSION, [libsigrokdecode_version],
 148           [Define to the libsigrokdecode package version])
 149
 150 AC_CONFIG_FILES([Makefile
 151                  libsigrokdecode.pc
 152                  decoders/Makefile
 153                 ])
 154
 155 AC_OUTPUT
 156
 157 echo
 158 echo "libsigrokdecode configuration summary:"
 159 echo
 160 echo "  - Package version (major.minor.micro):    $LIBSIGROKDECODE_VERSION"
 161 echo "  - Library version (current:revision:age): $LIBSIGROKDECODE_LT_VERSION"
 162 echo "  - Prefix: $prefix"
 163 echo
 164 echo "Detected libraries:"
 165 echo
 166
 167 # Note: This only works for libs with pkg-config integration.
 168 for lib in "glib-2.0"; do
 169         if `$PKG_CONFIG --exists $lib`; then
 170                 ver=`$PKG_CONFIG --modversion $lib`
 171                 answer="yes ($ver)"
 172         else
 173                 answer="no"
 174         fi
 175         echo "  - $lib: $answer"
 176 done
 177
 178 echo
 179 echo "Detected Python:"
 180 echo
 181 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
 182 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
 183 echo
 184