configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([srd_package_version_major], [0])
  25 m4_define([srd_package_version_minor], [1])
  26 m4_define([srd_package_version_micro], [0])
  27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
  28
  29 AC_INIT([libsigrokdecode], [srd_package_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SRD_CONFIG_H
  42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  44
  45 CFLAGS="-g -Wall -Wextra"
  46
  47 # Checks for programs.
  48 AC_PROG_CXX
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53
  54 # Initialize libtool.
  55 LT_INIT
  56
  57 # Initialize pkg-config.
  58 # We require at least 0.22, as "Requires.private" behaviour changed there.
  59 PKG_PROG_PKG_CONFIG([0.22])
  60
  61 # Library version for libsigrokdecode (NOT the same as the package version).
  62 # Carefully read the libtool docs before updating these numbers!
  63 # The algorithm for determining which number to change (and how) is nontrivial!
  64 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  65 SRD_LIB_VERSION_CURRENT=0
  66 SRD_LIB_VERSION_REVISION=0
  67 SRD_LIB_VERSION_AGE=0
  68 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
  69 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
  70 AC_SUBST(SRD_LIB_VERSION_CURRENT)
  71 AC_SUBST(SRD_LIB_VERSION_REVISION)
  72 AC_SUBST(SRD_LIB_VERSION_AGE)
  73 AC_SUBST(SRD_LIB_VERSION)
  74 AC_SUBST(SRD_LIB_LDFLAGS)
  75
  76 # Checks for libraries.
  77
  78 # libglib-2.0 is always needed.
  79 # Note: glib-2.0 is part of the libsigrokdecode API
  80 # (hard pkg-config requirement).
  81 AM_PATH_GLIB_2_0([2.28.0],
  82         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  83
  84 # Python support. We require at least Python >= 3.0.
  85 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
  86 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.3-config python3.2-config python3.1-config python3.0-config])
  87 CPPFLAGS_PYTHON=""
  88 LDFLAGS_PYTHON=""
  89 case "$build" in
  90 *mingw*)
  91         # We currently hardcode the paths to the Python 3.2 default install
  92         # location as there's no 'python-config' script on Windows, it seems.
  93         # Note: We add both the /c/ and c:/ syntax (needed for cmake).
  94         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
  95         CPPFLAGS_PYTHON="-I/c/Python32/include -Ic:/Python32/include"
  96         LDFLAGS_PYTHON="-L/c/Python32/libs -Lc:/Python32/libs -lpython32"
  97         ;;
  98 *)
  99         # We know that Linux has 'python3-config'.
 100         # On Darwin, Macports has python3.x-config, fink has python3-config.
 101         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
 102         # that's Python 2.x, so not useful for us.
 103         # Everything else is untested, we just hope 'PYTHON3_CONFIG' works.
 104         if test -n "$PYTHON3_CONFIG"; then
 105                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
 106                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
 107         else
 108                 AC_MSG_ERROR([python3-config not found])
 109         fi
 110         ;;
 111 esac
 112 AC_SUBST(CPPFLAGS_PYTHON)
 113 AC_SUBST(LDFLAGS_PYTHON)
 114
 115 # Checks for header files.
 116 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 117 # AC_CHECK_HEADERS([])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_TYPE_INT8_T
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_UINT8_T
 126 AC_TYPE_UINT16_T
 127 AC_TYPE_UINT32_T
 128 AC_TYPE_UINT64_T
 129 AC_TYPE_SIZE_T
 130
 131 # Checks for library functions.
 132 AC_CHECK_FUNCS([memset strtoull])
 133
 134 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 135 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 136 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 137
 138 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
 139 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
 140 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
 141 SRD_PACKAGE_VERSION=srd_package_version
 142
 143 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
 144 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
 145 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
 146 AC_SUBST(SRD_PACKAGE_VERSION)
 147
 148 AC_CONFIG_FILES([Makefile
 149                  sigrokdecode.h
 150                  libsigrokdecode.pc
 151                  decoders/Makefile
 152                  decoders/avr_isp/Makefile
 153                  decoders/can/Makefile
 154                  decoders/dcf77/Makefile
 155                  decoders/edid/Makefile
 156                  decoders/i2c/Makefile
 157                  decoders/i2cdemux/Makefile
 158                  decoders/i2cfilter/Makefile
 159                  decoders/i2s/Makefile
 160                  decoders/jtag/Makefile
 161                  decoders/jtag_stm32/Makefile
 162                  decoders/lm75/Makefile
 163                  decoders/lpc/Makefile
 164                  decoders/maxim_ds28ea00/Makefile
 165                  decoders/mlx90614/Makefile
 166                  decoders/mx25lxx05d/Makefile
 167                  decoders/mxc6225xu/Makefile
 168                  decoders/nunchuk/Makefile
 169                  decoders/onewire_link/Makefile
 170                  decoders/onewire_network/Makefile
 171                  decoders/pan1321/Makefile
 172                  decoders/rtc8564/Makefile
 173                  decoders/sdcard_spi/Makefile
 174                  decoders/spi/Makefile
 175                  decoders/tlc5620/Makefile
 176                  decoders/transitioncounter/Makefile
 177                  decoders/uart/Makefile
 178                  decoders/uart_dump/Makefile
 179                  decoders/usb_protocol/Makefile
 180                  decoders/usb_signalling/Makefile
 181                 ])
 182
 183 AC_OUTPUT
 184
 185 echo
 186 echo "libsigrokdecode configuration summary:"
 187 echo
 188 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
 189 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
 190 echo "  - Prefix: $prefix"
 191 echo
 192 echo "Detected libraries:"
 193 echo
 194
 195 # Note: This only works for libs with pkg-config integration.
 196 for lib in "glib-2.0"; do
 197         if `$PKG_CONFIG --exists $lib`; then
 198                 ver=`$PKG_CONFIG --modversion $lib`
 199                 answer="yes ($ver)"
 200         else
 201                 answer="no"
 202         fi
 203         echo "  - $lib: $answer"
 204 done
 205
 206 echo
 207 echo "Detected Python:"
 208 echo
 209 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
 210 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
 211 echo
 212