76f71031bd2e1ef8c63b03731c198c0f9dcc7fe9
[libsigrokdecode.git] / configure.ac
1 ##
2 ## This file is part of the sigrok project.
3 ##
4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
5 ##
6 ## This program is free software: you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation, either version 3 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 # We require at least autoconf 2.63 (AC_INIT format changed there).
21 AC_PREREQ([2.63])
22
23 # libsigrokdecode package version number (NOT the same as shared lib version!).
24 m4_define([srd_package_version_major], [0])
25 m4_define([srd_package_version_minor], [1])
26 m4_define([srd_package_version_micro], [0])
27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
28
29 AC_INIT([libsigrokdecode], [srd_package_version],
30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
31         [http://www.sigrok.org])
32 AC_CONFIG_HEADER([config.h])
33 AC_CONFIG_MACRO_DIR([autostuff])
34 AC_CONFIG_AUX_DIR([autostuff])
35
36 # We require at least automake 1.11 (needed for 'silent rules').
37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
40
41 AH_TOP([#ifndef SRD_CONFIG_H
42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
44
45 CFLAGS="-g -Wall -Wextra"
46
47 # Checks for programs.
48 AC_PROG_CXX
49 AC_PROG_CC
50 AC_PROG_CPP
51 AC_PROG_INSTALL
52 AC_PROG_LN_S
53
54 # Initialize libtool.
55 LT_INIT
56
57 # Initialize pkg-config.
58 # We require at least 0.22, as "Requires.private" behaviour changed there.
59 PKG_PROG_PKG_CONFIG([0.22])
60
61 # Library version for libsigrokdecode (NOT the same as the package version).
62 # Carefully read the libtool docs before updating these numbers!
63 # The algorithm for determining which number to change (and how) is nontrivial!
64 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
65 SRD_LIB_VERSION_CURRENT=0
66 SRD_LIB_VERSION_REVISION=0
67 SRD_LIB_VERSION_AGE=0
68 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
69 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
70 AC_SUBST(SRD_LIB_VERSION_CURRENT)
71 AC_SUBST(SRD_LIB_VERSION_REVISION)
72 AC_SUBST(SRD_LIB_VERSION_AGE)
73 AC_SUBST(SRD_LIB_VERSION)
74 AC_SUBST(SRD_LIB_LDFLAGS)
75
76 # Checks for libraries.
77
78 # libglib-2.0 is always needed.
79 # Note: glib-2.0 is part of the libsigrokdecode API
80 # (hard pkg-config requirement).
81 AM_PATH_GLIB_2_0([2.28.0],
82         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
83
84 # Python support. We require at least Python >= 3.0.
85 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
86 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.2-config python3.1-config python3.0-config])
87 CPPFLAGS_PYTHON=""
88 LDFLAGS_PYTHON=""
89 case "$build" in
90 *mingw*)
91         # We currently hardcode the paths to the Python 3.2 default install
92         # location as there's no 'python-config' script on Windows, it seems.
93         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
94         CPPFLAGS_PYTHON="-I/c/Python32/include"
95         LDFLAGS_PYTHON="-L/c/Python32/libs -lpython32"
96         ;;
97 *)
98         # We know that Linux has 'python3-config'.
99         # On Darwin, Macports has python3.x-config, fink has python3-config.
100         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
101         # that's Python 2.x, so not useful for us.
102         # Everything else is untested, we just hope 'PYTHON3_CONFIG' works.
103         if test -n "$PYTHON3_CONFIG"; then
104                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
105                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
106         else
107                 AC_MSG_ERROR([python3-config not found])
108         fi
109         ;;
110 esac
111 AC_SUBST(CPPFLAGS_PYTHON)
112 AC_SUBST(LDFLAGS_PYTHON)
113
114 # Checks for header files.
115 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
116 # AC_CHECK_HEADERS([])
117
118 # Checks for typedefs, structures, and compiler characteristics.
119 AC_C_INLINE
120 AC_TYPE_INT8_T
121 AC_TYPE_INT16_T
122 AC_TYPE_INT32_T
123 AC_TYPE_INT64_T
124 AC_TYPE_UINT8_T
125 AC_TYPE_UINT16_T
126 AC_TYPE_UINT32_T
127 AC_TYPE_UINT64_T
128 AC_TYPE_SIZE_T
129
130 # Checks for library functions.
131 AC_CHECK_FUNCS([memset strtoull])
132
133 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
134 AC_SUBST(MAKEFLAGS, '--no-print-directory')
135 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
136
137 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
138 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
139 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
140 SRD_PACKAGE_VERSION=srd_package_version
141
142 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
143 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
144 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
145 AC_SUBST(SRD_PACKAGE_VERSION)
146
147 AC_CONFIG_FILES([Makefile
148                  sigrokdecode.h
149                  libsigrokdecode.pc
150                  decoders/Makefile
151                  decoders/dcf77/Makefile
152                  decoders/edid/Makefile
153                  decoders/i2c/Makefile
154                  decoders/i2cdemux/Makefile
155                  decoders/i2cfilter/Makefile
156                  decoders/i2s/Makefile
157                  decoders/jtag/Makefile
158                  decoders/jtag_stm32/Makefile
159                  decoders/lm75/Makefile
160                  decoders/lpc/Makefile
161                  decoders/mlx90614/Makefile
162                  decoders/mx25lxx05d/Makefile
163                  decoders/mxc6225xu/Makefile
164                  decoders/nunchuk/Makefile
165                  decoders/pan1321/Makefile
166                  decoders/rtc8564/Makefile
167                  decoders/spi/Makefile
168                  decoders/transitioncounter/Makefile
169                  decoders/uart/Makefile
170                  decoders/uart_dump/Makefile
171                  decoders/usb_signalling/Makefile
172                  decoders/usb_protocol/Makefile
173                  decoders/onewire_link/Makefile
174                  decoders/onewire_network/Makefile
175                  decoders/onewire_transport/Makefile
176                 ])
177
178 AC_OUTPUT
179
180 echo
181 echo "libsigrokdecode configuration summary:"
182 echo
183 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
184 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
185 echo "  - Prefix: $prefix"
186 echo
187 echo "Detected libraries:"
188 echo
189
190 # Note: This only works for libs with pkg-config integration.
191 for lib in "glib-2.0"; do
192         if `$PKG_CONFIG --exists $lib`; then
193                 ver=`$PKG_CONFIG --modversion $lib`
194                 answer="yes ($ver)"
195         else
196                 answer="no"
197         fi
198         echo "  - $lib: $answer"
199 done
200
201 echo
202 echo "Detected Python:"
203 echo
204 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
205 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
206 echo
207