configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([srd_package_version_major], [0])
  25 m4_define([srd_package_version_minor], [1])
  26 m4_define([srd_package_version_micro], [0])
  27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
  28
  29 AC_INIT([libsigrokdecode], [srd_package_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39
  40 AH_TOP([#ifndef SRD_CONFIG_H
  41 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  42 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  43
  44 CFLAGS="-g -Wall -Wextra"
  45
  46 # Checks for programs.
  47 AC_PROG_CXX
  48 AC_PROG_CC
  49 AC_PROG_CPP
  50 AC_PROG_INSTALL
  51 AC_PROG_LN_S
  52
  53 # Initialize libtool.
  54 LT_INIT
  55
  56 # Initialize pkg-config.
  57 # We require at least 0.22, as "Requires.private" behaviour changed there.
  58 PKG_PROG_PKG_CONFIG([0.22])
  59
  60 # Library version for libsigrokdecode (NOT the same as the package version).
  61 # Carefully read the libtool docs before updating these numbers!
  62 # The algorithm for determining which number to change (and how) is nontrivial!
  63 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  64 SRD_LIB_VERSION_CURRENT=0
  65 SRD_LIB_VERSION_REVISION=0
  66 SRD_LIB_VERSION_AGE=0
  67 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
  68 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
  69 AC_SUBST(SRD_LIB_VERSION_CURRENT)
  70 AC_SUBST(SRD_LIB_VERSION_REVISION)
  71 AC_SUBST(SRD_LIB_VERSION_AGE)
  72 AC_SUBST(SRD_LIB_VERSION)
  73 AC_SUBST(SRD_LIB_LDFLAGS)
  74
  75 # Checks for libraries.
  76
  77 # libglib-2.0 is always needed.
  78 # Note: glib-2.0 is part of the libsigrokdecode API
  79 # (hard pkg-config requirement).
  80 AM_PATH_GLIB_2_0([2.22.0],
  81         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  82
  83 # Python support. We require at least Python >= 3.0.
  84 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
  85 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.2-config python3.1-config python3.0-config])
  86 CPPFLAGS_PYTHON=""
  87 LDFLAGS_PYTHON=""
  88 case "$build" in
  89 *mingw*)
  90         # We currently hardcode the paths to the Python 3.2 default install
  91         # location as there's no 'python-config' script on Windows, it seems.
  92         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
  93         CPPFLAGS_PYTHON="-I/c/Python32/include"
  94         LDFLAGS_PYTHON="-L/c/Python32/libs -lpython32"
  95         ;;
  96 *)
  97         # We know that Linux has 'python3-config'.
  98         # On Darwin, Macports has python3.x-config, fink has python3-config.
  99         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
 100         # that's Python 2.x, so not useful for us.
 101         # Everything else is untested, we just hope 'PYTHON3_CONFIG' works.
 102         if test -n "$PYTHON3_CONFIG"; then
 103                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
 104                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
 105         else
 106                 AC_MSG_ERROR([python3-config not found])
 107         fi
 108         ;;
 109 esac
 110 AC_SUBST(CPPFLAGS_PYTHON)
 111 AC_SUBST(LDFLAGS_PYTHON)
 112
 113 # Checks for header files.
 114 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 115 # AC_CHECK_HEADERS([])
 116
 117 # Checks for typedefs, structures, and compiler characteristics.
 118 AC_C_INLINE
 119 AC_TYPE_INT8_T
 120 AC_TYPE_INT16_T
 121 AC_TYPE_INT32_T
 122 AC_TYPE_INT64_T
 123 AC_TYPE_UINT8_T
 124 AC_TYPE_UINT16_T
 125 AC_TYPE_UINT32_T
 126 AC_TYPE_UINT64_T
 127 AC_TYPE_SIZE_T
 128
 129 # Checks for library functions.
 130 AC_CHECK_FUNCS([memset strtoull])
 131
 132 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 133 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 134 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 135
 136 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
 137 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
 138 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
 139 SRD_PACKAGE_VERSION=srd_package_version
 140
 141 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
 142 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
 143 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
 144 AC_SUBST(SRD_PACKAGE_VERSION)
 145
 146 AC_CONFIG_FILES([Makefile
 147                  sigrokdecode.h
 148                  libsigrokdecode.pc
 149                  decoders/Makefile
 150                  decoders/dcf77/Makefile
 151                  decoders/edid/Makefile
 152                  decoders/i2c/Makefile
 153                  decoders/i2cdemux/Makefile
 154                  decoders/i2cfilter/Makefile
 155                  decoders/mlx90614/Makefile
 156                  decoders/mx25lxx05d/Makefile
 157                  decoders/pan1321/Makefile
 158                  decoders/rtc8564/Makefile
 159                  decoders/spi/Makefile
 160                  decoders/transitioncounter/Makefile
 161                  decoders/uart/Makefile
 162                  decoders/usb/Makefile
 163                 ])
 164
 165 AC_OUTPUT
 166
 167 echo
 168 echo "libsigrokdecode configuration summary:"
 169 echo
 170 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
 171 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
 172 echo "  - Prefix: $prefix"
 173 echo
 174 echo "Detected libraries:"
 175 echo
 176
 177 # Note: This only works for libs with pkg-config integration.
 178 for lib in "glib-2.0"; do
 179         if `$PKG_CONFIG --exists $lib`; then
 180                 ver=`$PKG_CONFIG --modversion $lib`
 181                 answer="yes ($ver)"
 182         else
 183                 answer="no"
 184         fi
 185         echo "  - $lib: $answer"
 186 done
 187
 188 echo
 189 echo "Detected Python:"
 190 echo
 191 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
 192 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
 193 echo
 194