configure.ac

   1 ##
   2 ## This file is part of the libsigrokdecode project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([srd_package_version_major], [0])
  25 m4_define([srd_package_version_minor], [3])
  26 m4_define([srd_package_version_micro], [0])
  27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
  28
  29 AC_INIT([libsigrokdecode], [srd_package_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SRD_CONFIG_H
  42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SRD_API to explicitly mark all public API functions.
  47 AM_CFLAGS="$AM_CFLAGS -Wall -Wextra -Wmissing-prototypes -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrokdecode (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SRD_LIB_VERSION_CURRENT=2
  70 SRD_LIB_VERSION_REVISION=0
  71 SRD_LIB_VERSION_AGE=0
  72 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
  73 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
  74 AC_SUBST(SRD_LIB_VERSION_CURRENT)
  75 AC_SUBST(SRD_LIB_VERSION_REVISION)
  76 AC_SUBST(SRD_LIB_VERSION_AGE)
  77 AC_SUBST(SRD_LIB_VERSION)
  78 AC_SUBST(SRD_LIB_LDFLAGS)
  79
  80 # Checks for libraries.
  81
  82 # libglib-2.0 is always needed.
  83 # Note: glib-2.0 is part of the libsigrokdecode API
  84 # (hard pkg-config requirement).
  85 AM_PATH_GLIB_2_0([2.24.0],
  86         [AM_CFLAGS="$AM_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  87
  88 # Python 3 is always needed.
  89 # Note: We need to try a few different variants, since some systems have a
  90 # python3.pc file, others have a python-3.3.pc file, and so on.
  91 # We also export the name of the package so that it can be correctly
  92 # added to libsigrokdecode.pc.
  93 # See also: http://sigrok.org/wiki/Libsigrokdecode/Python
  94 CPPFLAGS_PYTHON=""
  95 LDFLAGS_PYTHON=""
  96 pyver="none"
  97 PKG_CHECK_MODULES([python3], [python3 >= 3.2],
  98         [pyver=`$PKG_CONFIG --modversion python3`;
  99         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python3_CFLAGS";
 100         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python3_LIBS";
 101         MODNAME_PYTHON="python3"],
 102 [PKG_CHECK_MODULES([python34], [python-3.4 >= 3.4],
 103         [pyver=`$PKG_CONFIG --modversion python-3.4`;
 104         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python34_CFLAGS";
 105         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python34_LIBS";
 106         MODNAME_PYTHON="python-3.4"],
 107 [PKG_CHECK_MODULES([python33], [python-3.3 >= 3.3],
 108         [pyver=`$PKG_CONFIG --modversion python-3.3`;
 109         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python33_CFLAGS";
 110         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python33_LIBS";
 111         MODNAME_PYTHON="python-3.3"],
 112 [PKG_CHECK_MODULES([python32], [python-3.2 >= 3.2],
 113         [pyver=`$PKG_CONFIG --modversion python-3.2`;
 114         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python32_CFLAGS";
 115         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python32_LIBS";
 116         MODNAME_PYTHON="python-3.2"],
 117 )])])])
 118 AC_SUBST(CPPFLAGS_PYTHON)
 119 AC_SUBST(LDFLAGS_PYTHON)
 120 AC_SUBST(MODNAME_PYTHON)
 121
 122 # We also need to find the name of the python3 executable (for 'make install').
 123 # Some OSes call this python3, some call it python3.2, etc. etc.
 124 AC_CHECK_PROGS([PYTHON3], [python3.4 python3.3 python3.2 python3])
 125 if test "x$PYTHON3" = "x"; then
 126         AC_MSG_ERROR([cannot find python3 executable.])
 127 fi
 128
 129 # Link against libm, this is required (among other things) by Python.
 130 AC_SEARCH_LIBS([pow], [m])
 131
 132 # The Check unit testing framework is optional. Disable if not found.
 133 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 134         [have_check="yes"], [have_check="no"])
 135 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 136
 137 # Checks for header files.
 138 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 139
 140 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 141 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 142 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 143
 144 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
 145 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
 146 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
 147 SRD_PACKAGE_VERSION=srd_package_version
 148
 149 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
 150 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
 151 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
 152 AC_SUBST(SRD_PACKAGE_VERSION)
 153
 154 AC_SUBST(AM_CFLAGS)
 155
 156 AC_CONFIG_FILES([Makefile version.h libsigrokdecode.pc])
 157
 158 AC_OUTPUT
 159
 160 echo
 161 echo "libsigrokdecode configuration summary:"
 162 echo
 163 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
 164 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
 165 echo "  - Prefix: $prefix"
 166 echo "  - Building on: $build"
 167 echo "  - Building for: $host"
 168 echo
 169 echo "Detected libraries:"
 170 echo
 171
 172 if test "x$pyver" = "xnone"; then
 173         echo "  - (REQUIRED) python >= 3.2: no"
 174 else
 175         echo "  - (REQUIRED) python >= 3.2: yes ($pyver)"
 176 fi
 177
 178 # Note: This only works for libs with pkg-config integration.
 179 for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4"; do
 180         optional="OPTIONAL"
 181         if test "x$lib" = "xglib-2.0 >= 2.24.0"; then optional="REQUIRED"; fi
 182         if `$PKG_CONFIG --exists $lib`; then
 183                 ver=`$PKG_CONFIG --modversion $lib`
 184                 answer="yes ($ver)"
 185         else
 186                 answer="no"
 187         fi
 188         echo "  - ($optional) $lib: $answer"
 189 done
 190
 191 echo
 192 echo "Enabled features:"
 193 echo
 194 echo "  - (OPTIONAL) Library unit test framework support: $have_check"
 195 echo
 196