configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([libsigrokdecode_major_version], [0])
  25 m4_define([libsigrokdecode_minor_version], [2])
  26 m4_define([libsigrokdecode_micro_version], [0])
  27 m4_define([libsigrokdecode_version],
  28           [libsigrokdecode_major_version.libsigrokdecode_minor_version.libsigrokdecode_micro_version])
  29
  30 AC_INIT([libsigrokdecode], [libsigrokdecode_version],
  31         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  32         [http://www.sigrok.org])
  33 AC_CONFIG_HEADER([config.h])
  34 AC_CONFIG_MACRO_DIR([autostuff])
  35 AC_CONFIG_AUX_DIR([autostuff])
  36
  37 # We require at least automake 1.11 (needed for 'silent rules').
  38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40
  41 AH_TOP([#ifndef LIBSIGROKDECODE_CONFIG_H
  42 #define LIBSIGROKDECODE_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* LIBSIGROKDECODE_CONFIG_H */])
  44
  45 CFLAGS="-g -Wall -Wextra"
  46
  47 # Checks for programs.
  48 AC_PROG_CXX
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53
  54 # Initialize libtool.
  55 LT_INIT
  56
  57 # Initialize pkg-config.
  58 # We require at least 0.22, as "Requires.private" behaviour changed there.
  59 PKG_PROG_PKG_CONFIG([0.22])
  60
  61 # Library version for libsigrokdecode (NOT the same as the package version).
  62 # Carefully read the libtool docs before updating these numbers!
  63 # The algorithm for determining which number to change (and how) is nontrivial!
  64 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  65 LIBSIGROKDECODE_LT_CURRENT=0
  66 LIBSIGROKDECODE_LT_REVISION=0
  67 LIBSIGROKDECODE_LT_AGE=0
  68 LIBSIGROKDECODE_LT_VERSION="$LIBSIGROKDECODE_LT_CURRENT:$LIBSIGROKDECODE_LT_REVISION:$LIBSIGROKDECODE_LT_AGE"
  69 LIBSIGROKDECODE_LT_LDFLAGS="-version-info $LIBSIGROKDECODE_LT_VERSION"
  70 AC_SUBST(LIBSIGROKDECODE_LT_LDFLAGS)
  71
  72 # Checks for libraries.
  73
  74 # libglib-2.0 is always needed.
  75 # Note: glib-2.0 is part of the libsigrokdecode API
  76 # (hard pkg-config requirement).
  77 AM_PATH_GLIB_2_0([2.22.0],
  78         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  79
  80 # Python support. We require at least Python >= 3.0.
  81 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
  82 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.2-config python3.1-config python3.0-config])
  83 CPPFLAGS_PYTHON=""
  84 LDFLAGS_PYTHON=""
  85 case "$build" in
  86 *mingw*)
  87         # We currently hardcode the paths to the Python 3.2 default install
  88         # location as there's no 'python-config' script on Windows, it seems.
  89         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
  90         CPPFLAGS_PYTHON="-I/c/Python32/include"
  91         LDFLAGS_PYTHON="-L/c/Python32/libs -lpython32"
  92         ;;
  93 *)
  94         # We know that Linux has 'python3-config'.
  95         # On Darwin, Macports has python3.x-config, fink has python3-config.
  96         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
  97         # that's Python 2.x, so not useful for us.
  98         # Everything else is untested, we just hope 'PYTHON3_CONFIG' works.
  99         if test -n "$PYTHON3_CONFIG"; then
 100                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
 101                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
 102         else
 103                 AC_MSG_ERROR([python3-config not found])
 104         fi
 105         ;;
 106 esac
 107 AC_SUBST(CPPFLAGS_PYTHON)
 108 AC_SUBST(LDFLAGS_PYTHON)
 109
 110 # Checks for header files.
 111 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 112 # AC_CHECK_HEADERS([])
 113
 114 # Checks for typedefs, structures, and compiler characteristics.
 115 AC_C_INLINE
 116 AC_TYPE_INT8_T
 117 AC_TYPE_INT16_T
 118 AC_TYPE_INT32_T
 119 AC_TYPE_INT64_T
 120 AC_TYPE_UINT8_T
 121 AC_TYPE_UINT16_T
 122 AC_TYPE_UINT32_T
 123 AC_TYPE_UINT64_T
 124 AC_TYPE_SIZE_T
 125
 126 # Checks for library functions.
 127 AC_CHECK_FUNCS([memset strtoull])
 128
 129 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 130 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 131 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 132
 133 LIBSIGROKDECODE_MAJOR_VERSION=libsigrokdecode_major_version
 134 LIBSIGROKDECODE_MINOR_VERSION=libsigrokdecode_minor_version
 135 LIBSIGROKDECODE_MICRO_VERSION=libsigrokdecode_micro_version
 136 LIBSIGROKDECODE_VERSION=libsigrokdecode_version
 137
 138 AC_SUBST(LIBSIGROKDECODE_MAJOR_VERSION)
 139 AC_SUBST(LIBSIGROKDECODE_MINOR_VERSION)
 140 AC_SUBST(LIBSIGROKDECODE_MICRO_VERSION)
 141 AC_SUBST(LIBSIGROKDECODE_VERSION)
 142
 143 AC_DEFINE(LIBSIGROKDECODE_MAJOR_VERSION, [libsigrokdecode_major_version],
 144           [Define to the libsigrokdecode major package version])
 145 AC_DEFINE(LIBSIGROKDECODE_MINOR_VERSION, [libsigrokdecode_minor_version],
 146           [Define to the libsigrokdecode minor package version])
 147 AC_DEFINE(LIBSIGROKDECODE_MICRO_VERSION, [libsigrokdecode_micro_version],
 148           [Define to the libsigrokdecode micro package version])
 149 AC_DEFINE(LIBSIGROKDECODE_VERSION, [libsigrokdecode_version],
 150           [Define to the libsigrokdecode package version])
 151
 152 AC_CONFIG_FILES([Makefile
 153                  libsigrokdecode.pc
 154                  decoders/Makefile
 155                  decoders/dcf77/Makefile
 156                  decoders/ebr30a_i2c_demux/Makefile
 157                  decoders/edid/Makefile
 158                  decoders/i2c/Makefile
 159                  decoders/i2cdemux/Makefile
 160                  decoders/i2cfilter/Makefile
 161                  decoders/mlx90614/Makefile
 162                  decoders/mx25lxx05d/Makefile
 163                  decoders/nunchuk/Makefile
 164                  decoders/pan1321/Makefile
 165                  decoders/rtc8564/Makefile
 166                  decoders/spi/Makefile
 167                  decoders/transitioncounter/Makefile
 168                  decoders/uart/Makefile
 169                  decoders/usb/Makefile
 170                 ])
 171
 172 AC_OUTPUT
 173
 174 echo
 175 echo "libsigrokdecode configuration summary:"
 176 echo
 177 echo "  - Package version (major.minor.micro):    $LIBSIGROKDECODE_VERSION"
 178 echo "  - Library version (current:revision:age): $LIBSIGROKDECODE_LT_VERSION"
 179 echo "  - Prefix: $prefix"
 180 echo
 181 echo "Detected libraries:"
 182 echo
 183
 184 # Note: This only works for libs with pkg-config integration.
 185 for lib in "glib-2.0"; do
 186         if `$PKG_CONFIG --exists $lib`; then
 187                 ver=`$PKG_CONFIG --modversion $lib`
 188                 answer="yes ($ver)"
 189         else
 190                 answer="no"
 191         fi
 192         echo "  - $lib: $answer"
 193 done
 194
 195 echo
 196 echo "Detected Python:"
 197 echo
 198 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
 199 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
 200 echo
 201