configure.ac

   1 ##
   2 ## This file is part of the libsigrokdecode project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrokdecode package version number (NOT the same as shared lib version!).
  24 m4_define([srd_package_version_major], [0])
  25 m4_define([srd_package_version_minor], [3])
  26 m4_define([srd_package_version_micro], [0])
  27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
  28
  29 AC_INIT([libsigrokdecode], [srd_package_version],
  30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
  31         [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SRD_CONFIG_H
  42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SRD_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -Wmissing-prototypes -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrokdecode (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SRD_LIB_VERSION_CURRENT=2
  70 SRD_LIB_VERSION_REVISION=0
  71 SRD_LIB_VERSION_AGE=0
  72 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
  73 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
  74 AC_SUBST(SRD_LIB_VERSION_CURRENT)
  75 AC_SUBST(SRD_LIB_VERSION_REVISION)
  76 AC_SUBST(SRD_LIB_VERSION_AGE)
  77 AC_SUBST(SRD_LIB_VERSION)
  78 AC_SUBST(SRD_LIB_LDFLAGS)
  79
  80 # Assume we can build tests/runtc unless proven otherwise.
  81 build_runtc="yes"
  82
  83 # Checks for libraries.
  84
  85 # libglib-2.0 is always needed.
  86 # Note: glib-2.0 is part of the libsigrokdecode API
  87 # (hard pkg-config requirement).
  88 AM_PATH_GLIB_2_0([2.24.0],
  89         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
  90
  91 # Python 3 is always needed.
  92 # Note: We need to try a few different variants, since some systems have a
  93 # python3.pc file, others have a python-3.3.pc file, and so on.
  94 # We also export the name of the package so that it can be correctly
  95 # added to libsigrokdecode.pc.
  96 # See also: http://sigrok.org/wiki/Libsigrokdecode/Python
  97 CPPFLAGS_PYTHON=""
  98 LDFLAGS_PYTHON=""
  99 pyver="none"
 100 PKG_CHECK_MODULES([python3], [python3 >= 3.2],
 101         [pyver=`$PKG_CONFIG --modversion python3`;
 102         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python3_CFLAGS";
 103         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python3_LIBS";
 104         MODNAME_PYTHON="python3"],
 105 [PKG_CHECK_MODULES([python34], [python-3.4 >= 3.4],
 106         [pyver=`$PKG_CONFIG --modversion python-3.4`;
 107         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python34_CFLAGS";
 108         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python34_LIBS";
 109         MODNAME_PYTHON="python-3.4"],
 110 [PKG_CHECK_MODULES([python33], [python-3.3 >= 3.3],
 111         [pyver=`$PKG_CONFIG --modversion python-3.3`;
 112         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python33_CFLAGS";
 113         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python33_LIBS";
 114         MODNAME_PYTHON="python-3.3"],
 115 [PKG_CHECK_MODULES([python32], [python-3.2 >= 3.2],
 116         [pyver=`$PKG_CONFIG --modversion python-3.2`;
 117         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python32_CFLAGS";
 118         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python32_LIBS";
 119         MODNAME_PYTHON="python-3.2"],
 120 )])])])
 121 AC_SUBST(CPPFLAGS_PYTHON)
 122 AC_SUBST(LDFLAGS_PYTHON)
 123 AC_SUBST(MODNAME_PYTHON)
 124
 125 # We also need to find the name of the python3 executable (for 'make install').
 126 # Some OSes call this python3, some call it python3.2, etc. etc.
 127 AC_CHECK_PROGS([PYTHON3], [python3.4 python3.3 python3.2 python3])
 128 if test "x$PYTHON3" = "x"; then
 129         AC_MSG_ERROR([cannot find python3 executable.])
 130 fi
 131
 132 # Link against libm, this is required (among other things) by Python.
 133 AC_SEARCH_LIBS([pow], [m])
 134
 135 # The Check unit testing framework is optional. Disable if not found.
 136 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 137         [have_check="yes"], [have_check="no"])
 138 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 139
 140 # libsigrok is optional (only used for the protocol decoder test framework).
 141 # Disable if not found.
 142 PKG_CHECK_MODULES([libsigrok], [libsigrok >= 0.3.0],
 143         [LIBSIGROK_CFLAGS="$libsigrok_CFLAGS"; LIBSIGROK_LIBS="$libsigrok_LIBS"],
 144         [build_runtc="no"])
 145 AC_SUBST([LIBSIGROK_CFLAGS])
 146 AC_SUBST([LIBSIGROK_LIBS])
 147
 148 # Checks for header files.
 149 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 150 AC_CHECK_HEADER([sys/resource.h], [], [build_runtc="no"])
 151
 152 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
 153 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 154 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 155
 156 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
 157 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
 158 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
 159 SRD_PACKAGE_VERSION=srd_package_version
 160
 161 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
 162 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
 163 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
 164 AC_SUBST(SRD_PACKAGE_VERSION)
 165
 166 AM_CONDITIONAL(BUILD_RUNTC, test x"$build_runtc" = "xyes")
 167
 168 AC_CONFIG_FILES([Makefile version.h libsigrokdecode.pc])
 169
 170 AC_OUTPUT
 171
 172 echo
 173 echo "libsigrokdecode configuration summary:"
 174 echo
 175 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
 176 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
 177 echo "  - Prefix: $prefix"
 178 echo "  - Building on: $build"
 179 echo "  - Building for: $host"
 180 echo
 181 echo "Detected libraries:"
 182 echo
 183
 184 if test "x$pyver" = "xnone"; then
 185         echo "  - (REQUIRED) python >= 3.2: no"
 186 else
 187         echo "  - (REQUIRED) python >= 3.2: yes ($pyver)"
 188 fi
 189
 190 # Note: This only works for libs with pkg-config integration.
 191 for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4" "libsigrok >= 0.3.0"; do
 192         optional="OPTIONAL"
 193         if test "x$lib" = "xglib-2.0 >= 2.24.0"; then optional="REQUIRED"; fi
 194         if `$PKG_CONFIG --exists $lib`; then
 195                 ver=`$PKG_CONFIG --modversion $lib`
 196                 answer="yes ($ver)"
 197         else
 198                 answer="no"
 199         fi
 200         echo "  - ($optional) $lib: $answer"
 201 done
 202
 203 echo
 204 echo "Enabled features:"
 205 echo
 206 echo "  - (OPTIONAL) Library unit test framework support: $have_check"
 207 echo "  - (OPTIONAL) Protocol decoder test framework support: $build_runtc"
 208 echo
 209