X-Git-Url: https://sigrok.org/gitweb/?p=libsigrok.git;a=blobdiff_plain;f=configure.ac;h=56c097fa6af6461fb8ade901a5034b66bb7f0a62;hp=ff9c93958177b3580b8b326d7ead27b86261c456;hb=47bbc4b531eb8e491115b0dbcb686d23c78235fb;hpb=bd7b83cf631d515ae7e9560400cef2d9f662299a

diff --git a/configure.ac b/configure.ac
index ff9c9395..56c097fa 100644
--- a/configure.ac
+++ b/configure.ac
@@ -21,37 +21,22 @@
 # We require at least autoconf 2.63 (AC_INIT format changed there).
 AC_PREREQ([2.63])
 
-# libsigrok package version number (NOT the same as shared lib version!).
-m4_define([sr_package_version_major], [0])
-m4_define([sr_package_version_minor], [4])
-m4_define([sr_package_version_micro], [0])
-m4_define([sr_package_version_suffix], [-git])
-m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro[]sr_package_version_suffix])
-
-AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
+AC_INIT([libsigrok], [0.6.0],
+	[sigrok-devel@lists.sourceforge.net],
 	[libsigrok], [http://www.sigrok.org])
-AC_CONFIG_HEADER([config.h])
-AC_CONFIG_MACRO_DIR([autostuff])
+AC_CONFIG_MACRO_DIR([m4])
 AC_CONFIG_AUX_DIR([autostuff])
+AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
 
 # We require at least automake 1.11 (needed for 'silent rules').
-AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
-m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
+AM_SILENT_RULES([yes])
 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
 
-AH_TOP([#ifndef SR_CONFIG_H
-#define SR_CONFIG_H    /* To stop multiple inclusions. */])
-AH_BOTTOM([#endif /* SR_CONFIG_H */])
-
-# Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
-# and enforce use of SR_API to explicitly mark all public API functions.
-COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
-CFLAGS="$COMMON_FLAGS -std=c11 -D_POSIX_C_SOURCE=200112L -Wmissing-prototypes"
-CXXFLAGS="-std=c++11 $COMMON_FLAGS"
+AC_CANONICAL_HOST
 
 # Checks for programs.
 AC_PROG_CC
-AC_PROG_CPP
 AC_PROG_CXX
 AC_PROG_INSTALL
 AC_PROG_LN_S
@@ -59,590 +44,564 @@ AC_PROG_LN_S
 # Required for per-target flags or subdir-objects with C sources.
 AM_PROG_CC_C_O
 
+# Set the standard the C library headers should conform to.
+AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
+#ifndef _POSIX_C_SOURCE
+# define _POSIX_C_SOURCE 200112L
+#endif])
+
+# Get compiler versions.
+SR_PROG_VERSION([$CC], [sr_cc_version])
+SR_PROG_VERSION([$CXX], [sr_cxx_version])
+
+# Check for optional make features.
+SR_PROG_MAKE_ORDER_ONLY
+
 # Initialize libtool.
 LT_INIT
 
-# Initialize pkg-config.
-# We require at least 0.22, as "Requires.private" behaviour changed there.
-PKG_PROG_PKG_CONFIG([0.22])
+# Set up the libsigrok version defines.
+SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
 
 # Library version for libsigrok (NOT the same as the package version).
 # Carefully read the libtool docs before updating these numbers!
 # The algorithm for determining which number to change (and how) is nontrivial!
 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
-SR_LIB_VERSION_CURRENT=2
-SR_LIB_VERSION_REVISION=0
-SR_LIB_VERSION_AGE=0
-SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
-SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
-AC_SUBST(SR_LIB_VERSION_CURRENT)
-AC_SUBST(SR_LIB_VERSION_REVISION)
-AC_SUBST(SR_LIB_VERSION_AGE)
-AC_SUBST(SR_LIB_VERSION)
-AC_SUBST(SR_LIB_LDFLAGS)
-
-AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
-	[enable all drivers by default [default=yes]]),
-	[HW_ENABLED_DEFAULT="$enableval"],
-	[HW_ENABLED_DEFAULT="yes"])
-
-# Usage: DRIVER([Device name], [driver-name])
-# An optional third argument [no] disables that driver.
-m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
-m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
-AC_DEFUN([DRIVER], [
-	if test -z "$3"; then
-		default=$HW_ENABLED_DEFAULT
-	else
-		default="$3"
-	fi
-	AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
-		[m4_join([], [HW_], upperize([$2]))="$enableval"],
-		[m4_join([], [HW_], upperize([$2]))=$default])
-	dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
-	driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
+# Format: current:revision:age.
+SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
+
+AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
+
+#############################
+##  Optional dependencies  ##
+#############################
+
+AC_LANG([C])
+
+# Initialize pkg-config.
+# We require at least 0.22, as "Requires.private" behaviour changed there.
+PKG_PROG_PKG_CONFIG([0.22])
+
+# Keep track of all checked modules so we can list them at the end.
+SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
+
+# Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
+# These are used to derive the compiler flags and for the "Requires.private"
+# field in the generated libsigrok.pc file.
+SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
+SR_PKGLIBS_TESTS=
+SR_PKGLIBS_CXX=
+SR_PKGLIBS_PYTHON=
+SR_PKGLIBS_RUBY=
+SR_EXTRA_LIBS=
+SR_EXTRA_CXX_LIBS=
+
+SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
+	[libserialport >= 0.1.1])
+
+SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
+
+# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
+# This means libusb-1.0 is always available; no need to check for it.
+# On Windows, require the latest version we can get our hands on,
+# until the new generic event handling has seen an official release.
+AS_CASE([$host_os],
+	[freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
+	[mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
+	[sr_libusb_req='libusb-1.0 >= 1.0.16'])
+
+SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
+	[$sr_libusb_req])
+
+SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
+	[librevisa >= 0.0.20130412])
+
+SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
+	[libgpib])
+
+SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
+	sr_save_LIBS=$LIBS
+	LIBS="-lieee1284 $LIBS"
+	AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
+				[[(void) ieee1284_open(0, 0, 0);]])],
+		[sr_have_libieee1284=yes], [sr_have_libieee1284=no])
+	LIBS=$sr_save_LIBS
 ])
+AS_IF([test "x$sr_have_libieee1284" = xyes],
+	[SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 
-DRIVER([Agilent DMM], [agilent-dmm])
-DRIVER([Appa 55II], [appa-55ii])
-DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
-DRIVER([Atten PPS3xxx], [atten-pps3xxx])
-DRIVER([BayLibre ACME], [baylibre-acme])
-DRIVER([BeagleLogic], [beaglelogic])
-DRIVER([Brymen BM86x], [brymen-bm86x])
-DRIVER([Brymen DMM], [brymen-dmm])
-DRIVER([CEM DT-885x], [cem-dt-885x])
-DRIVER([Center 3xx], [center-3xx])
-DRIVER([ChronoVu LA], [chronovu-la])
-DRIVER([Colead SLM], [colead-slm])
-DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
-DRIVER([DER EE DE-5000], [deree-de5000])
-DRIVER([demo], [demo])
-DRIVER([Fluke DMM], [fluke-dmm])
-DRIVER([fx2lafw], [fx2lafw])
-DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
-DRIVER([Hameg HMO], [hameg-hmo])
-DRIVER([Hantek DSO], [hantek-dso])
-DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
-DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
-DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
-DRIVER([Lascar EL-USB], [lascar-el-usb])
-DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
-DRIVER([maynuo-m97], [maynuo-m97])
-DRIVER([MIC 985xx], [mic-985xx])
-DRIVER([Motech LPS 30x], [motech-lps-30x])
-DRIVER([Norma DMM], [norma-dmm])
-DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
-DRIVER([Pipistrello-OLS], [pipistrello-ols])
-DRIVER([Rigol DS], [rigol-ds])
-DRIVER([Saleae Logic16], [saleae-logic16])
-DRIVER([SCPI PPS], [scpi-pps])
-DRIVER([serial DMM], [serial-dmm])
-DRIVER([Sysclk LWLA], [sysclk-lwla])
-DRIVER([Teleinfo], [teleinfo])
-DRIVER([Testo], [testo])
-DRIVER([Tondaj SL-814], [tondaj-sl-814])
-DRIVER([UNI-T DMM], [uni-t-dmm])
-DRIVER([UNI-T UT32x], [uni-t-ut32x])
-DRIVER([Victor DMM], [victor-dmm])
-DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
-DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
-
-AC_ARG_ENABLE(libserialport,
-	AC_HELP_STRING([--disable-libserialport],
-	[disable libserialport support [default=detect]]))
-
-AC_ARG_ENABLE(libftdi,
-	AC_HELP_STRING([--disable-libftdi],
-	[disable libftdi support [default=detect]]))
-
-AC_ARG_ENABLE(libusb,
-	AC_HELP_STRING([--disable-libusb],
-	[disable libusb support [default=detect]]))
-
-# Language binding '--enable' options:
-
-AC_ARG_ENABLE(bindings,
-	AC_HELP_STRING([--enable-bindings],
-	[build language bindings [default=yes]]),
-	[BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
-
-AC_ARG_ENABLE(cxx,
-	AC_HELP_STRING([--enable-cxx],
-	[build C++ bindings [default=yes]]),
-	[BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
-
-AC_ARG_ENABLE(python,
-	AC_HELP_STRING([--enable-python],
-	[build Python bindings [default=yes]]),
-	[BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
-
-AC_ARG_ENABLE(java,
-	AC_HELP_STRING([--enable-java],
-	[build Java bindings [default=yes]]),
-	[BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
-
-AC_ARG_WITH(jni-include-path,
-	AC_HELP_STRING([--with-jni-include-path=path],
-	[specify include path for JNI [default=autodetect]]),
-	[JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
+######################
+##  Feature checks  ##
+######################
 
-# Check if the C++ compiler supports the C++11 standard.
+# The Check unit testing framework is optional. Disable if not found.
+SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
+AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 
-m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
-	[AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
+# Enable the C99 standard if possible, and enforce the use
+# of SR_API to explicitly mark all public API functions.
+SR_EXTRA_CFLAGS=
+SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
+SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 
-if test "x$HAVE_CXX11" != "x1"; then
-	BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
-fi
+SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 
-# The C++ bindings use Doxygen to parse libsigrok symbols.
-AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
-if test "x$HAVE_DOXYGEN" != "xyes"; then
-	BINDINGS_CXX="no"; cxx_msg="Doxygen required"
-fi
+# Check host characteristics.
+AC_SYS_LARGEFILE
+AC_C_BIGENDIAN
 
-# Python is needed for the C++ bindings.
-AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
-	[HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
-
-# The Python bindings need Python development files.
-PKG_CHECK_MODULES([python], [python >= 2.7],
-	[CXXFLAGS="$CXXFLAGS $python_CFLAGS";
-	CXXLIBS="$CXXLIBS $python_LIBS"],
-[PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
-	[CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
-	CXXLIBS="$CXXLIBS $python27_LIBS"],
-		[BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
-
-# The Python bindings need the setuptools Python module.
-m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
-	# We'll let it go through even if the macro wasn't found, the Python
-	# module may still be there.
-	[HAVE_PYTHON_SETUPTOOLS="yes";
-		AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
-)
-if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
-	BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
-fi
-
-# The Python and Java bindings use SWIG to generate code.
-AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
-if test "x$HAVE_SWIG" != "xyes"; then
-	BINDINGS_PYTHON="no"; python_msg="SWIG required"
-	BINDINGS_JAVA="no"; java_msg="SWIG required"
-fi
-
-# Checks for libraries.
-
-case "$host" in
-*mingw*)
-	# We need to link against the Winsock2 library for SCPI over TCP.
-	LIBS="$LIBS -lws2_32";;
-esac
-
-# This variable collects the pkg-config names of all detected libs.
-# It is then used to construct the "Requires.private:" field in the
-# libsigrok.pc file.
-SR_PKGLIBS=""
+AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
+AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
+AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
+
+# We need to link against the Winsock2 library for SCPI over TCP.
+AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 
 # libm (the standard math library) is always needed.
-AC_SEARCH_LIBS([pow], [m])
+SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 
 # RPC is only needed for VXI support.
-AC_MSG_CHECKING([for RPC support])
-AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
-			[CLIENT *rpc_test(void)],
-			[{ return clnt_create("", 0, 0, ""); }])],
-		[AC_MSG_RESULT([yes]); have_rpc=1],
-		[AC_MSG_RESULT([no]);  have_rpc=0])
-# Define HAVE_RPC in config.h if we found RPC support.
-AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
+AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
+	[AC_LINK_IFELSE([AC_LANG_PROGRAM(
+			[[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
+			[[(void) clnt_create("", 0, 0, "");]])],
+		[sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
+AS_IF([test "x$sr_cv_have_rpc" = xyes],
+	[AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 # VXI support is only compiled if RPC support was found.
-AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
-
-AC_DEFINE_UNQUOTED(HOST, ["$host"], [.])
-
-# libglib-2.0 is always needed. Abort if it's not found.
-# Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
-# We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
-AM_PATH_GLIB_2_0([2.32.0],
-	[LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
-
-# libzip is always needed. Abort if it's not found.
-PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
-	[LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
-	SR_PKGLIBS="$SR_PKGLIBS libzip"])
-libzip_ver=`$PKG_CONFIG --modversion libzip`
-AC_DEFINE_UNQUOTED(HAVE_LIBZIP_VER, ["$libzip_ver"], [.])
-
-# libserialport is only needed for some hardware drivers. Disable the
-# respective drivers if it is not found.
-if test "x$enable_libserialport" != "xno"; then
-	PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.1],
-		[have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
-		LIBS="$LIBS $libserialport_LIBS";
-		SR_PKGLIBS="$SR_PKGLIBS libserialport"],
-		[have_libserialport="no"])
-	if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
-		AC_MSG_ERROR([libserialport support requested, but it was not found.])
-	fi
-else
-	have_libserialport="no"
-fi
-if test "x$have_libserialport" = "xno"; then
-	HW_AGILENT_DMM="no"; HW_APPA_55II="no";
-	HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
-	HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
-	HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
-	HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
-	HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
-	HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
-	HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
-else
-	# Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
-	AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
-		[Specifies whether we have libserialport.])
-fi
-
-# Serial port helper code is only compiled in if libserialport was found.
-AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
-
-# The VISA SCPI backend is only compiled in if librevisa was found.
-PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
-	[have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
-	LIBS="$LIBS $librevisa_LIBS";
-	SR_PKGLIBS="$SR_PKGLIBS librevisa"],
-	[have_librevisa="no"])
-AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
-if test "x$have_librevisa" != "xno"; then
-	# Define HAVE_LIBREVISA in config.h if we found librevisa.
-	AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
-		[Specifies whether we have librevisa.])
-	librevisa_ver=`$PKG_CONFIG --modversion librevisa`
-	AC_DEFINE_UNQUOTED(HAVE_LIBREVISA_VER, ["$librevisa_ver"], [.])
-fi
-
-# The GPIB SCPI backend is only compiled in if libgpib is found.
-PKG_CHECK_MODULES([libgpib], [libgpib],
-	[have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
-	LIBS="$LIBS $libgpib_LIBS";
-	SR_PKGLIBS="$SR_PKGLIBS libgpib"],
-	[have_libgpib="no"])
-AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
-if test "x$have_libgpib" != "xno"; then
-	# Define HAVE_LIBGPIB in config.h if we found libgpib.
-	AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
-		[Specifies whether we have libgpib.])
-	libgpib_ver=`$PKG_CONFIG --modversion libgpib`
-	AC_DEFINE_UNQUOTED(HAVE_LIBGPIB_VER, ["$libgpib_ver"], [.])
-fi
-
-# libusb-1.0 is only needed for some hardware drivers. Disable the respective
-# drivers if it is not found.
-if test "x$enable_libusb" != "xno"; then
-	case "$host" in
-	*freebsd*)
-		# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
-		# This means libusb-1.0 is always available, no need to check for it,
-		# and no need to (potentially) disable any drivers if it's not found.
-		have_libusb1_0="yes"
-		;;
-	*)
-		PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
-			[have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
-			LIBS="$LIBS $libusb_LIBS";
-			SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
-			[have_libusb1_0="no"])
-		if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
-			AC_MSG_ERROR([libusb support requested, but it was not found.])
-		fi
-		;;
-	esac
-else
-	have_libusb1_0="no"
-fi
-if test "x$have_libusb1_0" = "xno"; then
-	HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
-	HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
-	HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
-	HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
-	HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
-	HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
-else
-	# Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
-	AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
-		[Specifies whether we have libusb-1.0.])
-fi
-
-# USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
-AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
-
-# libftdi is only needed for some hardware drivers. Disable them if not found.
-if test "x$enable_libftdi" != "xno"; then
-	PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
-		[have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
-		LIBS="$LIBS $libftdi_LIBS"; SR_PKGLIBS="$SR_PKGLIBS libftdi";
-		libftdi_ver=`$PKG_CONFIG --modversion libftdi`],
-		[PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
-			[LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
-			LIBS="$LIBS $libftdi1_LIBS";
-			SR_PKGLIBS="$SR_PKGLIBS libftdi1";
-			libftdi_ver=`$PKG_CONFIG --modversion libftdi1`],
-			[have_libftdi="no"])])
-	if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
-		AC_MSG_ERROR([libftdi support requested, but it was not found.])
-	fi
-else
-	have_libftdi="no"
-fi
-if test "x$have_libftdi" = "xno"; then
-	HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
-	HW_PIPISTRELLO_OLS="no";
-else
-	# Define HAVE_LIBFTDI in config.h if we found libftdi.
-	AC_DEFINE_UNQUOTED(HAVE_LIBFTDI, [1],
-		[Specifies whether we have libftdi.])
-	AC_DEFINE_UNQUOTED(HAVE_LIBFTDI_VER, ["$libftdi_ver"], [.])
-fi
-
-# glibmm-2.4 is needed for the C++ bindings.
-PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
-	[CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
-	CXXLIBS="$CXXLIBS $glibmm_LIBS"],
-	[BINDINGS_CXX="no"; cxx_msg="glibmm required"])
+AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
+
+# Check for compiler support of 128 bit integers
+AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
+
+########################
+##  Hardware drivers  ##
+########################
+
+# Keep track of all drivers so we can list them at the end.
+SR_VAR_SUMMARY([sr_driver_summary])
+
+# Check whether the sr_deps_avail list contains all of the arguments.
+# Unavailable dependencies are collected in sr_deps_missing.
+sr_check_driver_deps() {
+	sr_deps_missing=
+	for sr_dep
+	do
+		AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
+			[SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
+	done
+	test -z "$sr_deps_missing" || return 1
+}
+
+AC_ARG_ENABLE([all-drivers],
+	[AS_HELP_STRING([--enable-all-drivers],
+			[enable all drivers by default [default=yes]])],
+	[], [enable_all_drivers=yes])
+
+## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
+m4_define([_SR_DRIVER], [
+	AC_ARG_ENABLE([$2],
+		[AS_HELP_STRING([--enable-$2], [enable $1 support])],
+		[$3=$enableval], [$3=$enable_all_drivers])
+
+	AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
+		sr_check_driver_deps $4 \
+			|| $3=no sr_hw_info="no (missing: $sr_deps_missing)"
+	])], [sr_hw_info='no (disabled)'])
+	sr_driver_summary_append "$2" "$sr_hw_info"
+
+	AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
+	AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
+])
 
-# C++ bindings want stoi and stod.
-if test "x$BINDINGS_CXX" = "xyes"; then
-	AC_LANG_PUSH([C++])
-	AC_MSG_CHECKING([for stoi and stod])
-	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
-		[{ return std::stoi("1") + std::stod("1.0"); }])],
-		[AC_MSG_RESULT([yes]);
-		AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
-		[Specifies whether we have the stoi and stod functions.])],
-		[AC_MSG_RESULT([no])])
-	AC_LANG_POP([C++])
-fi
+## SR_DRIVER(Device name, driver-name, [dependencies...])
+m4_define([SR_DRIVER],
+	[_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
+
+SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
+SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
+SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [libserialport])
+SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
+SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
+SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
+SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
+SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
+SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
+SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
+SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
+SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
+SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
+SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
+SR_DRIVER([demo], [demo])
+SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
+SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
+SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
+SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
+SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
+SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
+SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
+SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
+SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
+SR_DRIVER([HP 3457A], [hp-3457a])
+SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
+SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
+SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
+SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
+SR_DRIVER([KERN scale], [kern-scale], [libserialport])
+SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
+SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
+SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
+SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
+SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
+SR_DRIVER([maynuo-m97], [maynuo-m97])
+SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
+SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
+SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
+SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
+SR_DRIVER([PCE PCE-322A], [pce-322a], [libserialport])
+SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
+SR_DRIVER([Rigol DS], [rigol-ds])
+SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [libserialport])
+SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
+SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
+SR_DRIVER([SCPI PPS], [scpi-pps])
+SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
+SR_DRIVER([serial LCR], [serial-lcr], [libserialport])
+SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
+SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
+SR_DRIVER([Testo], [testo], [libusb])
+SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
+SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
+SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
+SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
+SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
+SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
+
+###############################
+##  Language bindings setup  ##
+###############################
+
+AC_LANG([C++])
+SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
+
+AC_ARG_ENABLE([bindings],
+	[AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
+	[], [enable_bindings=yes])
+
+AC_ARG_ENABLE([cxx],
+	[AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
+	[], [enable_cxx=$enable_bindings])
+
+AC_ARG_ENABLE([python],
+	[AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
+	[], [enable_python=$enable_bindings])
+
+AC_ARG_ENABLE([ruby],
+	[AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
+	[], [enable_ruby=$enable_bindings])
+
+AC_ARG_ENABLE([java],
+	[AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
+	[], [enable_java=$enable_bindings])
+
+####################
+##  C++ bindings  ##
+####################
+
+sr_cxx_missing=
 
-# PyGObject is needed for the Python bindings.
-PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
-	[CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
-	CXXLIBS="$CXXLIBS $pygobject_LIBS";
-	PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
-		[pyg_flags_signed=0], [pyg_flags_signed=1]);
-	AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
-		[Whether last argument to pyg_flags_get_value() is signed.])],
-	[BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
+# Check if the C++ compiler supports the C++11 standard.
+AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
+AS_IF([test "x$HAVE_CXX11" != x1],
+	[SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 
-# The Check unit testing framework is optional. Disable if not found.
-PKG_CHECK_MODULES([check], [check >= 0.9.4],
-	[have_check="yes"], [have_check="no"])
-AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
+# The C++ bindings need glibmm.
+SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
+AS_IF([test "x$sr_have_glibmm" != xyes],
+	[SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 
-# The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
-# build it if these headers aren't available.
-AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
+# The C++ bindings use Doxygen to parse libsigrok symbols.
+AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
+AS_IF([test "x$HAVE_DOXYGEN" != xyes],
+	[SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 
-# The BayLibre ACME driver needs sys/timerfd.h. Don't try to build it if
-# this header isn't available.
-AC_CHECK_HEADERS([sys/timerfd.h], [], [HW_BAYLIBRE_ACME="no"])
+# Link C++ code with gnustl_shared if it exists (Android)
+SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 
-# The ACME driver can only be built for Linux.
-case "$host" in
-	*linux*) ;;
-	*) HW_BAYLIBRE_ACME="no" ;;
-esac
+# Python is needed for the C++ bindings.
+AM_PATH_PYTHON([2.7],
+	[HAVE_PYTHON=yes],
+	[HAVE_PYTHON=no
+	SR_APPEND([sr_cxx_missing], [', '], [Python])])
 
-AC_SUBST(SR_PKGLIBS)
+AS_IF([test -z "$sr_cxx_missing"],
+	[BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
+AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
+
+# C++ bindings want stoi and stod.
+AM_COND_IF([BINDINGS_CXX], [
+	AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
+		[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
+				[[(void) std::stoi("1"); (void) std::stod("1.0");]])],
+			[sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
+	AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
+		[AC_DEFINE([HAVE_STOI_STOD], [1],
+			[Specifies whether we have the stoi and stod functions.])])
+])
 
-CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
-CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrokcxx -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
+#######################
+##  Python bindings  ##
+#######################
+
+AS_IF([test "x$BINDINGS_CXX" = xyes],
+	[sr_python_missing=],
+	[sr_python_missing='C++ bindings'])
+
+# Extract major and minor version number of the Python interpreter.
+sr_pymajor=${PYTHON_VERSION%%.*}
+sr_pyminor=${PYTHON_VERSION#*.}
+
+# The Python bindings need Python development files. Check for either
+# Python 3 or Python 2 headers depending on the interpreter version.
+SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
+	[python = $PYTHON_VERSION],
+	[python$sr_pymajor = $PYTHON_VERSION],
+	[python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
+	[python-$PYTHON_VERSION = $PYTHON_VERSION])
+
+AS_IF([test "x$sr_have_python_dev" != xyes],
+	[SR_APPEND([sr_python_missing], [', '], [Headers])])
+
+# PyGObject is needed for the Python bindings.
+SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
+AS_IF([test "x$sr_have_pygobject" != xyes],
+	[SR_APPEND([sr_python_missing], [', '], [PyGObject])])
+
+PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
+	[AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
+		[Whether last argument to pyg_flags_get_value() is signed.])])
+
+# The Python bindings need the setuptools and numpy Python modules.
+# We'll let it go through even if the AX macro wasn't found, as the
+# Python modules may still be there.
+m4_ifdef([AX_PYTHON_MODULE], [
+	AX_PYTHON_MODULE([setuptools])
+	AX_PYTHON_MODULE([numpy])
+], [
+	HAVE_PYMOD_SETUPTOOLS=yes
+	HAVE_PYMOD_NUMPY=yes
+	m4_warn([unsupported],
+		[Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
+])
+AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
+	[SR_APPEND([sr_python_missing], [', '], [setuptools])])
+AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
+	[SR_APPEND([sr_python_missing], [', '], [numpy])])
+
+# The Python bindings use SWIG to generate code.
+AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
+AS_IF([test "x$SWIG" != x],
+    AC_MSG_CHECKING([for $SWIG version])
+    [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
+    AC_MSG_RESULT([$SWIG_VERSION]))
+AS_IF([test "x$SWIG" = x],
+	[SR_APPEND([sr_python_missing], [', '], [SWIG])])
+
+AS_IF([test -z "$sr_python_missing"],
+	[BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
+AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
+
+#####################
+##  Ruby bindings  ##
+#####################
+
+AS_IF([test "x$BINDINGS_CXX" = xyes],
+	[sr_ruby_missing=],
+	[sr_ruby_missing='C++ bindings'])
+
+AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
+AS_IF([test "x$RUBY" != x],
+	AC_MSG_CHECKING([for Ruby version])
+    [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
+    AC_MSG_RESULT([$RUBY_VERSION])
+    [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
+    AC_SUBST(RUBY_DLEXT))
+
+AS_IF([test "x$RUBY" = x],
+	[SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
+
+# Extract major and minor version number of the Ruby interpreter.
+sr_rbmajor=${RUBY_VERSION%%.*}
+sr_rbminor=${RUBY_VERSION#*.}
+sr_rbminor=${sr_rbminor%%.*}
+
+# The Ruby bindings need Ruby development files.
+SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
+	[ruby],
+	[ruby-$sr_rbmajor.$sr_rbminor])
+
+AS_IF([test "x$sr_have_ruby_dev" != xyes],
+	[SR_APPEND([sr_ruby_missing], [', '], [Headers])])
+
+# The Ruby bindings use SWIG >= 3.0.8 to generate code.
+AS_IF([test "x$SWIG" = x],
+	[SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
+	[AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
+		[SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
+
+AS_IF([test -z "$sr_ruby_missing"],
+	[BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
+AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
+
+####################
+##  Java bindings ##
+####################
+
+AS_IF([test "x$BINDINGS_CXX" = xyes],
+	[sr_java_missing=],
+	[sr_java_missing='C++ bindings'])
+
+# The Java bindings use SWIG to generate code.
+AS_IF([test "x$SWIG" = x],
+	[SR_APPEND([sr_java_missing], [', '], [SWIG])])
 
 # Find Java compiler and JNI includes for Java bindings.
 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
-if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
+AS_IF([test "x$HAVE_JAVAC" = xno],
+	[SR_APPEND([sr_java_missing], [', '], [JavaC])])
+
+AC_ARG_WITH([jni-include-path],
+	[AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
+		[specify JNI include directories [default=detect]])],
+	[JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
+
+JNI_CPPFLAGS=
+AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 	AX_PROG_JAVAC
-	if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
-		if test "x$cross_compiling" = "xyes"; then
-			JNI_INCLUDE_DIRS=
-		else
-			AX_JNI_INCLUDE_DIR
-		fi
-	fi
-	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
-		CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
-	done
-	AC_LANG_PUSH([C++])
-	AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
-	AC_LANG_POP([C++])
-else
-	BINDINGS_JAVA="no"; java_msg="Java compiler required"
-fi
-
-# Python and Java bindings depend on C++ bindings.
-if test "x$BINDINGS_CXX" != "xyes"; then
-	BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
-	BINDINGS_JAVA="no"; java_msg="C++ bindings required"
-fi
-
-# Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
-
-AC_DEFUN([DRIVER2], [
-	AM_CONDITIONAL($1, test "x$2" = "xyes")
-	if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
+	AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
+		## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
+		## If we can find jni.h without any special search path, skip
+		## the execution of the broken macro to increase our chances of
+		## success.
+		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
+			[AX_JNI_INCLUDE_DIR])
+	])
+])
+for sr_dir in $JNI_INCLUDE_DIRS
+do
+	SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
+done
+AC_SUBST([JNI_CPPFLAGS])
+
+sr_save_cppflags=$CPPFLAGS
+SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
+AC_CHECK_HEADER([jni.h],,
+	[SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
+CPPFLAGS=$sr_save_cppflags
+
+AS_IF([test -z "$sr_java_missing"],
+	[BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
+AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
+
+##############################
+##  Finalize configuration  ##
+##############################
+
+# Add mandatory dependencies to module list.
+SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
+AC_SUBST([SR_PKGLIBS])
+
+# Retrieve the compile and link flags for all modules combined.
+# Also, bail out at this point if any module dependency is not met.
+PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
+PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
+
+# SR_PKGLIBS_CXX may be empty, so only invoke these checks when
+# the C++ bindings are enabled.
+AM_COND_IF([BINDINGS_CXX], [
+	PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
+	PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
+	PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 ])
 
-DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
-DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
-DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
-DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
-DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
-DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
-DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
-DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
-DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
-DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
-DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
-DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
-DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
-DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
-DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
-DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
-DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
-DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
-DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
-DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
-DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
-DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
-DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
-DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
-DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
-DRIVER2([HW_MAYNUO_M97], [$HW_MAYNUO_M97], [HAVE_HW_MAYNUO_M97])
-DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
-DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
-DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
-DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
-DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
-DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
-DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
-DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
-DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
-DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
-DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
-DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
-DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
-DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
-DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
-DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
-DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
-DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
-
-AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
-
-AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
-
-AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
-
-# Checks for header files.
-# These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
-# unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
-
-# Checks for typedefs, structures, and compiler characteristics.
-AC_C_BIGENDIAN
+# Check for specific libusb features, now that we know the CFLAGS.
+AC_LANG([C])
+sr_save_cflags=$CFLAGS
+sr_save_libs=$LIBS
+CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
+LIBS="$LIBSIGROK_LIBS $LIBS"
+AC_CHECK_TYPES([libusb_os_handle],
+	[sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
+	[[#include <libusb.h>]])
+AC_CHECK_FUNCS([zip_discard])
+LIBS=$sr_save_libs
+CFLAGS=$sr_save_cflags
 
-AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
-AC_SUBST(MAKEFLAGS, '--no-print-directory')
-AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
+AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
+	[AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 
-SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
-SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
-SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
-SR_PACKAGE_VERSION=sr_package_version
+sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
+sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 
-AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
-AC_SUBST(SR_PACKAGE_VERSION_MINOR)
-AC_SUBST(SR_PACKAGE_VERSION_MICRO)
-AC_SUBST(SR_PACKAGE_VERSION)
+AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
+	[Build-time version of libzip.])
+AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
+	[The canonical host libsigrok will run on.])
 
-AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
-	bindings/cxx/libsigrokcxx.pc])
+AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 
 AC_OUTPUT
 
-echo
-echo "libsigrok configuration summary:"
-echo
-echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
-echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
-echo "  - Prefix: $prefix"
-echo "  - Building on: $build"
-echo "  - Building for: $host"
-echo
-echo "Detected libraries:"
-echo
-
-# Note: This only works for libs with pkg-config integration.
-for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.1" \
-	"librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
-	"libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
-	"pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
-do
-	optional="OPTIONAL"
-	if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
-	if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
-	if `$PKG_CONFIG --exists $lib`; then
-		ver=`$PKG_CONFIG --modversion $lib`
-		answer="yes ($ver)"
-	else
-		answer="no"
-	fi
-	echo "  - ($optional) $lib: $answer"
-done
-
-eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
-
-# Prepare final bindings report messages.
-final_cxx=""
-final_python=""
-final_java=""
-if test "$enable_bindings" = "no"; then
-	final_cxx=" (disabled)"
-	final_python=" (disabled)"
-	final_java=" (disabled)"
-else
-	if test "$enable_cxx" = "no"; then
-		final_cxx=" (disabled)"
-	elif test "$BINDINGS_CXX" = "no"; then
-		final_cxx=" ($cxx_msg)"
-	fi
-	if test "$enable_python" = "no"; then
-		final_python=" (disabled)"
-	elif test "$BINDINGS_PYTHON" = "no"; then
-		final_python=" ($python_msg)"
-	fi
-	if test "$enable_java" = "no"; then
-		final_java=" (disabled)"
-	elif test "$BINDINGS_JAVA" = "no"; then
-		final_java=" ($java_msg)"
-	fi
-fi
-
-echo "Enabled SCPI backends:"
-echo " - TCP............................. yes"
-if test "x$have_rpc" = "x0"; then
-echo " - RPC............................. no"
-else
-echo " - RPC............................. yes"
-fi
-echo " - serial.......................... $have_libserialport"
-echo " - VISA............................ $have_librevisa"
-echo " - GPIB............................ $have_libgpib"
-echo " - USBTMC.......................... $have_libusb1_0"
-echo
-
-echo "Enabled language bindings:"
-echo " - C++............................. $BINDINGS_CXX$final_cxx"
-echo " - Python.......................... $BINDINGS_PYTHON$final_python"
-echo " - Java............................ $BINDINGS_JAVA$final_java"
-echo
+# Prepare bindings report messages.
+m4_define([SR_PREPARE_BINDING_REPORT], [
+	sr_report_$1=
+	test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
+	test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
+])
+m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
+
+cat >&AS_MESSAGE_FD <<_EOF
+
+libsigrok configuration summary:
+ - Package version................. $SR_PACKAGE_VERSION
+ - Library ABI version............. $SR_LIB_VERSION
+ - Prefix.......................... $prefix
+ - Building on..................... $build
+ - Building for.................... $host
+ - Building shared / static........ $enable_shared / $enable_static
+
+Compile configuration:
+ - C compiler...................... $CC
+ - C compiler version.............. $sr_cc_version
+ - C compiler flags................ $CFLAGS
+ - Additional C compiler flags..... $SR_EXTRA_CFLAGS
+ - C compiler warnings............. $SR_WFLAGS
+ - C++ compiler.................... $CXX
+ - C++ compiler version............ $sr_cxx_version
+ - C++ compiler flags.............. $CXXFLAGS
+ - C++ compiler warnings........... $SR_WXXFLAGS
+ - Linker flags.................... $LDFLAGS
+
+Detected libraries (required):
+ - glib-2.0 >= 2.32.0.............. $sr_glib_version
+ - libzip >= 0.10.................. $sr_libzip_version
+
+Detected libraries (optional):
+$sr_pkglibs_summary
+Enabled hardware drivers:
+$sr_driver_summary
+Enabled SCPI backends:
+ - TCP............................. yes
+ - RPC............................. $sr_cv_have_rpc
+ - serial.......................... $sr_have_libserialport
+ - VISA............................ $sr_have_librevisa
+ - GPIB............................ $sr_have_libgpib
+ - USBTMC.......................... $sr_have_libusb
+
+Enabled language bindings:
+ - C++............................. $BINDINGS_CXX$sr_report_cxx
+ - Python.......................... $BINDINGS_PYTHON$sr_report_python
+ - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
+ - Java............................ $BINDINGS_JAVA$sr_report_java
+
+_EOF