configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  71
  72 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  73
  74 #############################
  75 ##  Optional dependencies  ##
  76 #############################
  77
  78 AC_LANG([C])
  79
  80 # Initialize pkg-config.
  81 # We require at least 0.22, as "Requires.private" behaviour changed there.
  82 PKG_PROG_PKG_CONFIG([0.22])
  83
  84 # Keep track of all checked modules so we can list them at the end.
  85 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  86
  87 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  88 # These are used to derive the compiler flags and for the "Requires.private"
  89 # field in the generated libsigrok.pc file.
  90 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  91 SR_PKGLIBS_TESTS=
  92 SR_PKGLIBS_CXX=
  93 SR_PKGLIBS_PYTHON=
  94 SR_PKGLIBS_RUBY=
  95 SR_EXTRA_LIBS=
  96
  97 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  98         [libserialport >= 0.1.1])
  99
 100 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 101         [libftdi1 >= 1.0], [libftdi >= 0.16])
 102
 103 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 104 # This means libusb-1.0 is always available; no need to check for it.
 105 # On Windows, require the latest version we can get our hands on,
 106 # until the new generic event handling has seen an official release.
 107 AS_CASE([$host_os],
 108         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 109         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 110         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 111
 112 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 113         [$sr_libusb_req])
 114
 115 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 116         [librevisa >= 0.0.20130412])
 117
 118 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 119         [libgpib])
 120
 121 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 122         sr_save_LIBS=$LIBS
 123         LIBS="-lieee1284 $LIBS"
 124         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 125                                 [[(void) ieee1284_open(0, 0, 0);]])],
 126                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 127         LIBS=$sr_save_LIBS
 128 ])
 129 AS_IF([test "x$sr_have_libieee1284" = xyes],
 130         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 131
 132 ######################
 133 ##  Feature checks  ##
 134 ######################
 135
 136 # The Check unit testing framework is optional. Disable if not found.
 137 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 138 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 139
 140 # Enable the C99 standard if possible, and enforce the use
 141 # of SR_API to explicitly mark all public API functions.
 142 SR_EXTRA_CFLAGS=
 143 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 144 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 145
 146 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 147
 148 # Check host characteristics.
 149 AC_SYS_LARGEFILE
 150 AC_C_BIGENDIAN
 151
 152 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 153 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 154 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 155
 156 # We need to link against the Winsock2 library for SCPI over TCP.
 157 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 158
 159 # libm (the standard math library) is always needed.
 160 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 161
 162 # RPC is only needed for VXI support.
 163 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 164         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 165                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 166                         [[(void) clnt_create("", 0, 0, "");]])],
 167                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 168 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 169         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 170 # VXI support is only compiled if RPC support was found.
 171 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 172
 173 ########################
 174 ##  Hardware drivers  ##
 175 ########################
 176
 177 # Keep track of all drivers so we can list them at the end.
 178 SR_VAR_SUMMARY([sr_driver_summary])
 179
 180 # Check whether the sr_deps_avail list contains all of the arguments.
 181 # Unavailable dependencies are collected in sr_deps_missing.
 182 sr_check_driver_deps() {
 183         sr_deps_missing=
 184         for sr_dep
 185         do
 186                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 187                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 188         done
 189         test -z "$sr_deps_missing" || return 1
 190 }
 191
 192 AC_ARG_ENABLE([all-drivers],
 193         [AS_HELP_STRING([--enable-all-drivers],
 194                         [enable all drivers by default [default=yes]])],
 195         [], [enable_all_drivers=yes])
 196
 197 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 198 m4_define([_SR_DRIVER], [
 199         AC_ARG_ENABLE([$2],
 200                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 201                 [$3=$enableval], [$3=$enable_all_drivers])
 202
 203         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 204                 sr_check_driver_deps $4 \
 205                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 206         ])], [sr_hw_info='no (disabled)'])
 207         sr_driver_summary_append "$2" "$sr_hw_info"
 208
 209         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 210         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 211 ])
 212
 213 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 214 m4_define([SR_DRIVER],
 215         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 216
 217 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 218 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 219 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 220 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 221 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 222 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 223 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 224 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 225 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 226 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 227 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 228 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 229 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 230 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 231 SR_DRIVER([demo], [demo])
 232 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 233 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 234 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 235 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
 236 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 237 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 238 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 239 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 240 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 241 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 242 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 243 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
 244 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 245 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 246 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 247 SR_DRIVER([maynuo-m97], [maynuo-m97])
 248 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 249 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 250 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 251 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 252 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 253 SR_DRIVER([Rigol DS], [rigol-ds])
 254 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 255 SR_DRIVER([SCPI PPS], [scpi-pps])
 256 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 257 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 258 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 259 SR_DRIVER([Testo], [testo], [libusb])
 260 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 261 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 262 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 263 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 264 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 265 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 266
 267 ###############################
 268 ##  Language bindings setup  ##
 269 ###############################
 270
 271 AC_LANG([C++])
 272 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 273
 274 AC_ARG_ENABLE([bindings],
 275         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 276         [], [enable_bindings=yes])
 277
 278 AC_ARG_ENABLE([cxx],
 279         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 280         [], [enable_cxx=$enable_bindings])
 281
 282 AC_ARG_ENABLE([python],
 283         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 284         [], [enable_python=$enable_bindings])
 285
 286 AC_ARG_ENABLE([ruby],
 287         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 288         [], [enable_ruby=$enable_bindings])
 289
 290 AC_ARG_ENABLE([java],
 291         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 292         [], [enable_java=$enable_bindings])
 293
 294 ####################
 295 ##  C++ bindings  ##
 296 ####################
 297
 298 sr_cxx_missing=
 299
 300 # Check if the C++ compiler supports the C++11 standard.
 301 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 302 AS_IF([test "x$HAVE_CXX11" != x1],
 303         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 304
 305 # The C++ bindings need glibmm.
 306 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 307 AS_IF([test "x$sr_have_glibmm" != xyes],
 308         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 309
 310 # The C++ bindings use Doxygen to parse libsigrok symbols.
 311 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 312 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 313         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 314
 315 # Python is needed for the C++ bindings.
 316 AM_PATH_PYTHON([2.7],
 317         [HAVE_PYTHON=yes],
 318         [HAVE_PYTHON=no
 319         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 320
 321 AS_IF([test -z "$sr_cxx_missing"],
 322         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 323 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 324
 325 # C++ bindings want stoi and stod.
 326 AM_COND_IF([BINDINGS_CXX], [
 327         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 328                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 329                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 330                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 331         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 332                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 333                         [Specifies whether we have the stoi and stod functions.])])
 334 ])
 335
 336 #######################
 337 ##  Python bindings  ##
 338 #######################
 339
 340 AS_IF([test "x$BINDINGS_CXX" = xyes],
 341         [sr_python_missing=],
 342         [sr_python_missing='C++ bindings'])
 343
 344 # Extract major and minor version number of the Python interpreter.
 345 sr_pymajor=${PYTHON_VERSION%%.*}
 346 sr_pyminor=${PYTHON_VERSION#*.}
 347
 348 # The Python bindings need Python development files. Check for either
 349 # Python 3 or Python 2 headers depending on the interpreter version.
 350 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 351         [python = $PYTHON_VERSION],
 352         [python$sr_pymajor = $PYTHON_VERSION],
 353         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 354         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 355
 356 AS_IF([test "x$sr_have_python_dev" != xyes],
 357         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 358
 359 # PyGObject is needed for the Python bindings.
 360 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 361 AS_IF([test "x$sr_have_pygobject" != xyes],
 362         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 363
 364 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 365         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 366                 [Whether last argument to pyg_flags_get_value() is signed.])])
 367
 368 # The Python bindings need the setuptools and numpy Python modules.
 369 # We'll let it go through even if the AX macro wasn't found, as the
 370 # Python modules may still be there.
 371 m4_ifdef([AX_PYTHON_MODULE], [
 372         AX_PYTHON_MODULE([setuptools])
 373         AX_PYTHON_MODULE([numpy])
 374 ], [
 375         HAVE_PYMOD_SETUPTOOLS=yes
 376         HAVE_PYMOD_NUMPY=yes
 377         m4_warn([unsupported],
 378                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 379 ])
 380 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 381         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 382 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 383         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 384
 385 # The Python bindings use SWIG to generate code.
 386 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 387 AS_IF([test "x$SWIG" != x],
 388     AC_MSG_CHECKING([for $SWIG version])
 389     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version\s*//p'`]
 390     AC_MSG_RESULT([$SWIG_VERSION]))
 391 AS_IF([test "x$SWIG" = x],
 392         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 393
 394 AS_IF([test -z "$sr_python_missing"],
 395         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 396 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 397
 398 #####################
 399 ##  Ruby bindings  ##
 400 #####################
 401
 402 AS_IF([test "x$BINDINGS_CXX" = xyes],
 403         [sr_ruby_missing=],
 404         [sr_ruby_missing='C++ bindings'])
 405
 406 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 407 AS_IF([test "x$RUBY" != x],
 408         AC_MSG_CHECKING([for Ruby version])
 409     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 410     AC_MSG_RESULT([$RUBY_VERSION])
 411     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 412     AC_SUBST(RUBY_DLEXT))
 413
 414 AS_IF([test "x$RUBY" = x],
 415         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 416
 417 # Extract major and minor version number of the Ruby interpreter.
 418 sr_rbmajor=${RUBY_VERSION%%.*}
 419 sr_rbminor=${RUBY_VERSION#*.}
 420 sr_rbminor=${sr_rbminor%%.*}
 421
 422 # The Ruby bindings need Ruby development files.
 423 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 424         [ruby],
 425         [ruby-$sr_rbmajor.$sr_rbminor])
 426
 427 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 428         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 429
 430 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 431 AS_IF([test "x$SWIG" = x],
 432         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 433         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 434                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 435
 436 AS_IF([test -z "$sr_ruby_missing"],
 437         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 438 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 439
 440 ####################
 441 ##  Java bindings ##
 442 ####################
 443
 444 AS_IF([test "x$BINDINGS_CXX" = xyes],
 445         [sr_java_missing=],
 446         [sr_java_missing='C++ bindings'])
 447
 448 # The Java bindings use SWIG to generate code.
 449 AS_IF([test "x$SWIG" = x],
 450         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 451
 452 # Find Java compiler and JNI includes for Java bindings.
 453 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 454 AS_IF([test "x$HAVE_JAVAC" = xno],
 455         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 456
 457 AC_ARG_WITH([jni-include-path],
 458         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 459                 [specify JNI include directories [default=detect]])],
 460         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 461
 462 JNI_CPPFLAGS=
 463 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 464         AX_PROG_JAVAC
 465         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 466                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 467                 ## If we can find jni.h without any special search path, skip
 468                 ## the execution of the broken macro to increase our chances of
 469                 ## success.
 470                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 471                         [AX_JNI_INCLUDE_DIR])
 472         ])
 473 ])
 474 for sr_dir in $JNI_INCLUDE_DIRS
 475 do
 476         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 477 done
 478 AC_SUBST([JNI_CPPFLAGS])
 479
 480 sr_save_cppflags=$CPPFLAGS
 481 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 482 AC_CHECK_HEADER([jni.h],,
 483         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 484 CPPFLAGS=$sr_save_cppflags
 485
 486 AS_IF([test -z "$sr_java_missing"],
 487         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 488 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 489
 490 ##############################
 491 ##  Finalize configuration  ##
 492 ##############################
 493
 494 # Add mandatory dependencies to module list.
 495 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 496 AC_SUBST([SR_PKGLIBS])
 497
 498 # Retrieve the compile and link flags for all modules combined.
 499 # Also, bail out at this point if any module dependency is not met.
 500 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 501 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 502
 503 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 504 # the C++ bindings are enabled.
 505 AM_COND_IF([BINDINGS_CXX], [
 506         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 507         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 508         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 509 ])
 510
 511 # Check for specific libusb features, now that we know the CFLAGS.
 512 AC_LANG([C])
 513 sr_save_cflags=$CFLAGS
 514 sr_save_libs=$LIBS
 515 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 516 LIBS="$LIBSIGROK_LIBS $LIBS"
 517 AC_CHECK_TYPES([libusb_os_handle],
 518         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 519         [[#include <libusb.h>]])
 520 AC_CHECK_FUNCS([zip_discard])
 521 LIBS=$sr_save_libs
 522 CFLAGS=$sr_save_cflags
 523
 524 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 525         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 526
 527 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 528 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 529
 530 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 531         [Build-time version of libzip.])
 532 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 533         [The canonical host libsigrok will run on.])
 534
 535 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 536
 537 AC_OUTPUT
 538
 539 # Prepare bindings report messages.
 540 m4_define([SR_PREPARE_BINDING_REPORT], [
 541         sr_report_$1=
 542         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 543         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 544 ])
 545 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 546
 547 cat >&AS_MESSAGE_FD <<_EOF
 548
 549 libsigrok configuration summary:
 550  - Package version................. $SR_PACKAGE_VERSION
 551  - Library ABI version............. $SR_LIB_VERSION
 552  - Prefix.......................... $prefix
 553  - Building on..................... $build
 554  - Building for.................... $host
 555
 556 Compile configuration:
 557  - C compiler...................... $CC
 558  - C compiler version.............. $sr_cc_version
 559  - C compiler flags................ $CFLAGS
 560  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 561  - C compiler warnings............. $SR_WFLAGS
 562  - C++ compiler.................... $CXX
 563  - C++ compiler version............ $sr_cxx_version
 564  - C++ compiler flags.............. $CXXFLAGS
 565  - C++ compiler warnings........... $SR_WXXFLAGS
 566
 567 Detected libraries (required):
 568  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 569  - libzip >= 0.10.................. $sr_libzip_version
 570
 571 Detected libraries (optional):
 572 $sr_pkglibs_summary
 573 Enabled hardware drivers:
 574 $sr_driver_summary
 575 Enabled SCPI backends:
 576  - TCP............................. yes
 577  - RPC............................. $sr_cv_have_rpc
 578  - serial.......................... $sr_have_libserialport
 579  - VISA............................ $sr_have_librevisa
 580  - GPIB............................ $sr_have_libgpib
 581  - USBTMC.......................... $sr_have_libusb
 582
 583 Enabled language bindings:
 584  - C++............................. $BINDINGS_CXX$sr_report_cxx
 585  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 586  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 587  - Java............................ $BINDINGS_JAVA$sr_report_java
 588
 589 _EOF