configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.5.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [3:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97
  98 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  99         [libserialport >= 0.1.1])
 100
 101 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 102         [libftdi1 >= 1.0], [libftdi >= 0.16])
 103
 104 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 105 # This means libusb-1.0 is always available; no need to check for it.
 106 # On Windows, require the latest version we can get our hands on,
 107 # until the new generic event handling has seen an official release.
 108 AS_CASE([$host_os],
 109         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 110         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 111         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 112
 113 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 114         [$sr_libusb_req])
 115
 116 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 117         [librevisa >= 0.0.20130412])
 118
 119 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 120         [libgpib])
 121
 122 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 123         sr_save_LIBS=$LIBS
 124         LIBS="-lieee1284 $LIBS"
 125         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 126                                 [[(void) ieee1284_open(0, 0, 0);]])],
 127                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 128         LIBS=$sr_save_LIBS
 129 ])
 130 AS_IF([test "x$sr_have_libieee1284" = xyes],
 131         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 132
 133 ######################
 134 ##  Feature checks  ##
 135 ######################
 136
 137 # The Check unit testing framework is optional. Disable if not found.
 138 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 139 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 140
 141 # Enable the C99 standard if possible, and enforce the use
 142 # of SR_API to explicitly mark all public API functions.
 143 SR_EXTRA_CFLAGS=
 144 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 145 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 146
 147 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 148
 149 # Check host characteristics.
 150 AC_SYS_LARGEFILE
 151 AC_C_BIGENDIAN
 152
 153 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 154 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 155 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 156
 157 # We need to link against the Winsock2 library for SCPI over TCP.
 158 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 159
 160 # libm (the standard math library) is always needed.
 161 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 162
 163 # RPC is only needed for VXI support.
 164 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 165         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 166                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 167                         [[(void) clnt_create("", 0, 0, "");]])],
 168                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 169 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 170         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 171 # VXI support is only compiled if RPC support was found.
 172 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 173
 174 ########################
 175 ##  Hardware drivers  ##
 176 ########################
 177
 178 # Keep track of all drivers so we can list them at the end.
 179 SR_VAR_SUMMARY([sr_driver_summary])
 180
 181 # Check whether the sr_deps_avail list contains all of the arguments.
 182 # Unavailable dependencies are collected in sr_deps_missing.
 183 sr_check_driver_deps() {
 184         sr_deps_missing=
 185         for sr_dep
 186         do
 187                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 188                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 189         done
 190         test -z "$sr_deps_missing" || return 1
 191 }
 192
 193 AC_ARG_ENABLE([all-drivers],
 194         [AS_HELP_STRING([--enable-all-drivers],
 195                         [enable all drivers by default [default=yes]])],
 196         [], [enable_all_drivers=yes])
 197
 198 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 199 m4_define([_SR_DRIVER], [
 200         AC_ARG_ENABLE([$2],
 201                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 202                 [$3=$enableval], [$3=$enable_all_drivers])
 203
 204         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 205                 sr_check_driver_deps $4 \
 206                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 207         ])], [sr_hw_info='no (disabled)'])
 208         sr_driver_summary_append "$2" "$sr_hw_info"
 209
 210         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 211         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 212 ])
 213
 214 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 215 m4_define([SR_DRIVER],
 216         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 217
 218 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 219 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 220 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [libserialport])
 221 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 222 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 223 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 224 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 225 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 226 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 227 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 228 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 229 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 230 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 231 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 232 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 233 SR_DRIVER([demo], [demo])
 234 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 235 SR_DRIVER([FTDI FT2232H], [ft2232h], [libusb libftdi])
 236 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 237 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 238 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
 239 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 240 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 241 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 242 SR_DRIVER([HP 3457A], [hp-3457a])
 243 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 244 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 245 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 246 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 247 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 248 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
 249 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 250 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 251 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 252 SR_DRIVER([maynuo-m97], [maynuo-m97])
 253 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 254 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 255 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 256 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 257 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 258 SR_DRIVER([Rigol DS], [rigol-ds])
 259 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 260 SR_DRIVER([SCPI PPS], [scpi-pps])
 261 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 262 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 263 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 264 SR_DRIVER([Testo], [testo], [libusb])
 265 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 266 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 267 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 268 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 269 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 270 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 271
 272 ###############################
 273 ##  Language bindings setup  ##
 274 ###############################
 275
 276 AC_LANG([C++])
 277 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 278
 279 AC_ARG_ENABLE([bindings],
 280         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 281         [], [enable_bindings=yes])
 282
 283 AC_ARG_ENABLE([cxx],
 284         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 285         [], [enable_cxx=$enable_bindings])
 286
 287 AC_ARG_ENABLE([python],
 288         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 289         [], [enable_python=$enable_bindings])
 290
 291 AC_ARG_ENABLE([ruby],
 292         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 293         [], [enable_ruby=$enable_bindings])
 294
 295 AC_ARG_ENABLE([java],
 296         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 297         [], [enable_java=$enable_bindings])
 298
 299 ####################
 300 ##  C++ bindings  ##
 301 ####################
 302
 303 sr_cxx_missing=
 304
 305 # Check if the C++ compiler supports the C++11 standard.
 306 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 307 AS_IF([test "x$HAVE_CXX11" != x1],
 308         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 309
 310 # The C++ bindings need glibmm.
 311 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 312 AS_IF([test "x$sr_have_glibmm" != xyes],
 313         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 314
 315 # The C++ bindings use Doxygen to parse libsigrok symbols.
 316 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 317 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 318         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 319
 320 # Python is needed for the C++ bindings.
 321 AM_PATH_PYTHON([2.7],
 322         [HAVE_PYTHON=yes],
 323         [HAVE_PYTHON=no
 324         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 325
 326 AS_IF([test -z "$sr_cxx_missing"],
 327         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 328 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 329
 330 # C++ bindings want stoi and stod.
 331 AM_COND_IF([BINDINGS_CXX], [
 332         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 333                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 334                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 335                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 336         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 337                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 338                         [Specifies whether we have the stoi and stod functions.])])
 339 ])
 340
 341 #######################
 342 ##  Python bindings  ##
 343 #######################
 344
 345 AS_IF([test "x$BINDINGS_CXX" = xyes],
 346         [sr_python_missing=],
 347         [sr_python_missing='C++ bindings'])
 348
 349 # Extract major and minor version number of the Python interpreter.
 350 sr_pymajor=${PYTHON_VERSION%%.*}
 351 sr_pyminor=${PYTHON_VERSION#*.}
 352
 353 # The Python bindings need Python development files. Check for either
 354 # Python 3 or Python 2 headers depending on the interpreter version.
 355 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 356         [python = $PYTHON_VERSION],
 357         [python$sr_pymajor = $PYTHON_VERSION],
 358         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 359         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 360
 361 AS_IF([test "x$sr_have_python_dev" != xyes],
 362         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 363
 364 # PyGObject is needed for the Python bindings.
 365 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 366 AS_IF([test "x$sr_have_pygobject" != xyes],
 367         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 368
 369 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 370         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 371                 [Whether last argument to pyg_flags_get_value() is signed.])])
 372
 373 # The Python bindings need the setuptools and numpy Python modules.
 374 # We'll let it go through even if the AX macro wasn't found, as the
 375 # Python modules may still be there.
 376 m4_ifdef([AX_PYTHON_MODULE], [
 377         AX_PYTHON_MODULE([setuptools])
 378         AX_PYTHON_MODULE([numpy])
 379 ], [
 380         HAVE_PYMOD_SETUPTOOLS=yes
 381         HAVE_PYMOD_NUMPY=yes
 382         m4_warn([unsupported],
 383                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 384 ])
 385 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 386         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 387 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 388         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 389
 390 # The Python bindings use SWIG to generate code.
 391 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 392 AS_IF([test "x$SWIG" != x],
 393     AC_MSG_CHECKING([for $SWIG version])
 394     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version\s*//p'`]
 395     AC_MSG_RESULT([$SWIG_VERSION]))
 396 AS_IF([test "x$SWIG" = x],
 397         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 398
 399 AS_IF([test -z "$sr_python_missing"],
 400         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 401 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 402
 403 #####################
 404 ##  Ruby bindings  ##
 405 #####################
 406
 407 AS_IF([test "x$BINDINGS_CXX" = xyes],
 408         [sr_ruby_missing=],
 409         [sr_ruby_missing='C++ bindings'])
 410
 411 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 412 AS_IF([test "x$RUBY" != x],
 413         AC_MSG_CHECKING([for Ruby version])
 414     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 415     AC_MSG_RESULT([$RUBY_VERSION])
 416     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 417     AC_SUBST(RUBY_DLEXT))
 418
 419 AS_IF([test "x$RUBY" = x],
 420         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 421
 422 # Extract major and minor version number of the Ruby interpreter.
 423 sr_rbmajor=${RUBY_VERSION%%.*}
 424 sr_rbminor=${RUBY_VERSION#*.}
 425 sr_rbminor=${sr_rbminor%%.*}
 426
 427 # The Ruby bindings need Ruby development files.
 428 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 429         [ruby],
 430         [ruby-$sr_rbmajor.$sr_rbminor])
 431
 432 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 433         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 434
 435 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 436 AS_IF([test "x$SWIG" = x],
 437         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 438         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 439                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 440
 441 AS_IF([test -z "$sr_ruby_missing"],
 442         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 443 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 444
 445 ####################
 446 ##  Java bindings ##
 447 ####################
 448
 449 AS_IF([test "x$BINDINGS_CXX" = xyes],
 450         [sr_java_missing=],
 451         [sr_java_missing='C++ bindings'])
 452
 453 # The Java bindings use SWIG to generate code.
 454 AS_IF([test "x$SWIG" = x],
 455         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 456
 457 # Find Java compiler and JNI includes for Java bindings.
 458 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 459 AS_IF([test "x$HAVE_JAVAC" = xno],
 460         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 461
 462 AC_ARG_WITH([jni-include-path],
 463         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 464                 [specify JNI include directories [default=detect]])],
 465         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 466
 467 JNI_CPPFLAGS=
 468 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 469         AX_PROG_JAVAC
 470         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 471                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 472                 ## If we can find jni.h without any special search path, skip
 473                 ## the execution of the broken macro to increase our chances of
 474                 ## success.
 475                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 476                         [AX_JNI_INCLUDE_DIR])
 477         ])
 478 ])
 479 for sr_dir in $JNI_INCLUDE_DIRS
 480 do
 481         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 482 done
 483 AC_SUBST([JNI_CPPFLAGS])
 484
 485 sr_save_cppflags=$CPPFLAGS
 486 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 487 AC_CHECK_HEADER([jni.h],,
 488         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 489 CPPFLAGS=$sr_save_cppflags
 490
 491 AS_IF([test -z "$sr_java_missing"],
 492         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 493 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 494
 495 ##############################
 496 ##  Finalize configuration  ##
 497 ##############################
 498
 499 # Add mandatory dependencies to module list.
 500 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 501 AC_SUBST([SR_PKGLIBS])
 502
 503 # Retrieve the compile and link flags for all modules combined.
 504 # Also, bail out at this point if any module dependency is not met.
 505 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 506 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 507
 508 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 509 # the C++ bindings are enabled.
 510 AM_COND_IF([BINDINGS_CXX], [
 511         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 512         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 513         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 514 ])
 515
 516 # Check for specific libusb features, now that we know the CFLAGS.
 517 AC_LANG([C])
 518 sr_save_cflags=$CFLAGS
 519 sr_save_libs=$LIBS
 520 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 521 LIBS="$LIBSIGROK_LIBS $LIBS"
 522 AC_CHECK_TYPES([libusb_os_handle],
 523         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 524         [[#include <libusb.h>]])
 525 AC_CHECK_FUNCS([zip_discard])
 526 LIBS=$sr_save_libs
 527 CFLAGS=$sr_save_cflags
 528
 529 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 530         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 531
 532 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 533 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 534
 535 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 536         [Build-time version of libzip.])
 537 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 538         [The canonical host libsigrok will run on.])
 539
 540 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 541
 542 AC_OUTPUT
 543
 544 # Prepare bindings report messages.
 545 m4_define([SR_PREPARE_BINDING_REPORT], [
 546         sr_report_$1=
 547         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 548         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 549 ])
 550 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 551
 552 cat >&AS_MESSAGE_FD <<_EOF
 553
 554 libsigrok configuration summary:
 555  - Package version................. $SR_PACKAGE_VERSION
 556  - Library ABI version............. $SR_LIB_VERSION
 557  - Prefix.......................... $prefix
 558  - Building on..................... $build
 559  - Building for.................... $host
 560
 561 Compile configuration:
 562  - C compiler...................... $CC
 563  - C compiler version.............. $sr_cc_version
 564  - C compiler flags................ $CFLAGS
 565  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 566  - C compiler warnings............. $SR_WFLAGS
 567  - C++ compiler.................... $CXX
 568  - C++ compiler version............ $sr_cxx_version
 569  - C++ compiler flags.............. $CXXFLAGS
 570  - C++ compiler warnings........... $SR_WXXFLAGS
 571
 572 Detected libraries (required):
 573  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 574  - libzip >= 0.10.................. $sr_libzip_version
 575
 576 Detected libraries (optional):
 577 $sr_pkglibs_summary
 578 Enabled hardware drivers:
 579 $sr_driver_summary
 580 Enabled SCPI backends:
 581  - TCP............................. yes
 582  - RPC............................. $sr_cv_have_rpc
 583  - serial.......................... $sr_have_libserialport
 584  - VISA............................ $sr_have_librevisa
 585  - GPIB............................ $sr_have_libgpib
 586  - USBTMC.......................... $sr_have_libusb
 587
 588 Enabled language bindings:
 589  - C++............................. $BINDINGS_CXX$sr_report_cxx
 590  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 591  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 592  - Java............................ $BINDINGS_JAVA$sr_report_java
 593
 594 _EOF